[[20210923205304]] 『検索』(JB) ページの最後に飛ぶ

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『検索』(JB)

よろしくお願いします。
この様な検索は出来ませんか?
マスターです

	[A]	[B]	[C]	[D]     [E]
[1]	青森	リンゴ	25	みかん	50
[2]	沖縄	リンゴ	26	みかん	20
[3]	埼玉	リンゴ	27	みかん	56
[4]	群馬	リンゴ	28	みかん	72
[5]	千葉	リンゴ	29	みかん	45
[6]	栃木	リンゴ	30	みかん	66
[7]	三重	リンゴ	31	みかん	8
[8]	栃木	リンゴ	32	みかん	9
[9]	愛媛	リンゴ	33	みかん	33
[10]	東京	リンゴ	34	みかん 56

別シート(検索シート)

	[A]	[B]	[C]	[D]     [E]
[1]	埼玉				
[2]	みかん				
[3]	56	

A1に埼玉 A2みかん入力でA3のセルに56と答えを出したいのですがどうしても
わかりません教えてください。
例 A1に東京 A2リンゴでA3のセルに34
例 A1に群馬 A2みかんでA3のセルに72
よろしくお願いします

< 使用 Excel:Excel2010、使用 OS:WindowsVista >


 マスターは ↓ のようにした方がいいのでは?

	A	B	C
1	地区	リンゴ	みかん
2	青森	25	50
3	沖縄	26	20
4	埼玉	27	56
5	群馬	28	72
6	千葉	29	45
7	栃木	30	66
8	三重	31	8
9	栃木	32	9
10	愛媛	33	33
11	東京	34	56

 これなら、マスターが Sheet1 だとして

 A3 =VLOOKUP(A1,Sheet1!A2:C20,MATCH(A2,Sheet1!A1:C1,0),FALSE)
 または
 A3 =INDEX(Sheet1!B2:C20,MATCH(A1,Sheet1!A2:A20,0),MATCH(A2,Sheet1!B1:C1,0))

 以上
(笑) 2021/09/23(木) 22:07

 一応、言っておきますけど・・・
「リンゴ」と「みかん」しかないんだったら

 =VLOOKUP(A1,Sheet1!A2:C20,IF(A2="リンゴ",2,3),FALSE)
 =INDEX(Sheet1!B2:C20,MATCH(A1,Sheet1!A2:A20,0),IF(A2="リンゴ",1,2))

 でも
(笑) 2021/09/23(木) 23:14

 作業列を使っていいのなら配列でC1とD1に結果を出しておいて
C1=INDEX(Sheet1!C1:C10,MATCH(A1&A2,Sheet1!A1:A10&Sheet1!B1:B10,0))
D1=INDEX(Sheet1!E1:E10,MATCH(A1&A2,Sheet1!A1:A10&Sheet1!D1:D10,0))

 A3に
A3=SUMIF(C1:D1,"<>#n/a")

    |[A]   |[B]|[C] |[D]
 [1]|千葉  |   |#N/A| 45
 [2]|みかん|   |    |   
 [3]|    45|   |    |   
(SoulMan) 2021/09/23(木) 23:20

 何かの事情で、マスターのレイアウトを変更できないのなら

 =VLOOKUP(A1,Sheet1!A1:E10,IF(A2="リンゴ",3,5),FALSE)
 または
 =VLOOKUP(A1,Sheet1!A1:E10,MATCH(A2,Sheet1!A1:E1,0)+1,FALSE)
 または
 =INDEX(Sheet1!B1:E10,MATCH(A1,Sheet1!A1:A10,0),MATCH(A2,Sheet1!B1:E1,0)+1)

 以上
(笑) 2021/09/23(木) 23:34

こういうのもありかなと。参考にしてください。

C列D列の間に県名を挿入し表形態を同じにして表を切り替えるようにして見ました。

    |[A]   |[B]   |[C]|[D] |[E]   |[F]
 [1] |青森  |リンゴ| 25|青森|みかん| 50
 [2] |沖縄  |リンゴ| 26|沖縄|みかん| 20
 [3] |埼玉  |リンゴ| 27|埼玉|みかん| 56
 [4] |群馬  |リンゴ| 28|群馬|みかん| 72
 [5] |千葉  |リンゴ| 29|千葉|みかん| 45
 [6] |栃木  |リンゴ| 30|栃木|みかん| 66
 [7] |三重  |リンゴ| 31|三重|みかん|  8
 [8] |栃木  |リンゴ| 32|栃木|みかん|  9
 [9] |愛媛  |リンゴ| 33|愛媛|みかん| 33
 [10]|東京  |リンゴ| 34|東京|みかん| 56
 [11]|      |      |   |    |      |   
 [12]|      |      |   |    |      |   
 [13]|      |      |   |    |      |   
 [14]|      |      |   |    |      |   
 [15]|件名  |三重  |   |    |      |   
 [16]|果物名|みかん|   |    |      |   
 [17]|個数  |     8|   |    |      | 

A1:C10 → 名前定義で「リンゴ」としている
D1:F10 → 名前定義で「りんご」としている

B17=IF(B16="リンゴ",VLOOKUP(B15,A1:C10,3,FALSE),IF(B16="みかん",VLOOKUP(B15,D1:E10,3,FALSE))
(*) 2021/09/23(木) 23:39


 まさかとは思いますけど、念のため確認

 マスターのB列は「リンゴ」とは限らない、D列は「みかん」とは限らない、ということ?

 以上
(笑) 2021/09/24(金) 00:26

 出尽くした感ありますが、まさかの場合に備えて。

 =VLOOKUP(A1,マスター!A:E,MATCH(A2,INDIRECT("マスター!"&MATCH(A1,マスター!A:A,0)&":"&MATCH(A1,マスター!A:A,0)),0)+1,FALSE)

 スマートな回答は他の回答者様の回答をお待ちください。
(#) 2021/09/24(金) 06:19

皆様回答ありがとうございます。
リンゴとみかんしかありません
助かりました。
感謝です
(JB) 2021/09/24(金) 06:31

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.