[[20200509010834]]　『関数を使って別シートに抽出したい』（テレワーク中）　ページの最後に飛ぶ

『関数を使って別シートに抽出したい』（テレワーク中）

はじめまして、

関数で処理したいのですが、VlookUPや、
iF関数を使っても上手くいかず、悩んでおります。

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
　Ａ｜Ｂ｜Ｃ｜Ｄ｜Ｅ｜
1とうふ｜５０円｜×
2だいこん｜３０円｜〇
3ちくわ｜４０円｜〇
4とうふ｜２００円｜〇
5りんご｜８０円｜×
6バナナ｜３５円｜×
7いちご｜６８円｜〇
8とうふ｜７７円｜×
9お菓子｜１８円｜〇
10りんご｜５５円｜〇

＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
上のような表がありまして、
毎月、入力して表を作成します。
その時、別シートにＣ列の「×」が付いたものだけ
自動で抽出したいのです。

※上手くいけば、とうふ、りんご、バナナ、とうふ」が
でてくるハズですが・・・

Ｏｆｆｉｃｅ365、Ｗｉｎ10を使っています。
どうすればよいのでしょうか？ご教授願います。

＜使用 Excel：unknown、使用 OS：unknown ＞

 ＞Ｏｆｆｉｃｅ365、Ｗｉｎ10を使っています。

 そのバージョンなら、Sheet2のA1セルへ

 =FILTER(Sheet1!A1:B10,Sheet1!C1:C10="×")

 <Sheet2 結果図>　　　　　<Sheet1 サンプル>　　　　　　　　
  行  ___A___  ___B___     行  ____A____  ____B____  _C_
   1  とうふ   ５０円       1  とうふ     ５０円     × 
   2  りんご   ８０円       2  だいこん   ３０円     〇 
   3  バナナ   ３５円       3  ちくわ     ４０円     〇 
   4  とうふ   ７７円       4  とうふ     ２００円   〇 
                            5  りんご     ８０円     × 
                            6  バナナ     ３５円     × 
                            7  いちご     ６８円     〇 
                            8  とうふ     ７７円     × 
                            9  お菓子     １８円     〇 
                           10  りんご     ５５円     〇

 ※ B列が不要なら
    =FILTER(Sheet1!A1:A10,Sheet1!C1:C10="×")

（半平太） 2020/05/09(土) 07:20

半平太さんレスありがとうございます。
しかし・・・

すみません、「関数が違います」と出るので、
調べてみたら、エクセルのバージョンは、
「エクセル２０１３」になってました。

オフィスからインストールしたのですが、
オフィス365ではなかったようです。申し訳ありませんでした。

（テレワーク中） 2020/05/10(日) 08:30

上記のリストがSheet1のA1:C10にあるとして、
別シートの適当な場所に

=IF(COUNTIF(Sheet1!$C$1:$C$10,"×")<ROW(A1),"",INDEX(Sheet1!$A$1:$A$10,SMALL(IF(Sheet1!$C$1:$C$10="×",ROW($A$1:$A$10)),ROW(A1))))

と入力し、CtrlとShiftキーを押しながらEnterで確定、配列数式になります。
そのセルを下に適当にコピーすればどうでしょうか。

（tora） 2020/05/10(日) 10:09

追記:

もし、金額も抽出したいなら

=IF(COUNTIF(Sheet1!$C$1:$C$10,"×")<ROW(A1),"",INDEX(Sheet1!A$1:A$10,SMALL(IF(Sheet1!$C$1:$C$10="×",ROW($A$1:$A$10)),ROW(A1))))

として、CtrlとShiftキーを押しながらEnterで確定。
これなら右にコピーすれば金額も抽出できます。

ちなみに、配列数式が分かりにくい場合は、
Sheet1のD列を作業列として、

D1=IF(C1="×",ROW(),"")

などとして、そのデータをもとにINDEX関数で抽出するといいでしょう。

（tora） 2020/05/10(日) 10:27

なるほど、これですかー
配列数式・・・いつも躓くところです（＾＾；

代入してみると上手くできました、
ありがとうございました。

（テレワーク中） 2020/05/11(月) 05:42

コメント返信：

[ 一覧(最新更新順) ]

[[20200509010834]] 『関数を使って別シートに抽出したい』（テレワーク中） ページの最後に飛ぶ

[[20200509010834]]　『関数を使って別シートに抽出したい』（テレワーク中）　ページの最後に飛ぶ