[[20200504002524]]　『セルを結合せずに写真を上下に貼り付け』（初心者福）　ページの最後に飛ぶ

『セルを結合せずに写真を上下に貼り付け』（初心者福）

『セルを結合せずに写真を上下に貼り付け』

マクロ初心者です。
Excelで画像を複数(1枚～4枚程度)挿入して
A4サイズ(縦)の資料を作成しています。
画像は上下に並べています。

――――――――
商品説明

 内容説明文
　
   画像1枚目

 内容説明文
　
   画像2枚目

――――――――

↓↓↓

[[20171129083916]]　『エクセルに、セルを結合せずに写真を貼り付け』（kao）
さんが質問して
どなたかが記載してくれたコードを参考に使用したいと思いましたが
画像が横並びでなく下に並べるにはどうしたらいいのでしょうか？
教えて頂けると嬉しいです。
よろしくお願いします。

↓↓↓記載されてたコード

Sub test()

    Dim Filenames As Variant
    Dim i As Long
    Dim iWidth As Single
    Dim iHeight As Single

    ActiveSheet.Range("A1").Select

    With ActiveCell.Resize(23, 29)
        iWidth = .Width
        iHeight = .Height
    End With

    Filenames = Application.GetOpenFilename( _
        FileFilter:="画像ファイル(*.jpg;*.jpeg;*.gif;*.bmp;*.png),*.jpg;*.jpeg;*.gif;*.bmp;*.png", _
        Title:="図の挿入(複数選択可）", MultiSelect:=True)
    If Not IsArray(Filenames) Then Exit Sub

    Application.ScreenUpdating = False

    With CreateObject("System.Collections.ArrayList")
        For i = LBound(Filenames) To UBound(Filenames)
            .Add Filenames(i)
        Next i
        .Sort

        For i = 0 To .Count - 1
            With ActiveSheet.Shapes.AddPicture(.Item(i), msoFalse, msoTrue, _
                ActiveCell.Offset(0, (i Mod 3) * 30).Left, _
                ActiveCell.Offset(Int(i / 3) * 24, 0).Top, _
                iWidth, _
                iHeight)
            End With
        Next i

        Application.ScreenUpdating = True
        MsgBox .Count & "枚の画像を挿入しました", vbInformation
    End With
 End Sub
（???） 2017/11/29(水) 11:17

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

 >画像が横並びでなく下に並べるにはどうしたらいいのでしょうか

 >ActiveCell.Offset(0, (i Mod 3) * 30).Left, _
 >ActiveCell.Offset(Int(i / 3) * 24, 0).Top, _

 ActiveCell.Left, _
 ActiveCell.Offset(i * 24, 0).Top, _

（通行人） 2020/05/04(月) 04:43

 >商品説明 
 >内容説明文
 >画像1枚目
 >内容説明文
 >画像2枚目

 ActiveCell.Offset(i * 24 + 2, 0).Top, _

（通行人） 2020/05/04(月) 07:01

通行人さん
画像を上下に並べる事が出来ました。
ありがとうございました。

（初心者福） 2020/05/04(月) 13:00

コメント返信：

[ 一覧(最新更新順) ]

[[20200504002524]] 『セルを結合せずに写真を上下に貼り付け』（初心者福） ページの最後に飛ぶ

[[20200504002524]]　『セルを結合せずに写真を上下に貼り付け』（初心者福）　ページの最後に飛ぶ