[[20040530061813]] 『「--」と「!」の意味?』(masabou5) >>BOT

[ 初めての方へ | 一覧(最新更新順) | 全文検索 | 過去ログ ]

 

『「--」と「!」の意味?』(masabou5)

 よくLOOKUPさんが、  =--TEXT(A1,"0!:00")  と言うような式を
 表現されていますが、「--」と「0!」の意味を教えて下さい。


     A      B 
 1 1030	10:30	 =--TEXT(A1,"0!:00")・・・・・・値
 2 1031	10:31	 =TEXT(A2,"0!:00")   ・・・・・・テキスト
 3 1032	10:32	 =TEXT(A3,"0!:00")*1・・・・・・値
 4 1033	#VALUE!	 =--TEXT(A4,"0:00")   ・・・・・・表示形式が不正で値エラー
 5 1034	10:34	 =--TEXT(A5,"0"":""00")・・・・値
 6 1035	10:35	 =TEXT(A6,"0"":""00")・・・・・・テキスト
 7 1036	10:36	 =TEXT(A7,"0"":""00")*1・・・・値
 8 10:37	10:37	 =TEXT(A8,"h:mm")   ・・・・・値をテキストに変更
以上の式変更で、推測されたと思います。
 --はテキストを値に変更する*1と同様の働きをしています。
 4桁の数字を時刻のシリアル値形式にする,"0"":""00")を,"0!:00")につまり、"":""を!:に書換られます。
[[20030828105334]] 『日付:エクセル以外からのデータを日付に』(困った君)
[[20030902130329]] 『時間をいちいち入力したくないんです』(ちぐとも)
 上の同様の例題を参考にして下さい。(シニア)


 シニアさん、懇切丁寧な解説、ありがとうございました。
 大変よく分かりました。いろいろな技があるものですね。
 御礼申し上げます。(masabou5)


 意外なご質問です。
 こちらで、既にご承知のはずです。         (LOOKUP)

[[20040325151029]]『4と入力して4月1日とするには』(masabou5)


 たぶん、「--」がエクセル独特の何かだと勘違いされて覚えにくいのでしょうね。
基本的には算数なんですが。
="0.5"
は文字列となるので、このままでは計算に使えません。
=-("0.5")
とマイナス記号をつけてやるとエクセルは「("0.5")は数字として扱うんだ」
と勝手に解釈してくれます。でも、この場合、マイナスのままでは都合が悪いので、
=--("0.5")
ともう一回マイナス記号をつけてプラスの数字に戻してやるわけです。
(KAMIYA)


 lookupさん、ご迷惑をおかけしました。よく分かっていなかったのです。
 KAMIYAさん、「--」は何かの特殊記号かと思っていました。
 ところで「--」が普通のマイナス記号ならば、「+」はどうかと思いましたら、
 「+」では数字とはなりませんね。(masabou5)


 A1に '0.5 などとしたときは、文字扱いですね。
 B1に =+A1
 B2に =-A1
 B3に =A1*1
 B4に =A1/1
 と入力した結果が↓です。

     A      B
 1 '0.5	0.5
 2	  -0.5
 3	   0.5
 4	   0.5

 ようはExcel的には +A1 としたとき「なにも計算しなくていいんだ」と解釈し、
 -、*1、/1 のときは、「計算した結果を返さなくちゃ」となるわけです。
 計算されたものに関しては結果が数値になります。

 ですから↓のように A1 が本当に文字だったら、-、*1、/1 では
 計算できずにエラーとなり、+ は計算していないのがわかります。

     A      B
 1 a	a
 2	 #VALUE!
 3	 #VALUE!
 4	 #VALUE!

 '0.5とき - の場合は数値になったと同時に、符号がひっくり返ってしまいますから
 もどすためにさらに - 符号を付け、 =--A1 と記述します。

 --、*1、/1 の中で -- が一番入力しやすいということです。
 (ramrun)

コメント返信:

[ 一覧(最新更新順) ]


YukiWiki 1.6.7 Copyright (C) 2000,2001 by Hiroshi Yuki. Modified by kazu.