Worksheet_SelectionChange (mm0727)

Worksheet_SelectionChange についてわかりやすく説明します

(1) Worksheet_SelectionChangeとは

ワークシート上で選択範囲が変更されたときに呼び出される特別なメソッドです
ワークシート上で何かが起こったら何かをするような目的に使われます

(2) [エクセルVBAのHELP]から

エクセルのVBAヘルプでWorksheet_SelectionChangeをフルスペルで調べても出てきません。VBAヘルプのキーワード SelectionChange で探します
[SelectionChange イベント]
ワークシートで 選択範囲を変更したとき に発生します。
Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
Target：新しい選択範囲を指定します
[使用例] 次の使用例は、選択範囲がウィンドウの左上隅になるまで、ブックのウィンドウをスクロールします

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    With ActiveWindow
        .ScrollRow = Target.Row
        .ScrollColumn = Target.Column
    End With
End Sub

(3) Worksheet_SelectionChangeの作成方法

ワークシートから[Alt]キー+[F11]キーでVBEの世界へ入り、
左側にあるプロジェクトエクスプローラの中で自分のブックのsheet1をダブルクリックします
右側に白紙が表示されます
白紙の上端左[オブジェクト]欄に (General)、白紙の上端右[プロシージャ]欄に (Declarations) が表示されます
この[オブジェクト]欄のコンボボックスをクリックして、[Worksheet]を選択します。
すると右側の[プロシージャ]欄は[SelectionChange]になります
この手順で下のように、プロシジャの枠組みが作成されます

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

End Sub

オブジェクト欄で[Worksheet]を選択すると右側のプロシージャ欄には [Activate], [BeforeDoubleClick], [BeforeRightClick], [Calculate]など色々な項目が選択できるようになります
こうして、Worksheetというオブジェクトで発生した色々なイベントに対して処理を書くことができるのです

(4) Worksheet_SelectionChangeの簡単な作成方法

ワークシートのシート名のタグのところで、マウス右クリックして、 [コードの表示(V)]をクリックします
右側に白紙が表示されます
白紙の上端左[オブジェクト]欄に (General)、白紙の上側右[プロシージャ]欄に (Declarations) が表示されます
この[オブジェクト]のコンボボックスをクリックして、 [Worksheet]を選択します
すると右側は[SelectionChange]になります
この手順でも同様にプロシジャの枠組みが作成されます

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

End Sub

(5) Worksheet_SelectionChangeの基本

一つの例ですが、Worksheet_SelectionChange内に下のようにコードを一行書くとそのワークシート上のどのセルをクリックしても必ず、セルA1に戻るようになります

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Cells(1, 1).Select

End Sub

普通のマクロとの違いはここにあります。 マクロの実行を人間がわざわざ指示しなくても動く ということです
つまり、Worksheet_SelectionChangeはSelectionChangeイベントを拾って起動されるマクロ(メソッド)なのです
もう一つ重要なことはこのイベントを拾う範囲です。有効なのはWorksheet_SelectionChangeを書き込んだワークシート上だけです
もし全てのシートでこの動作をさせたければ
- (a) 全てのシートにWorksheet_SelectionChangeを追加する (すべきことのコードが長い場合、標準モジュールにコードを書いて Worksheet_SelectionChangeでそれを呼び出すサブルーチン化は可能)
- (b) プロジェクトエクスプローラにあるThisWorkbookのアイコンをダブルクリックして、Workbook_SheetSelectionChangeを使う
もう一つ重要なことは
この処理の中でもう一度イベントが発生することがあるということです
下の例ではクリックして選択セルに1が入力されます。しかもセルA1にも数値が加算されて行きます。そんなはずはないと誰もが考え込みます。
```
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Target.value = Target.Value +1
    Cells(1, 1).Select
End Sub
```
理由は簡単、
Cell(1, 1).Select で移動するときにもう一度イベントが発生して、結果として、2回実行されるわけです。
対策は、Cells(1, 1).Select を実行するときにイベントが発生しないように Application.EnableEvents をFalse にするだけです

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Target.value = Target.Value +1
    Application.EnableEvents = False
    Cells(1, 1).Select
    Application.EnableEvents = True
End Sub

これで、セルA1には加算しなくなります

(6) 改めてイベントとは

[goo辞書]

        << event >> 
        ━━ n. 出来事, （大）事件; 場合 （case）; 成り行き, 結果; 
        【スポーツ】種目, （番組中の）一勝負, 一試合; 【コンピュータ】事象, イベント.
        ...
        in that event　その場合には. 
        in the event　実際には; 場合には ((of)); もしも…という時には ((that)). 
        ...
        quite an event　重大事件, 一大事. 
        event driven　【コンピュータ】イベント駆動.

[IT用語辞典w-word]

        << イベント >>
        オブジェクト指向プログラミングにおいて、
        オブジェクトに特定の現象が発生した時に発する信号。
        現象が発生したこと自体のほかに、イベントによってはその現象に関するデータ
        (例えば「キーボードを押した」というイベントなら「押されたキー」のデータ)
        も発せられる。...イベントが発生すると、イベントに1対1で対応した
        メソッドが起動し、イベントに対応した処理を行なう。

    非常ボタンが押された　　　←　イベントが発生
    パトカーが走ってくる。　　→　イベントに対応したメソッドを実行する
　
    今回のWorksheet_SelectionChangeはワークシート上で
    マウスを他の場所へ移動したときにイベントが発生して
    Worksheet_SelectionChangeメソッドを実行することになります。

(7) 実際の使用例_1

L列を選んだときは1行下のA列をアクティブにする

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Column <> 12 Then Exit Sub '12列目(L列)以外は無視する   
        Cells(Target.Row + 1, 1).Select  ' Target行の1行下のA列を選択
End Sub

[[20031011234951]] 『セルをスキップするマクロ』（じゃぽね）
↑[INA]さん、いつもありがとう

(8) 実際の使用例_2

式の入ったセルを選択した場合、そのセルのひとつ右横に移動する

    Private Sub Worksheet_SelectionChange(ByVal Target As Range) 

        If Target.HasFormula = True Then   ' Targetに数式があれば

            ActiveCell.Offset(0, 1).Select ' ActiveCellの一つ右へ

        End If

    End Sub

このコードは式の保護に使えます、ワークシートの保護でもそのセルを [矢印]キーで選択することはできますが、この方法ではセル選択をできません

[[20020929211217]] 『セルをスキップさせる方法を教えてください』（エータロー）
　↑[尋]さん、[ramrun]さん、いつもありがとう

(9) 応用編

Worksheet_Change とWorksheet_SelectionChange の組み合わせセルV125の計算結果が変わったら、指定セルに日付を表記する


Option Explicit
Dim mae As Variant

Private Sub Worksheet_Change(ByVal Target As Range)
Dim ato As Variant
If Target.Address <> "$A$1" Then Exit Sub
    Application.EnableEvents = False
    ato = Range("V125").Value
    If mae <> ato Then        'maeと現在のセルV125の値を比較
        MsgBox "変更されました"
        Range("U1").Value = Date
    End If
    Application.EnableEvents = True
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
                                '選択セルの範囲が変わったら
    mae = Range("V125").Value	'セルV125の値をmaeにとっておく
End Sub

[[20040630213250]] 『計算結果の変更→指定セルへ日付を表記』（D輔）
　↑[INA]さん、[夏目雅子似]さん、いつもありがとう

2022/01/16：更新 2004/07/27：登録訪問者：