[[20200806115935]]　『IFとVLOOKUPの混合』（ネコ）　ページの最後に飛ぶ

『IFとVLOOKUPの混合』（ネコ）

IFとVLOOKUPの　混合計算式で
エラー　→　#N/Aが表示されたときに
ISERRORを使って　空白にしたり、0にしていますが、
長い式にISERRORを使うと　計算式が長くなってしまうので
ISERROR以外に　エラーを表示しない方法はないでしょうか？

例
=IF($A$1="りんご",VLOOKUP($B2,sheet2!$A:$Z,2,0),IF($A$1="オレンジ",VLOOKUP($B2,sheet!$A:$Z,3,0),IF($A$1="メロン",VLOOKUP($B2,sheet2!$A:$Z,4,0),IF($A$1="ぶどう",VLOOKUP($B2,sheet2!$A:$Z,5,0),""))))

#N/Aと表示されたところは　空白にしたい。
（最終的にSUMで足し算します）

宜しくお願いします。

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

 IFERRORをお使いになればいいと思いますよ。
（コナミ） 2020/08/06(木) 12:21

コナミさん
ありがとうございます。IFERRRの場合は　ISERRORのように長くならないのでしょうか？
※調べてみます
（ネコ） 2020/08/06(木) 12:33

 提示の式なら ↓ でできますね。

 =IFERROR(VLOOKUP($B2,Sheet2!$A:$F,MATCH($A$1,{"りんご","オレンジ","メロン","ぶどう"},0)+1,FALSE),"")

 参考まで
（笑） 2020/08/06(木) 12:43

笑さん
ありがとうございます。

以下のようにsheet2で指定する場所がバラバラ
（２、８、１２、３０）でも　記載いただいた関数でも可能でしょうか？

例
=IF($A$1="りんご",VLOOKUP($B2,sheet2!$A:$Z,2,0),IF($A$1="オレンジ",VLOOKUP($B2,sheet!$A:$Z,8,0),IF($A$1="メロン",VLOOKUP($B2,sheet2!$A:$Z,12,0),IF($A$1="ぶどう",VLOOKUP($B2,sheet2!$A:$Z,30,0),""))))
（ネコ） 2020/08/06(木) 13:15

 情報は小出しにしないようにしてください。

 Z列までになってますが、30列目なら「AD列」では？
　
 =IFERROR(VLOOKUP($B2,Sheet2!$A:$AD,VLOOKUP(A1,{"りんご",2;"オレンジ",8;"メロン",12;"ぶどう",30},2,FALSE),FALSE),"")

 または ↓ のようなリストを作成

	F	　G
1	りんご	　2
2	オレンジ　8
3	メロン	　12
4	ぶどう	　30

 =IFERROR(VLOOKUP($B2,Sheet2!$A:$AD,VLOOKUP(A1,$F$1:$G$4,2,FALSE),FALSE),"")

 以上
（笑） 2020/08/06(木) 14:28

 訂正

 どちらの式も　A1 → $A$1　※絶対参照に

 以上です
（笑） 2020/08/06(木) 14:42

笑さん
ありがとうございます。エラーが表示されないようになりました。
IFERRORとVLOOKUPでこのような使い方ができることを初めて知りました。
今後も　活用させていただきたいと思います。

※もし、よろしければ教えていただきたいのですが　計算式末尾の

  ,2,FALSE),FALSE),"") の　列2とFALSE×２は　VLOOKUPを2回使っているから　2でしょうか？
　もし0と表示したいときはFALSEを0に置き換えればよいでしょうか。

 =IFERROR(VLOOKUP($B2,Sheet2!$A:$AD,VLOOKUP(A1,{"りんご",2;"オレンジ",8;"メロン",12;"ぶどう",30},2,FALSE),FALSE),"")
（ネコ） 2020/08/07(金) 17:03

 ＞列2とFALSE×２は　VLOOKUPを2回使っているから　2でしょうか？
「2でしょうか？」とは？
 FALSE を「2つ」使っているのか、ということならそうですけど、そういうこと？

 ＞もし0と表示したいときはFALSEを0に置き換えればよいでしょうか。
 VLOOKUP の「検索方法」は「0」でもいいのか、ということなら、それでオッケー

 …,2,0),0),"")
　                                                                                                                                                                             
 ただし「2」は VLOOKUP の「列番号」なので変更しないように。

 以上
（笑） 2020/08/07(金) 22:53

コメント返信：

[ 一覧(最新更新順) ]

[[20200806115935]] 『IFとVLOOKUPの混合』（ネコ） ページの最後に飛ぶ

[[20200806115935]]　『IFとVLOOKUPの混合』（ネコ）　ページの最後に飛ぶ