[[20210704155729]]　『漢数字の合計』（リキ）　ページの最後に飛ぶ

『漢数字の合計』（リキ）

漢数字で入力された表のセルが有ります。一千円、二千円、三千円、五千円、一万円の漢数字で入力されたセルの金額を合計したい。数式を知りたいので宜しくお願い致します。

＜使用 Excel：Excel2019、使用 OS：Windows10 ＞

ネットで検索したら下記がみつかりました。
これを参考にしたらどうですか？
https://yama-3.net/excel/kan2num
　
（一応、マクロ編も載せておきましょう。）
https://yama-3.net/vba/kan2num-2
（γ） 2021/07/04(日) 17:31

 ＞漢数字で入力された表のセルが有ります。
 ＞一千円、二千円、三千円、五千円、一万円の漢数字で入力されたセル

 １．セルのアドレスが分かる状態で提示して頂けませんか？

 ２．参千円とか四千円とか八千円とかは無いんですね？

（半平太） 2021/07/04(日) 17:36

 ＞一千円、二千円、三千円、五千円、一万円の漢数字

 この5種類しかないのなら、範囲が A1:A10 だとして

 =SUM(IF(A1:A10<>"",FIND(LEFT(A1:A10),"一二三四五")*IF(RIGHT(A1:A10,2)="千円",1000,10000)))

 Ctrl＋Shift＋Enter で確定

 以上
（笑） 2021/07/04(日) 19:14

 上と同じ前提なら ↓ でもいいかも･･･

 =SUMPRODUCT((LEFT(A1:A10,2)={"一千","二千","三千","五千","一万"})*{1,2,3,5,10}*1000)

 普通に Enter だけで確定

 以上
（笑） 2021/07/05(月) 13:07

 ↓ でよかったかも

 =SUM(COUNTIF(A1:A10,{"一千","二","三","五","一万"}&"*")*{1,2,3,5,10}*1000)

 普通に Enter だけで確定

 以上
（笑） 2021/07/06(火) 08:27

     A           B       C   
  1 三千円	*一千*	 1
  2 五千円	*二千*	 2
  3 一万円	*三千*	 3
  4 二万一千円	*四千*	 4
  5 一万三千円	*五千*	 5
  6 八千円	*六千*	 6
  7		*七千*	 7
  8		*八千*	 8
  9		*九千*	 9
 10		*一万*	10
 11 六万円	*二万*	20
 12		*三万*	30
 13		*四万*	40
 14		*五万*	50
 15		*六万*	60
 16		*七万*	70
 17 		*八万*	80
 18		*九万*	90

 変換表を配置するものですが、ためしに作式させていただきました。

 A11に =SUBSTITUTE(TEXT(SUM(COUNTIF(A1:A10,B1:B18)*C1:C18),"[>9][dbnum1]0万０千円;[dbnum1]0千円"),"〇千",)
 というものですが、９万９千円まで行けるつもりです。
（6up） 2021/07/06(火) 10:21

コメント返信：

[ 一覧(最新更新順) ]

[[20210704155729]] 『漢数字の合計』（リキ） ページの最後に飛ぶ

[[20210704155729]]　『漢数字の合計』（リキ）　ページの最後に飛ぶ