[[20200519135114]]　『文字列表示の日付時刻を変換する方法』（NK）　ページの最後に飛ぶ

『文字列表示の日付時刻を変換する方法』（NK）

テキスト入力されている日付と時刻があります。
ex：2020年4月30日 15:01
退室時刻から入室時刻の差分を計算したいので
計算ができるように適切な表示形式に変換したいです。
日付と時刻の間は半角スペースが基本となります。
すみませんが教えていただけると助かります。

＜使用 Excel：Excel2016、使用 OS：Windows10 ＞

 ↓のような感じで日時データに変換することはできます。

 =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"年","/"),"月","/"),"日","")*1
（OK） 2020/05/19(火) 14:05

=VALUE(LEFT(A1,FIND(" ",A1)))
=VALUE(RIGHT(A1,LEN(A1)-FIND(" ",A1)))
（きまぐれ） 2020/05/19(火) 14:06

OK様　きまぐれ様回答ありがとうございます。

2020年04月30日15:01

上記のように月が2桁で時刻の前にスペースがない場合も教えていただけますか？
（NK） 2020/05/19(火) 14:24

こっちの例の場合は " " を "日" に変えてください
（きまぐれ） 2020/05/19(火) 14:34

 別案です。

 2020年4月30日 15:01 の場合　=LEFT(A1,FIND(" ",A1)-1)+RIGHT(A1,LEN(A1)-FIND(" ",A1))

 2020年04月30日15:01 の場合　=LEFT(A1,11)+RIGHT(A1,5)
 こちらは年4桁、その他2桁の固定と解釈しました。

（tora） 2020/05/19(火) 14:39

＞時刻の前にスペースがない場合
基本はOKさんのアイデアのとおりで、「"日",""」→「"日"," "」だけで対応可能な気がします。

 =SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1,"年","/"),"月","/"),"日"," ")*1

（もこな２） 2020/05/19(火) 15:00

 ＞退室時刻から入室時刻の差分を計算したい

 入室も退室も同じ日？

 時刻だけ見て計算すればいいのなら
 A1が入室、B1が退室だとして

 =SUMPRODUCT(TRIM(REPLACE(A1:B1,1,FIND("日",A1:B1),""))*{-1,1})

 表示形式「時刻」

 日付も関係あるのなら
 =SUMPRODUCT(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1:B1,"年","/"),"月","/"),"日"," ")*{-1,1})

 表示形式～ユーザー定義　[h]:mm

 ↓ どちらでもいけると思います。
 ＞2020年4月30日 15:01
 ＞2020年04月30日15:01

 参考まで
（笑） 2020/05/19(火) 15:09

コメント返信：