[[20210228090712]]　『転記がしたい』（超初心者）　ページの最後に飛ぶ

『転記がしたい』（超初心者）

 Sheet1
     A    B    C    D    E    F
         1日　2日　3日　4日　5日　6日
　-------------------------------------
 1  A1   30   60
 2  A2   20   30   25
 3  A3                       50
 4  A4   10        40        30

 Sheet2
    A    B    C
   1日       2日　    3日　
　--------------------------
 1  A1  30   A1  60   A2   25
 2  A2  20   A2  30   A4   40
 3  A4  10
 4
 Sheet1の表の1日の実績をSheet2に転記させたいのですが、どのような数式を　　　用いたらいいのですか？　　Sheet1は手入力です。

＜使用 Excel：Excel2003、使用 OS：Windows10 ＞

 ちょっと確認だけ

 1）Excelのバージョンは「2003」で間違いないですか？

 2）Sheet1 は何行目までデータがあるんですか？

 3）どちらのシートも、1行目は日付ですよね？
  　何日分あるんですか？（Sheet1 はどの列までデータがあるのか？）

  　1か月分だとすれば、月初～月末までの全ての日付？（途中で日付が飛ぶことはないのか？）

 4）日付はシリアル値ですか？（わからなかったら日付セルの表示形式がどうなっているか見てください）

 以上
（笑） 2021/02/28(日) 11:17

 ありがとうございます。
 1）Excelのバージョンは「2003」で間違いないですか？　はい、間違いないです。 
 2）Sheet1 は何行目までデータがあるんですか？　　　50行です。
 3）どちらのシートも、1行目は日付ですよね？
  　何日分あるんですか？（Sheet1 はどの列までデータがあるのか？）
 ※日付は一か月分です。　列はAGまであります。　B列が空白でした。
 4）日付はシリアル値ですか？（わからなかったら日付セルの表示形式がどうなっているか見てください）
 ※ 日付の表示形式はdaaaです。
 旨く説明できませんが、よろしくお願いします。

　　　　　超初心者
（超初心者） 2021/02/28(日) 12:00

 2003だったら、ただでさえメンドーな式がさらにメンドーなものになります。

 ＞B列が空白でした。
 C列からAG列ってこと？

 ■Sheet2
	A	B	C	D	E	F	G	H	I	J	K	L	・
1	1日		2日		3日		4日		5日		6日		
2	A1	30	A1	60	A2	25			A3	50			
3	A2	20	A2	30	A4	40			A4	30			
4	A4	10											
5

 1行目の日付（シリアル値）は入力済みだとして･･･

 A2 =IF(COUNT(INDEX(Sheet1!$C$2:$AG$50,0,DAY(A$1)))<ROW(A1),"",INDEX(Sheet1!$A:$A,SMALL(IF(INDEX(Sheet1!$C$2:$AG$50,0,DAY(A$1))<>"",ROW($A$2:$A$50)),ROW(A1))))
 Ctrl＋Shift＋Enter で確定
 ※実際の配置がどうなっていようと、ROW(A1)の「A1」を変更しないように

 B2 =IF(A2="","",SUMIF(Sheet1!$A$2:$A$50,A2,INDEX(Sheet1!$C$2:$AG$50,0,DAY(A$1))))
 普通に Enter だけで確定

 A2とB2を選択して右と下にコピー

 条件付き書式でエラーを非表示にしてもいいのならもう少し簡単になるかも･･･

 以上
（笑） 2021/02/28(日) 12:39

 B2の式は ↓ でいいかも

 B2 =IF(A2="","",VLOOKUP(A2,Sheet1!$A$2:$AG$50,DAY(A$1)+2,FALSE))
 普通に Enter だけで確定

 以上
（笑） 2021/02/28(日) 12:51

 何とか出来ました。
 本当にありがとうございました。
（超初心者） 2021/02/28(日) 18:16

コメント返信：

[ 一覧(最新更新順) ]

[[20210228090712]] 『転記がしたい』（超初心者） ページの最後に飛ぶ

[[20210228090712]]　『転記がしたい』（超初心者）　ページの最後に飛ぶ