[[20030616174725]]　『ＩＮＤＥＸとＭＡＴＣＨ…』（りお）　ページの最後に飛ぶ

『ＩＮＤＥＸとＭＡＴＣＨ…』（りお）
ＩＮＤＥＸ、ＭＡＴＣＨの意味が分かりません…特にＩＮＤＥＸ。
どんな時に使うんですか？あと、どうやって使うんですか？？

 例えば、複数の倉庫に複数の商品が在庫していてそのデータがA1:E5のセルにあるとします。
 商品Ｂは倉庫１に何個あるだろう？を調べたいとき、
 =INDEX(A1:E5,3,2)と書きます。
 A1:E5はデータの存在するセルの範囲、3は「商品Ｂ」はデータの3行目、2はデータの2列目、という意味です。

 でも、データの数が多いと、商品Ｂが何行目か、倉庫１が何列目か調べるだけでも大変ですよね。
 そこで、MATCHの登場。MATCHは調べたい値が配列の何番目か、を返してきます。
 =MATCH("商品Ｂ",A1:A5)とすると３
 =MATCH("倉庫１",A1:E1)とすると２になります。

 INDEXとMATCHを組み合わせると
 =INDEX(A1:E5,MATCH("商品Ｂ",A1:A5),MATCH("倉庫１",A1:E1))
 これで、商品Ｂは倉庫１に何個かがわかります。

 でも、いちいちこんなことを考えなくても、ツールのルックアップウィザードを使うと下記のような式が作られます。
 （セルの参照は自動的に絶対参照になり$がつきます。）
 =INDEX($A$1:$E$5, MATCH("商品Ｂ",$A$1:$A$5,), MATCH("倉庫１",$A$1:$E$1,))

 さらに、"商品Ｂ"、"倉庫１"のところを、他のセルを参照するようにしておけば、いちいち式を書き換えなくて良いので便利でしょう。
 下の例はA1:E5にデータ、B7,B8が検索条件、B9に結果を表示するようにしてあります。

   A      B        C       D         E 
 1	 倉庫１	倉庫２	倉庫３	倉庫４
 2 商品Ａ	 13	75	75	27
 3 商品Ｂ	 20	97	49	19
 4 商品Ｃ	 75	24	8	17
 5 商品Ｄ	 44	79	25	75
 6
 7 倉庫	 倉庫１			
 8 商品	 商品Ａ			
 9 在庫	 =INDEX($A$1:$E$5, MATCH(B8,$A$1:$A$5,), MATCH(B7,$A$1:$E$1,))

(YS)

ものすごく詳しくありがとうございました！！また分からなかったら聞くと思うのでよろしくおねがいいたします！！(りお)

 更新が衝突して、タッチの差でまけました。

 ＜index関数・シンプル版＞
 表の形になっているデータで何行目、何列目と指定して答えを出すときに使います。

 セルA1 にリンゴ
 セルA2 にバナナ
 セルA3 にミカン
 セルB1 に青森
 セルB2 に台湾
 セルB3 に信州

 こういう表があったとき、この表の1行目の2列目を求めたいとき

 セルC1 に =INDEX(A1:B3,1,2) と入力すると青森がとってこれるのです。

 (1)なんでもあり関数にindexが入っていない。
 (2)単語検索でindex.htmlなど持ってきてしまう。
（平謝りの・kazu）

コメント返信：

[ 一覧(最新更新順) ]

[[20030616174725]] 『ＩＮＤＥＸとＭＡＴＣＨ…』（りお） ページの最後に飛ぶ

[[20030616174725]]　『ＩＮＤＥＸとＭＡＴＣＨ…』（りお）　ページの最後に飛ぶ