[[20210918150629]]　『入力後、振り分けする。』（ヨッシー）　ページの最後に飛ぶ

『入力後、振り分けする。』（ヨッシー）

下記の表があります。A列に受注番号を入力するとB列とC列へ別表から抽出されます。
C列に○があればE列とG列へ受注番号を振り分けしたいと思います。
どうぞ、ご教授の程、宜しくお願いします。

<入力>　　　　　　　　　　　　　　　　　　　　　　　　　<振分け後>　

  行 ____A____ ____B____  ________C_______ ___D___  ____ E ______ ____ F ____ ____ G ____ 
   1  受注番号 　品名　　　　　 区別               　受注番号              　　 受注番号
   2 　1111    　みかん 　　　　 ○                  　 1111                     　2222
   3 　2222 　　 りんご                              　 2525                     　5285
   4 　2525 　　 かき　          ○　　　　　         　8888                     　6355 
   5 　8888 　　 ばなな          ○                   
   7 　5285  　　ぶどう                                 
   8 　6355  　　いちご

＜使用 Excel：Excel2013、使用 OS：Windows10 ＞

C列に○があればE列、なければG列というということですか？
（きまぐれおじさん） 2021/09/18(土) 15:16

きまぐれおじさん
早速のご返答ありがとうございます。
はい、そうです。
（ヨッシー） 2021/09/18(土) 15:18

 A列の受注番号が例示通り「数値」で
 E列とG列は昇順で表示でもいいのなら

 F2 =IFERROR(AGGREGATE(15,6,$A$2:$A$50/($C$2:$C$50="○"),ROW(A1)),"")
 G2 =IFERROR(AGGREGATE(15,6,$A$2:$A$50/(($A$2:$A$50<>"")*($C$2:$C$50="")),ROW(A1)),"")
 下コピー

 ※範囲は実際の表に合わせてください
 ※実際の表が例示とはセル位置が違っていても、ROW(A1) の「A1」を変更しないように

 ■一応･･･
 A列は実際は数値ではない、または昇順ではなくA列の出現順に並べたいということなら

 F2 =IFERROR(INDEX(A:A,AGGREGATE(15,6,ROW($A$2:$A$50)/($C$2:$C$50="○"),ROW(A1))),"")
 G2 =IFERROR(INDEX(A:A,AGGREGATE(15,6,ROW($A$2:$A$50)/(($A$2:$A$50<>"")*($C$2:$C$50="")),ROW(A1))),"")
 下コピー

 以上
（笑） 2021/09/18(土) 15:37

笑さん

ありがとうございました。
月曜日に会社の実際のデーターで試してみます。
大変助かりました。
（ヨッシー） 2021/09/18(土) 23:18

コメント返信：

[ 一覧(最新更新順) ]

[[20210918150629]] 『入力後、振り分けする。』（ヨッシー） ページの最後に飛ぶ

[[20210918150629]]　『入力後、振り分けする。』（ヨッシー）　ページの最後に飛ぶ