[[20040701173628]]　『レンタル商品の出入りをエクセルで管理できますか』（わこ）　ページの最後に飛ぶ

『レンタル商品の出入りをエクセルで管理できますか』（わこ）

[レンタル商品の出入りをエクセルで管理。できますか？]

レンタル商品の出入りについてエクセルで管理しなくてはなりません。
具体的には・・・
レンタル商品の在庫データが　全ＬＯＴ№分収録されたｓｈｅｅｔ、および、
返却・貸し出商品について、それぞれＬＯＴ№を入力するsheetがあります。
ここで、商品の貸し出しに伴い、貸し出し商品用のsheetにLOTNo.を入力すると、
全ＬＯＴ№分のsheetにおいて、その貸し出したLOT№部分には「貸し出し中」と表示されます。
さらに、商品が返却された場合には、返却sheetに№を入力すればその「貸し出し中」が消えます。

以上のように夢のような工程をエクセルで表現することはできますでしょうか？

どなたかご教授くだされば幸いです。。。。

 出来ると思いますが、
 もっと詳しくシート上のデータやレイアウトについて
 サンプルを掲載して頂けませんか？

  (INA)

 失礼します。詳しいデータが出ていませんが、数式で考えました。

 返却sheet を sheet2 として以下のように仮定します。

 在庫データsheet を sheet1 として以下とします。

    A		B
 1 ＬＯＴ№	在庫確認
 2 123
 3 124	
 4 125
 5 126
 6 127
 7 128	
 8 129
 9 130

 sheet1 B2 に
=IF(AND(ISERROR(VLOOKUP(A2,Sheet2!A:A,1,0)),ISERROR(VLOOKUP(A2,Sheet2!B:B,1,0))),"",IF(AND(VLOOKUP(A2,Sheet2!A:A,1,0),ISERROR(VLOOKUP(A2,Sheet2!B:B,1,0))),"貸出中",""))
 として、下にコピー

 以上でどうでしょうか。
 ダメでしたら、詳しい情報を掲載しマクロをお待ち下さい。　　（jun53）

みなさま早速の書き込み感謝いたします。

情報の掲載も（jun53）さまにやっていただいてしまいた。
申し訳ございません！

詳しいデータですが、
（jun53）さまに作成していただいた感じで
申し分ありません。
私がこんなに楽してしまって情けないのですが。

さて、実際に（jun53）さま考案の式を用いてやってみました。
初心者の私には何がどうして？
という感じですが、本当に「貸出中」が

出現してとてもとても感動しました。

さらに欲を言ってしまいますと、数式の意味など、
簡単に種明かしをしていただきたいのですが・・・

 >数式の意味など、簡単に...
 簡単に、ということなのでホッとしてます（笑）

 最初の
IF(AND(ISERROR(VLOOKUP(A2,Sheet2!A:A,1,0)),ISERROR(VLOOKUP(A2,Sheet2!B:B,1,0))),"",
 は、Sheet2の A列、B列両方に　Sheet1 の ＬＯＴ№ は無い時は [空白] にする。

 次の
IF(AND(VLOOKUP(A2,Sheet2!A:A,1,0),ISERROR(VLOOKUP(A2,Sheet2!B:B,1,0))),"貸出中",
 は、Sheet2の A列に　Sheet1 の ＬＯＴ№ が有り　同時に
 　　Sheet2の B列に　Sheet1 の ＬＯＴ№ が無い時は [貸出中] を表示する。

 ISERROR は、テーブル(検査範囲)に検査値対象が有るのか無いのか、
 或いはエラーなのか　等を調べる時に便利な関数ですね。

 以上の説明でいかがでしょうか。　　（jun53）

ありがとうございます！！！

ご丁寧な説明でわかりやすいです。。
おかげで、なんとか理解して、応用もできちゃうかもです。

感謝いたします！！

 [わこ]さんは、もう一度ここを覗いてくれないでしょうか。

 当初から少し疑問に思っていたのですが、
 一度[貸し出]→[返却]が有って、もう一度同じ商品の[貸し出]が当然あるわけですね(例えば ＬＯＴ№ 130)
 その場合、返却sheet [貸し出]列に累積的に 130 と入力しても
 [貸出中] は表示しませんね([返却]列に 130 が有る為)
 どうしても、手作業でのデータ整理が必要です。

 データ整理がし易いように、[返却]が有った場合その ＬＯＴ№ に色を付ける。
 等はどうでしょうか。

 返却sheet2 A:B の色を付けたい下方範囲全て選択して
 条件付き書式
 条件１　セルの値が　次の値に等しい　=""　　として　書式 パターン　色なし　OK
 条件２　数式が　　　=COUNTIF($A:$B,A1)>1　　として　書式 パターン　例えば：青　OK

 このようにすれば、データ整理の際作業がし易いと思いますね。
 (既に実行中ならゴメンナサイ)　　（jun53）

アドバイスありがとうございます。
私は抜けていてだめですねぇ

とりあえずは、まだついていけていないので、
検討しなおしてみます。（わこ）

うーむ。やはり手作業でないとできないのですよね。。。

貸出列、返却列の両方に登場したLotについては

考慮しない方法とかあると
便利なのですが・・・。（わこ）

 やはり上の式では不都合が出ますよね。
 過去の貸し出し、返却の記録を残すのは大事なことだと思いますよ。
 ただ、面倒くさいだけ？(笑)

 ＬＯＴ№ を下方に追加入力していく、ということでしたら、
 いろんな方法があると思いますが、

 =IF(AND(ISERROR(VLOOKUP(A2,Sheet2!A:A,1,0)),ISERROR(VLOOKUP(A2,Sheet2!B:B,1,0))),"",IF(COUNTIF(Sheet2!A:A,VLOOKUP(A2,Sheet2!A:A,1,0))>COUNTIF(Sheet2!B:B,VLOOKUP(A2,Sheet2!B:B,1,0)),"貸出中","")
 で、どうでしょうか。

 A列の数とB列の数を比較して、
 A列の ＬＯＴ№ が多かったら [貸出中] 、同数 or 全く無かったら [空白] にする。

 他の方法としては、日付で管理する　等もありそうですが、
 式も複雑になるような気もしますし...

 以上、全くの検証不足です(少しだけ忙しい...言い訳...)　　（jun53）

 横から失礼します。
 ものすごく単純に考えてしまったのですが、

 =IF(COUNTIF(Sheet1!A:A,A2)>COUNTIF(Sheet1!B:B,A2),"貸出中",IF(COUNTIF(Sheet1!A:A,A2)<COUNTIF(Sheet1!B:B,A2),"エラー！","在庫あり"))

 はずしていましたら申し訳ありません。
 (jindon)

みなみなさまありがとうございます。
色々参考にさせて頂き、なんとか問題も解決しそうです。

助かりました～（わこ）

 続きと考えられるので、こちらに統合しました。
 （kazu）

『最新データの呼出について（レンタル商品管理表の続編です。。。）』（わこ）

つい、先日レンタル商品の管理について相談させていただきました。

続いて、質問です。
皆様のご支援のもと、何とか在庫確認（貸出・返却の表示）ができるようになりました。ありがとうございました。そこで。。。

さらに欲張って、在庫データSheetで貸出先までわかるようにしたいのです。

“貸出中”の商品について、データ入力Sheetの「貸出先」セルの値を
在庫データSheetの「貸出先」にも反映させるというものです。

簡単だと思って挑んだもののなかなかうまくできません。

毎日、貸出状況を入力するsheet を sheet2 とします。

    A	　　　　B　　　　　C
 1 日付　　　　LOT　　　　貸出先
 2 2004/7/2　　123　　　　会社Ａ
 3 2004/7/2　　127　　　　会社Ｂ　
 4 2004/7/2　　130　　　　会社Ｃ
 5 2004/7/5　　126　　　　会社Ｄ
 6 2004/7/5　　123　　　　会社Ｅ

 在庫データsheet を sheet1 として以下とします。
    A	　　　　B　　　　　　C
 1 LOT　　　在庫確認　　　　貸出先
 2 123　　　　貸出中　　　　会社Ｅ
 3 124　　　　倉庫　　　　　　―
 4 125　　　　倉庫　　　　　　―
 5 126　　　　貸出中　　　　会社Ｄ
 6 127　　　　貸出中　　　　会社Ｂ
 7 128　　　　倉庫　　　　　　―
 8 129　　　　倉庫　　　　　　―
 9 130　　　　貸出中　　　　会社Ｃ

（（jun53）作成表を参考にさせていただきました。）

以上のようにSheet1のB列が“貸出中”のLot№について、

Sheet2で入力した貸出先がC列に反映するようにしたいのですが・・・

Sheet1のC列に入れるべき関数がわかりません。（涙

Sheet2について、Lot№123を見ていただくと

7/2に貸し出され、返却後、7/5で再び貸し出されています。

この場合も、7/5のSheet1では123の貸出先は最新のデータ（会社Ｅ）を表示しなければなりません。

私は条件が多くなるとどうにもこうにも・・・
この謎の解ける方助けてください。

 sheet2の25行目までを使用範囲として式を立てていますので、範囲は適当に変えてください。
 sheet2
    A 　　　　  B　　　　　C         D         E
 1 日付　　　　LOT　　　貸出先　　 返却日
 2 2004/7/2　　123　　　会社Ａ   2004/7/3     
 3 2004/7/2　　127　　　会社Ｂ　              127
 4 2004/7/2　　130　　　会社Ｃ                130
 5 2004/7/5　　126　　　会社Ｄ                126
 6 2004/7/5　　123　　　会社Ｅ                123
 sheet2のD列を返却日として、返却された日を記入するようにします。
 E2
 =IF(AND(COUNTA(A2:C2)=3,D2=""),B2,"")
 として、下にコピー。
 B2:B25を選択して、
 書式→条件付書式→数式がを選び、
 =COUNTIF($E$2:E2,B2)>1
 と入力して、適当なパターンを選びます。
 （※貸出中のLOTナンバーを入力すると、セルの色を変えて、重複入力を防ぐため。）

 sheet1の
 B2
 =IF(COUNTIF(Sheet2!$E$2:$E$25,A2),"貸出中","")
 C2
 =IF(B2="","",INDEX(Sheet2!$C$1:$C$25,MATCH(A2,Sheet2!$E$1:$E$25,)))
 として、下にコピー。
 こんな感じでいかがでしょう。
 (kkk)

ご回答感謝いたします。
参考にさせて頂いて、ちょっと検討してみますね～。（わこ）

おっ。出来ました♪
ありがとうございます！！！

Sheet1 C2=～の式が大活躍です。　（わこ）

こんばんは。
こちらのレンタル在庫管理表を参考にして在庫表を作成させて頂いているのですが、
私の能力がなさすぎて上手くいきません。
丸っきりの真似をさせて頂いております。
Sheet1は在庫データ
Sheet2は貸出状況です。（全く上記のものと同じです。）

ただ、Sheet1は在庫データと名前変更しておりますし、
Sheet2は貸出状況と名前変更しております。

以下は貼り付けです。（上記のやりとりの中で使用したい在庫表）

 sheet2（貸出状況）
    A 　　　　  B　　　　　C         D         E
 1 日付　　　　LOT　　　貸出先　　 返却日
 2 2004/7/2　　123　　　会社Ａ   2004/7/3     
 3 2004/7/2　　127　　　会社Ｂ　              127
 4 2004/7/2　　130　　　会社Ｃ                130
 5 2004/7/5　　126　　　会社Ｄ                126
 6 2004/7/5　　123　　　会社Ｅ                123

sheet1（在庫データ）

    A	　　　　B　　　　　　C
 1 LOT　　　在庫確認　　　　貸出先
 2 123　　　　貸出中　　　　会社Ｅ
 3 124　　　　倉庫　　　　　　―
 4 125　　　　倉庫　　　　　　―
 5 126　　　　貸出中　　　　会社Ｄ
 6 127　　　　貸出中　　　　会社Ｂ
 7 128　　　　倉庫　　　　　　―
 8 129　　　　倉庫　　　　　　―
 9 130　　　　貸出中　　　　会社Ｃ

Sheet1の在庫確認に貸出中と倉庫という表記が自動的に出てきてくれません。
また、貸出先も自動的に出てこないのです。B列もC列も最新の情報でなければなりませんし、
どうしたらよいのか分かりません。
もうすぐ退職するので、その前にきれいに整理したいのですが・・・
教えて頂けませんでしょうか？
宜しくお願い致します。

（櫻花）

 新たに質問しなおしたほうがいいと思うよ。

 Sheet2

 E2 =IF(AND(COUNTA(A2:C2)=3,D2=""),B2,"")   ※前のやり取りのまま。

 Sheet1

 B2 =IF(COUNTIF(貸出状況!$E$2:$E$25,A2),"貸出中","倉庫")
 C2 =IF(B2="倉庫","―",INDEX(貸出状況!$C$1:$C$25,MATCH(A2,貸出状況!$E$1:$E$25,)))

 ※前のやり取りのシート名と空白処理を変更。

 (GobGob)

GobGobさん、ありがとうございます。
新たに質問してみたいと思います。

GobGobさんの Sheet2のE2に=IF(AND(COUNTA(A2:C2)=3,D2=""),B2,"")を
入れることで、まだ貸出から返却されていないツールが自動的に出てくるようにはなりました。
本当にどうもありがとうございました。
あとは貸出中と倉庫という表示が自動的に出ることと、貸出先が自動的に出ることができれば、
問題はほぼ解決なのですが、
コピーして貼り付けるだけでは上手くはいきませんか？（泣）
何故か貸出中なのに倉庫と出たりするのですが、私には原因が分かりません。
先程、頂いた助言通り新しく質問してみました。ありがとうございます。
GobGobさんにありがとうございますというコメントをここに書きましたが、自分の名前を入れるのを忘れてしまったので、新たに書き込みさせて頂きました。　（櫻花）

 ↓もう少し話が進展した様なので、櫻花さんの　新しい質問スレへのリンクを貼っておきます。(HANA)
[[20120917164028]]　『貸出品管理をエクセルでしたい』（櫻花）

コメント返信：

[ 一覧(最新更新順) ]

[[20040701173628]] 『レンタル商品の出入りをエクセルで管理できますか』（わこ） ページの最後に飛ぶ

[[20040701173628]]　『レンタル商品の出入りをエクセルで管理できますか』（わこ）　ページの最後に飛ぶ