[[20030702142814]]　『入力規則でリストにエントリーって？』（つのだ☆ぴろ) 　ページの最後に飛ぶ

『入力規則でリストにエントリーって？』（つのだ☆ぴろ)

 入力規則で参照しているリストに該当するものがないときは直接セルに入力しています。
この直接入力したものを逆に参照しているリストに登録することってできますか？？？
　
ＡＡＡＡＡＡＡ
ＢＢＢＢＢＢＢ
ＣＣＣＣＣＣＣ
　
というデータで該当がないので
　
ＤＤＤＤＤＤＤ　と直接入力
　
次回のデータにはＤＤＤＤＤＤＤも加わっている状態にしたいのですが？？？

 みやほりんが 未解決ログ解消を目的に 2007/04/01 15:00 ごろ、投稿しました。
 トピ主の[つのだ☆ぴろ]さんの投稿は2003/07/02 14:28:14でした。
　
マクロでリストに追加していくコード例。
【仕様・制限】
入力規則の元の値の範囲には"LIST"という名前が定義されていること。
なお定義名は、Const myList As String = "LIST"　でカスタマイズ。
入力規則のリスト入力・元の値として"=LIST"が設定されているかチェック。
入力値を名前定義範囲の最後尾に書き加え、名前定義範囲を再定義しています。
　
【コード例】
　
 Private Sub Worksheet_Change(ByVal Target As Range)
     Const myList As String = "LIST"
     Dim myRng As Range
     Dim myStr As String
     If Target.Count > 1 Then Exit Sub
     If Target.Value = "" Then Exit Sub
     Set myRng = Cells.SpecialCells(xlCellTypeAllValidation)
     If Intersect(Target, myRng) Is Nothing Then Exit Sub
     If Target.Validation.Type = xlValidateList Then
         If Target.Validation.Formula1 = "=" & myList Then
             myStr = Target.Value
             With ThisWorkbook.Names(myList).RefersToRange
                 If .Find(myStr, , xlValues, xlWhole) Is Nothing Then
                     Application.EnableEvents = False
                     .Cells(.Count).Offset(1).Value = Target.Value
                     ActiveWorkbook.Names.Add _
                         Name:=myList, _
                         RefersTo:="=" & .Parent.Name & "!" & .Resize(.Count + 1, 1).Address
                     Application.EnableEvents = True
                 End If
             End With
         End If
     End If
 End Sub
　　
【関連ログ】
[[20041206151442]] 『入力規則のリストに自動で追加したい』（miu）
[[20050205112121]] 『vbaで入力規則のリスト・・・。』（miu）
[[20050413125946]] 『入力規則 リストに自動追加して保存したい』（らんたろお）
[[20050425224445]] 『入力規則』（ポー）
[[20050510144918]] 『リストについて』（瑪瑙）
[[20060611125307]] 『リストに自動で追加』（sokai）
　
(みやほりん)(-_∂)b

コメント返信：

[ 一覧(最新更新順) ]

[[20030702142814]] 『入力規則でリストにエントリーって？』（つのだ☆ぴろ) ページの最後に飛ぶ

[[20030702142814]]　『入力規則でリストにエントリーって？』（つのだ☆ぴろ) 　ページの最後に飛ぶ