[[20200915095636]]　『エクセルの表を1行ずつパワポの1スライドにはりつ』（柊）　ページの最後に飛ぶ

『エクセルの表を1行ずつパワポの1スライドにはりつけるVBA』（柊）

お世話になります。初心者です。

エクセルの表を1行ずつパワポの1スライドに貼り付けるVBAについてです。
イメージとしましては
行に1セルずつ「個数」「商品」「売上個数」と横に並んでいて、列に「1月」「2月」「3月」…と縦に並んでいます。

  　　個数　　商品　　売上個数
 1月　100　　りんご　　50
 2月　230　　トマト　　100
 3月　280　　いちご　　200
 4月　350　　メロン　　350
 5月　390　　もも　　　390
 6月　410　　なし　　　200

この表を1行ごとにパワポの1スライドに貼り付けたいです。
1月の「個数」「商品」「売上個数」を1スライド目に
2月の「個数」「商品」「売上個数」を2スライド目に
3月の「個数」「商品」「売上個数」を3スライド目に…
といったようなイメージです。

出来ればテキストではなくエクセルの表の書式（セルの幅やフォントなど）のまま貼り付けていきたいです。

このようなことは可能でしょうか。

ご教授いただければ幸いです。

＜使用 Excel：Excel2016、使用 OS：unknown ＞

元はExcelのデータでしょうけど、パワポを操作するからには、その中身はパワポのVBAです。 Excel専門のここではなく、teratailのように、パワポのVBAについて質問できるところで聞くべきでしょう。

とりあえず、値だけでもコピペする例なぞ。書式がほとんど消えてしまうので、テーブル追加してから個々に代入すべきなのかも？

 Sub test()
    Const ppLayoutBlank = 12
    Dim i As Long

    With CreateObject("PowerPoint.Application")
        With .Presentations.Add
            For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
                Cells(i, "A").Resize(1, 4).Copy
                With .Slides.Add(i - 1, ppLayoutBlank)
                    .Shapes.PasteSpecial
                End With
            Next i
        End With
    End With
 End Sub
（???） 2020/09/15(火) 12:03

ありがとうございます。
素人質問で申し訳ございません。。。

早速使わせていただきます。
（柊） 2020/09/15(火) 13:29

Copy命令だけはExcel VBAですが、他はパワポのVBA…。
貼り付けの際、パワポの引数を指定したところ、元の書式を再現してくれました。

 Sub test2()
    Const ppLayoutBlank = 12
    Const ppPasteEnhancedMetafile = 2
    Dim i As Long

    With CreateObject("PowerPoint.Application")
        With .Presentations.Add
            For i = 2 To Cells(Rows.Count, "A").End(xlUp).Row
                Cells(i, "A").Resize(1, 4).Copy
                With .Slides.Add(i - 1, ppLayoutBlank)
                    .Shapes.PasteSpecial DataType:=ppPasteEnhancedMetafile
                End With
            Next i
        End With
    End With
 End Sub
（???） 2020/09/15(火) 13:30

追加回答を見てくれず、私のコードである事を書かずにteratailで再質問してるし…。
ここで教えてもらった事を書かないと、著作権侵害ですよ。ひどいなぁ。
https://teratail.com/questions/291921
（???） 2020/09/15(火) 17:26

コメント返信：

[ 一覧(最新更新順) ]

[[20200915095636]] 『エクセルの表を1行ずつパワポの1スライドにはりつ』（柊） ページの最後に飛ぶ

[[20200915095636]]　『エクセルの表を1行ずつパワポの1スライドにはりつ』（柊）　ページの最後に飛ぶ