[[20040607221050]]　『点数を評点に換算する方法』（konta）　ページの最後に飛ぶ

『点数を評点に換算する方法』（konta）

質問内容
テストの点数を、１０段階評価のの評点に換算する方法が分かりません。

０～４点は０，
５～１４点は１，
１５～２４点は２，
２５～３４点は３，
３５～４４点は４，
４５～５４点は５，
５５～６４点は６，
６５～７４点は７，
７５～８４点は８，
８５～９４点は９，
９５～１００点は１０
といったように換算します。

過去ログを見て、途中までうまくいったのですが、エクセルで２行になってしまうとエラーになってしまいます。
ちなみに途中までうまくいった式は、
=IF(B3>=95,"10",IF(B3>=85,"9",IF(B3>=75,"8",IF(B3>=65,"7",IF(B3>=55,"6",IF(B3>=45,"5",IF(B3>=35,"4",IF(B3>=25,"3"))))))))
です。こういった感じで最後までやろうとするとエラーになります。
色々考えたのですがどうしても分からないのでどなたか分かる方、教えて下さい。初心者ですがよろしくお願いいたします。

エクセルはExcel2002、ＯＳはWindowsXPです。

  点数と評価の表を使用する方法です。
評価表をD2:E12に作成したとします。
得点をA1に入力するとします。
=VLOOKUP(A1,$D$2:$E$12,2)
と、なります。　(マーヤ)
	D	E
1	点数	評価
2	0	0
3	5	1
4	15	2
5	25	3
6	35	4
7	45	5
8	55	6
9	65	7
10	75	8
11	85	9
12	95	10
　
ついでに、別のSheetに評価表を作成する場合
=VLOOKUP(A1,Sheet2!$D$2:$E$12,2)
のように、「Sheet2!」←シート名+「!」を使います。
　
10点刻みでの評価ですので、数式でも可能です。
=INT((A2+5)/10)
でもOKです。
　(マーヤ)

ありがとうございました。
早速、やってみます。
丁寧に説明して頂いて助かりました。
（konta）

 =IF()で書くのは、このようになると思います。　　　　　　　(LOOKUP)

 =IF(COUNT(B3)=0,"",

 IF(B3>=45,IF(B3>=75,IF(B3>=95,10,IF(B3>=85,9,8)),
                     IF(B3>=65,7,IF(B3>=55,6,5))),

 　　　　　 IF(B3>=15,IF(B3>=35,4,IF(B3>=25,3,2)),
                     IF(B3>=5,1,0))))

 解決済みのご様子ですが、
 >エクセルで２行になってしまうとエラーになってしまいます。
 >            ：
 >こういった感じで最後までやろうとするとエラーになります。

 に関しては、Excelヘルプで『（関数の）ネスト』を一度読まれることをお勧めします。
この問題の打開策が、LOOKUPさんが提示されている数式です。
 なぜエラーが出るのかを考える（エラー箇所を見つける）事も、今後必要になると思いますので
レスさせていただきました。。。
 　　　　　　　　　　　　　　　    . .
 マーヤさんが提示された以外の方法も参考までに書いておきます。
=LOOKUP(B3,{0,5,15,25,35,45,55,65,75,85,95;0,1,2,3,4,5,6,7,8,9,10})
                  や
=CHOOSE(MATCH(B3,{0,5,15,25,35,45,55,65,75,85,95},1),0,1,2,3,4,5,6,7,8,9,10)
  など 他にも方法は色々あると思いますが…
 余計なお世話だとは思いますが、近頃出番が無いもので……
 お久しぶりの(sin)　　念のため（SIN)さんでも（しん)さんでもありません。。。

コメント返信：

[ 一覧(最新更新順) ]

[[20040607221050]] 『点数を評点に換算する方法』（konta） ページの最後に飛ぶ

[[20040607221050]]　『点数を評点に換算する方法』（konta）　ページの最後に飛ぶ