[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]
『任意入力日に合致すると曜日別の参照値』(りき)
前回も似たような質問をしたのですが、
・任意入力日(P5:P18)に合致する日がありその日が月曜〜金曜ならばGから参照
・任意入力日かつ祝祭日(O5:O18)または、日曜ならばFから参照
・任意入力日かつ土曜ならば−(全角ハイフン)
の関数を作りたいのですが、どうかご教授ください。
任意入力日
P5 2020/5/1
P6 2020/5/2
P7 2020/5/3
P8 (ヌル)
B … F G 5 2020/5/1 鈴木 佐々木 6 2020/5/2 田中 前田 7 2020/5/3 山田 吉田 35 2020/5/31
(計算結果)
佐々木(P5だと)
− (P6だと)
山 田 (P7だと)
(ヌル)(P8だと)
< 使用 Excel:Excel2010、使用 OS:Windows7 >
土曜日なら祝日でも、もしくは B5:B35にない日付でも全角ハイフン?
=IF(P5="","",IF(WEEKDAY(P5)=7,"−",IFERROR(VLOOKUP(P5,$B$5:$G$35,5+(WORKDAY(P5-1,1,$O$5:$O$18)=P5),FALSE),"")))
以上 (笑) 2020/05/19(火) 12:07
土曜日が祝祭日ならFから参照です。
(りき) 2020/05/19(火) 12:23
=IF(P5="","",IF(AND(WEEKDAY(P5)=7,COUNTIF($O$5:$O$18,P5)=0),"−",IFERROR(VLOOKUP(P5,$B$5:$G$35,5+(WORKDAY(P5-1,1,$O$5:$O$18)=P5),FALSE),"")))
または =IF(P5="","",IF(WORKDAY.INTL(P5-1,1,"1111101",$O$5:$O$18)=P5,"−",IFERROR(VLOOKUP(P5,$B$5:$G$35,5+(WORKDAY(P5-1,1,$O$5:$O$18)=P5),FALSE),"")))
こういうこと? (笑) 2020/05/19(火) 13:53
【1】
=IF(P5="","",IF(AND(WEEKDAY(P5)=7,COUNTIF($O$5:$O$18,P5)=0),"−",IFERROR(VLOOKUP(P5,$B$5:$G$35,5+(WORKDAY(P5-1,1,$O$5:$O$18)=P5),FALSE),"")))
と
【2】
=IF(P5="","",IF(WORKDAY.INTL(P5-1,1,"1111101",$O$5:$O$18)=P5,"−",IFERROR(VLOOKUP(P5,$B$5:$G$35,5+(WORKDAY(P5-1,1,$O$5:$O$18)=P5),FALSE),"")))
は同一の結果になったのですが、違いはどういう事でしょうか?
(りき) 2020/05/19(火) 15:07
>違いはどういう事でしょうか? 土曜日が祝日かどうかの判定方法が違うだけで結果は同じですよ。 同じことをするにしてもやり方はひとつとは限らないということです。
以上 (笑) 2020/05/19(火) 16:30
愚問、失礼致しました。
関数ありがとうございます。
(りき) 2020/05/19(火) 16:51
[ 一覧(最新更新順) ]
YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki.
Modified by kazu.