[[20200511093958]]　『複雑な有休付与日数の計算方法について』（ｒ）　ページの最後に飛ぶ

『複雑な有休付与日数の計算方法について』（ｒ）

表題の件お尋ねしたいです。
有休の付与日数を計算するにあたり、計算方法について教えてください。
前期の有休取得数を出したく、そのために前期の付与数を求めています。

一般的な付与条件とは異なり、条件が特殊なためお力を貸していただけると幸いです。

■求めたいこと
前年の有給付与日数
そのために入社日から起算して何回目の付与なのかを求める

■有給付与条件

1回目の付与・・・・入社から半年
2回目以降の付与・・1回目付与の次の4月1日

　パターン1）2010年10月1日入社
　1回目付与・・2011年4月1日
　2回目付与・・2012年4月1日

　パターン2）2010年9月15日入社
　1回目付与・・2011年3月15日
　2回目付与・・2011年4月1日

■付与日数
1回目・・・10日
2回目・・・11日
3回目・・・12日
4回目・・・14日
5回目・・・16日
6回目・・・18日
7回目以降・20日

現在、下記方法で計算しております。
(1)初回付与日を計算
(2)2回目の付与日を計算
(3)3回目以降の付与日を計算
(4)付与回数を計算
(5)付与日を計算

(1)B1　=DATE(YEAR(入社日),MONTH(入社日)+6,DAY(入社日))
(2)C1　=DATE(YEAR(EDATE(B列,-3))+1,4,1)
(3)D1　=DATEDIF(C1,(付与日),"y")
(4)E1　=D2+2
(5)F1　=IF(X3=0,"0",IF(X3=1,"10",IF(X3=2,"11",IF(X3=3,"12",IF(X3=4,"14",IF(X3=5,"16",IF(X3=6,"18",IF(X3>=7,"20",""))))))))

上記で計算した場合、不備が2か所あり

【1】「(3)3回目以降の付与日」が#NUMで出てしまう。

「(2)2回目の付与日」が、(3)で使用する付与日以前の場合
「(3)3回目以降の付与日」が#NUMで出てしまう。

【2】実際より多い付与回数になってしまう可能性がある
3回目以降の付与回数を起算として+2で設定しているため
実際より多い付与回数になってしまう。

乱文で恐縮ですが、ご教示お願いします。

＜使用 Excel：Excel2019、使用 OS：Windows10 ＞

	A	B	C	D	E	F	G
1	氏名	入社日	付与1	付与2	付与3	回数	日数
2	A	10-10-1	11-4-1	12-4-1	7	9	20
3	B	10-9-15	11-3-15	11-4-1	8	10	20
4	C	20-1-1	20-7-1	21-4-1	0	0	0
5	D	19-8-1	20-2-1	20-4-1	0	2	11

 こんな感じ？

 ルール ・・・ 当年（TODAY）の4/1時点で計算。

 ・B列に入社日
 ・C2 =EDATE(B2,6)
 ・D2 =DATE(YEAR(EDATE(C2,-3))+1,4,1)
 ・E2 =IFERROR(MAX(0,DATEDIF(D2,DATE(YEAR(TODAY()),4,1),"y")-1),0)
 ・F2 =E2+COUNTIF(C2:D2,"<="&DATE(YEAR(TODAY()),4,1))
 ・G2 =CHOOSE(MIN(F2+1,8),0,10,11,12,14,16,18,20)
（GobGob） 2020/05/11(月) 11:27

ご丁寧にありがとうございます！！
出来ました！！！！！

（ｒ） 2020/05/11(月) 11:35

ちなみに、「当年（TODAY)」を指定したい年数（セル）に変えたい場合は
式はどのようにすればよろしいでしょうか。。。
（ｒ） 2020/05/11(月) 11:40

 例えば A1セルなら

 =IFERROR(MAX(0,DATEDIF(D2,DATE(YEAR($A$1),4,1),"y")-1),0)
 =E2+COUNTIF(C2:D2,"<="&DATE(YEAR($A$1),4,1))

（GobGob） 2020/05/11(月) 12:08

＞GobGobさん

できました！
本当に助かりました！
ありがとうございます！
（ｒ） 2020/05/11(月) 12:16

 セルに ●●年 4月 1日 （シリアル値）を設定するなら

 =IFERROR(MAX(0,DATEDIF(D2,$A$1,"y")-1),0)
 =E2+COUNTIF(C2:D2,"<="&$A$1)

 でもOKっすねｗ。

（GobGob） 2020/05/11(月) 12:38

コメント返信：

[ 一覧(最新更新順) ]

[[20200511093958]] 『複雑な有休付与日数の計算方法について』（ｒ） ページの最後に飛ぶ

[[20200511093958]]　『複雑な有休付与日数の計算方法について』（ｒ）　ページの最後に飛ぶ