[[20190622205605]]　『Iグループ名を自動識別』（のぶ）　ページの最後に飛ぶ

『Iグループ名を自動識別』（のぶ）

Excelの関数を教えて下さいm(__)m
Aグループ(山田、山下、山本)、Bグループ(高橋、高田、高柳)、Ｃグループ(横田、横山、横浜)、Ｄグループ(平山、平井、平本)とグループ分けがあります。
Ａ1
のセルに『山本』と入力したら、Ｂ1のセルに属するグループとして『Ａ』と自動で表示される関数を教えて下さい。
IF関数で条件に、IF(Ａ1=Ａグループを範囲選択,Ａ,IF(Ａ1=Bグループを範囲選択,B,‥以後繰り返し)のようにしてみても、エラーがでてうまくできません。。
IF関数は範囲選択はできないのでしょう？
お力添えよろしくお願いいたします。

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

 素直にオートフィルタを使えば良いと思うし、
 なんなら、フィルタオプションとか・・・・。
 なんでこういう発想になるのか解らない。
（BJ） 2019/06/22(土) 21:08

 ＞IF関数は範囲選択はできないのでしょうか？

 出来ますけど、Ctrl + Shift + Enter で入力する必要があります。

 あと、 A1=Aグループを範囲選択　は
 　　OR(A1=Aグループを範囲選択）とやる必要があります

 　　・・と思う。テストはしてないです　m(__)m

（半平太） 2019/06/22(土) 21:19

 同じ名前があった時とか、、色々あるとおもいます、、またまた、、べたべたな式ですけど、、、

 =IF(SUM(({"山田","山下","山本","高橋"}=A1)*1),"A",IF(SUM(({"高田","高柳","横田","横山"}=A1)*1),"B",IF(SUM(({"横浜","平山","平井","平本"}=A1)*1),"C")))
（SoulMan） 2019/06/22(土) 21:29

 すみません。範囲選択だったんですね。しかも、、三つづつ、、(^^;
 こうなると、、Ctrl+Shift+Enterとしないといけません。
 =IF(SUM((B1:D1=A1)*1),"A",IF(SUM((E1:G1=A1)*1),"B",IF(SUM((H1:J1=A1)*1),"C",IF(SUM((K1:M1=A1)*1),"D"))))
（SoulMan） 2019/06/22(土) 21:51

 そのグループ分けはどこに入力されてるんですか？
 それが分かるように質問してください。

 ■横並び
	E	F	G	H
1	Ａ	Ｂ	Ｃ	Ｄ
2	山田	高橋	横田	平山
3	山下	高田	横山	平井
4	山本	高柳	横浜	平本

 =IF(COUNTIF(E:E,A1),"A",IF(COUNTIF(F:F,A1),"B",IF(COUNTIF(G:G,A1),"C",IF(COUNTIF(H:H,A1),"D",""))))

 ■タテ並び
	E	F
1	山田	A
2	山下	A
3	山本	A
4	高橋	B
5	高田	B
6	高柳	B
7	横田	C
8	横山	C
9	横浜	C
10	平山	D
11	平井	D
12	平本	D

 =IF(A1="","",VLOOKUP(A1,E:F,2,FALSE))

 参考まで
（笑） 2019/06/22(土) 22:32

 ↑ の横並びの場合、例示程度の人数なら

 =IF(A1="","",INDEX($1:$1,MAX(INDEX(($E$2:$H$10=A1)*COLUMN($E$1:$H$1),0))))

 こんな感じでもできます。

 ですが、そんな難しく考えなくても、タテ並びにしておけば
 VLOOKUP 関数で簡単にできることです。

 以上、参考まで
（笑） 2019/06/22(土) 23:18

＞=IF(A1="","",INDEX($1:$1,MAX(INDEX(($E$2:$H$10=A1)*COLUMN($E$1:$H$1),0))))

式に不具合があります

（PPM） 2019/06/23(日) 14:13

横並び（ HLOOKUP ）の例です。参考にどうぞ。

	Ａ	Ｂ	Ｃ	Ｄ	Ｅ	Ｆ	Ｇ	Ｈ	Ｉ	Ｊ	Ｋ	Ｌ
1	山田	山下	山本	高橋	高田	高柳	横田	横山	横浜 	平山	平井	平本
2	Ａ	Ａ	Ａ	Ｂ	Ｂ	Ｂ	Ｃ	Ｃ	Ｃ	Ｄ	Ｄ	Ｄ

=IF(A5="","",HLOOKUP(A5,A1:L2,2,FALSE))

（のりん） 2019/06/23(日) 14:30

 ＞式に不具合があります 
 ＞（PPM） 2019/06/23(日) 14:13

 どこが？

 一応、先に言っておきますけど
 表にない名前を A1 に入力することは想定してません。
 入力規則のリストから選択するようにすればいい。
 そもそもその式はこんな感じでもできるという程度のこと。
 推奨しているのは VLOOKUP の方。

 で、不具合とはそのことですか？
（笑） 2019/06/23(日) 16:52

＞■タテ並び
を横にして試してみました。
式に合うフォーマットを見せてください。
私の勘違いかもしれません。
失礼しました。

（PPM） 2019/06/23(日) 18:50

 ＞式に合うフォーマットを見せてください。

 すでに提示済みですけど？

 ＞＞■タテ並び 
 ＞を横にして試してみました。

 横並びの場合と言ってるのに「タテ並びを横に」ってどういうこと？
 意味が分かりません。
（笑） 2019/06/23(日) 23:52

笑さんへ
大いなる私の勘違いでした。
気分を悪くされたことと思います。
心より謝罪します。
（PPM） 2019/06/24(月) 13:42

コメント返信：

[ 一覧(最新更新順) ]

[[20190622205605]] 『Iグループ名を自動識別』（のぶ） ページの最後に飛ぶ

[[20190622205605]]　『Iグループ名を自動識別』（のぶ）　ページの最後に飛ぶ