[[20200515095058]]　『当月の土曜日のみの表示』（りき）　ページの最後に飛ぶ

『当月の土曜日のみの表示』（りき）

当月の土曜日だけの日付を表示させ、次月の土曜日だとヌルにしたいのですが、どうしてもできません。ご教授いただけないでしょうか？

（現状）
B1　2020/4/1

 4  =CEILING($B$1+1,7)
11  =CEILING($B$1+1,7)+7
18  =CEILING($B$1+1,7)+14
25  =CEILING($B$1+1,7)+21
 2  =CEILING($B$1+1,7)+28

＜使用 Excel：Excel2010、使用 OS：Windows7 ＞

 その CEILING の式だと、2020年8月のように1日が土曜日の月がうまくいかないのでは？

 B3 =B1+MOD(14-WEEKDAY(B1),7)
 B4 =IF(B3="","",IF(MONTH(B3+7)=MONTH($B$1),B3+7,""))

 表示形式を「日付」にして B4を下コピー

 以上です
（笑） 2020/05/15(金) 10:41

 ↑ ちょっと保留にしてください。

 以上
（笑） 2020/05/15(金) 10:52

 B3 =B1+7-WEEKDAY(B1)
 B4 =IF(MONTH(B3+7)=MONTH(B3),B3+7,"")
（GobGob） 2020/05/15(金) 11:00

 B1に年、C1に月だけ入力した方が簡単ですよね。

 B3 =DATE(B1,C1,1)+7-WEEKDAY(DATE(B1,C1,1))
 B4 =IF(MONTH(B3+7)=$C$1,B3+7,"")

 B4をB7までコピー

 参考まで
（笑） 2020/05/15(金) 11:37

笑さん、GobGobさん、ありがとうございます。

=CEILINGでできるものだと思っていました。MONTH関数もB3の中に入れ込みどうしても
できずにいました。

＞B1に年、C1に月だけ入力した方が簡単ですよね。
B1に年月日を入力し他の関数も色々動かしているため、B1日付入力パターンでいこうと
思います。ありがとうございました。
（りき） 2020/05/15(金) 11:54

すみませんが、条件追加で土曜日が祝祭日だったら飛ばすて詰める場合はどうやるのでしょうか？
IF、VLOOKUPを絡めたのですができませんでした。
ご教授お願いしてもよろしいでしょうか？

祝祭日設定　O5:O18

（例）
2020/5/2（祝祭日だとすると）

（例）
2020/5/9（祝祭日だとすると）

（りき） 2020/05/18(月) 09:25

 B3 =WORKDAY.INTL(B1-1,1,"1111101",O5:O18)

 B4 =IF(B3="","",IF(WORKDAY.INTL(B3,1,"1111101",$O$5:$O$18)>EOMONTH($B$1,0),"",WORKDAY.INTL(B3,1,"1111101",$O$5:$O$18)))

 B4を下コピー

 以上
（笑） 2020/05/18(月) 11:23

 B3 =IFERROR(TEXT(WORKDAY.INTL(B1-1,1,"1111101",O5:O18),"[<="&EOMONTH(B1,0)&"]yyyy-m-d;")*1,"")

 B4 =IFERROR(TEXT(WORKDAY.INTL(B3,1,"1111101",O$5:O$18),"[<="&EOMONTH(B$1,0)&"]yyyy-m-d;")*1,"")
（GobGob） 2020/05/18(月) 12:04

笑さん、GobGobさん

自分が、思っていた関数と全く違いました。
ありがとうございます。
（りき） 2020/05/18(月) 12:10

コメント返信：