[[20190625145614]]　『特定の文字(複数)に色をつけたい。』（くっきー）　ページの最後に飛ぶ

『特定の文字(複数)に色をつけたい。』（くっきー）

 お世話になっております

[[20050616120721]]
こちらを確認して組んでいるのですがうまく行かず質問をさせて頂きます。

 Sub TEST3()
    IroData = "通常"
    For Each Cel In Selection
        poji = InStr(1, Cel.Value, IroData)
        Do Until poji = 0
            If poji > 0 Then
                Cel.Characters(poji, Len(IroData)).Font.ColorIndex = 3
                poji = InStr(poji + 1, Cel.Value, IroData)
            End If
        Loop
    Next
 End Sub

「通常」以外にも「特殊」「イベント」等の文字にも一括で赤色をつけたいのですが、複数指定の方法をご教授いただけませんでしょうか？

申し訳ありませんが何卒よろしくお願いいたします。

＜使用 Excel：Excel2013、使用 OS：Windows7 ＞

 別案

 Sub test()
     Dim r As Range, m As Object, mySearch As String
     mySearch = InputBox("検索文字列の入力" & vbLf & "複数の場合はカンマで区切る", , "通常,特殊,イベント")
     Selection.Font.ColorIndex = xlAutomatic
     With CreateObject("VBScript.RegExp")
         .Global = True
         .Pattern = Replace(mySearch, ",", "|")
         For Each r In Selection
             For Each m In .Execute(r.Value)
                 r.Characters(m.firstindex + 1, m.Length).Font.Color = vbRed
             Next
         Next
     End With
 End Sub
（seiya） 2019/06/25(火) 15:25

コメント返信：

[ 一覧(最新更新順) ]

[[20190625145614]] 『特定の文字(複数)に色をつけたい。』（くっきー） ページの最後に飛ぶ

[[20190625145614]]　『特定の文字(複数)に色をつけたい。』（くっきー）　ページの最後に飛ぶ