[[20240409151258]]　『文字を探して該当の行を抽出×180行』（いじゅー）　ページの最後に飛ぶ

『文字を探して該当の行を抽出×180行』（いじゅー）

指定した文字を縦に探して、該当の文字がある行を全て抽出したいです。

【Sheet1】

　　　Ａ　　Ｂ　　Ⅽ　　　Ⅾ　　　　Ｅ　　　　Ｆ
１　　種類　年度　様式　配付者１　配付者２　配付者３
２　　総務　Ｒ５　５　　　田中
３　　総務　Ｒ６　８　　　佐藤　　　鈴木　　　木下
４　　総務　Ｒ６　７　　　山田　　　森田　　
５　　財務　Ｒ５　２　　　田中　　　木下
６　　財務　Ｒ５　３　　　田中　　　鈴木　　　木下
７　　人事　Ｒ３　１　　　鈴木　　　森田　　　川野
８　　福利　Ｈ30　10　　　佐藤　　　山田
９　　福利　Ｈ30　12　　　山田　　　
～～～～～～～～～～～～～～～～～～～～～～～～～～
180　税理　Ｒ２　９　　　花田　　　木下

↑このような表から【田中】が持っているものを行ごと抽出したいです。
人名は変わる事があるので、ソートやフィルターでなく数式で抽出するにはどうしたらいいでしょうか？

人ごとのsheetに抽出したいです。

一行ずつ抽出はできますが、次の行への送り方が分かりませんでした。

＜使用 Excel：Excel2019、使用 OS：Windows10 ＞

 他人毎のシートで1行目を見出しでG1セルに抜き出したい名前を入力。
  　　　Ａ　　Ｂ　　Ⅽ　　　Ⅾ　　　　Ｅ　　　　Ｆ      Ｇ 
 １　　種類　年度　様式　配付者１　配付者２　配付者３  田中

 A2セルに
 =IFERROR(INDEX(Sheet1!B:B,AGGREGATE(15,6,ROW($2:$180)/((Sheet1!$D$2:$D$180=$G$1)+(Sheet1!$E$2:$E$180=$G$1)+(Sheet1!$F$2:$F$180=$G$1)>0),ROW(B1)))&"","")
 と入力して右及び下へフィルコピーではどうだろうか？
（ねむねむ） 2024/04/09(火) 16:04:40

 2019はFILTER関数が使えるのではないでしょうか？　スピルもしますよね？

 =FILTER(A:F,(D:D="田中")+(E:E="田中")+(F:F="田中"))
（´・ω・`） 2024/04/09(火) 16:14:56

 ＞2019はFILTER関数が使えるのではないでしょうか？　スピルもしますよね？

 ノーマルなバージョンなら無理だと思います。

 私は、ここで確認させて貰っています。
 　　　　↓
 Excel 関数一覧表(種類別,アルファベット順,機能別):Excel関数
http://www.eurus.dti.ne.jp/~yoneyama/Excel/kansu/itiran.html

（半平太） 2024/04/09(火) 16:23:12

 2019はFILTER関数使えないんですか...
 MicroSoftのサイトを盲信していました
（´・ω・`） 2024/04/09(火) 16:43:51

ねむねむ様

ご返信ありがとうございます。
数式を試してみましたが、A列の「種類」にB列の「年度」が表示されてしまいました。。。
同様にB列にはC列の結果が表示されています。
（いじゅー） 2024/04/09(火) 17:06:29

（´・ω・`）様
半平太様

ご返信ありがとうございます。

FILTER、UNIQUE使えませんでした(泣
職場のPCが古くて・・・
（いじゅー） 2024/04/09(火) 17:09:22

 すまない、式をコピーしてくるセルを間違えていた。
 式を
 =IFERROR(INDEX(Sheet1!A:A,AGGREGATE(15,6,ROW($2:$180)/((Sheet1!$D$2:$D$180=$G$1)+(Sheet1!$E$2:$E$180=$G$1)+(Sheet1!$F$2:$F$180=$G$1)>0),ROW(B1)))&"","")
 として見てくれ。
（ねむねむ） 2024/04/09(火) 17:19:58

 こんなのも。

 　　　A　　 B　　 C　D　E　F　G 
 1　種類　年度　様式　　　　　 山田 
 2　総務　Ｒ６　　 7　　　　　　　　
 3　福利　Ｈ30　　10　　　　　　　　
 4　福利　Ｈ30　　12

 A2
=IFERROR(INDEX(Sheet1!A:A,AGGREGATE(15,6,ROW($2:$200)/(Sheet1!$D$2:$Z$200=$G$1),ROW(A1))),"")
右方向・→下方向・↓
（んなっと） 2024/04/09(火) 17:44:05

ねむねむ様

修正ありがとうございます！
上手くいきました！！

はじめましての数式があったので勉強にもなりました。
迅速な対応でとても助かりました。
ありがとうございました。
（いじゅー） 2024/04/09(火) 18:18:33

んなっと様

ご返信ありがとうございます。
こちらの数式も試させていただきました。
うまく機能してくれています！
ありがとうございました！！
（いじゅー） 2024/04/09(火) 18:22:10

コメント返信：

[ 一覧(最新更新順) ]

[[20240409151258]] 『文字を探して該当の行を抽出×180行』（いじゅー） ページの最後に飛ぶ

[[20240409151258]]　『文字を探して該当の行を抽出×180行』（いじゅー）　ページの最後に飛ぶ