[[20040723163753]]　『複雑な勤務時間を分ける』（もも）　ページの最後に飛ぶ

『複雑な勤務時間を分ける』（もも）

 ＜内容＞
　
基本9時間拘束8時間勤務(昼1時間）　時間の区切りは30分切り捨て
通常出勤　　5：00～22：00の間に出勤した場合
　
通常出勤の残業　　通常出勤したときの実働8時間以降
　　
　　　深夜残業　　22：00～5：00の間
　
　
深夜出勤　　22：00～5：00の間に出勤した場合
　
日曜出勤　　日曜は時給が変わらないので通常時間と
　
　　　　　　残業時間に分けるだけ
　
祭日出勤　　5：00～22：00の間に出勤した場合
　
祭日残業　　祭日の残業は深夜残業とか関係なし
　
祭日深夜出勤　5：00～22：00の間に出勤した場合
　
 以上のルールで時間を分けなければなりません・・・
　
　
例　出勤　　退勤　　休憩　　実働　　日勤　　深夜    残業　深夜残業
   9：00　18：00　1：00　 8：00　　8：00　　0：00   0：00　0：00
  18：00　28：00　1：00　 9：00  　4：00　　4：00    0：00　1：00
　 
   出勤　　退勤　　休憩　　実働　深夜出勤　　日勤　　残業
  23：00　33：00   1:00   9:00    5：00 　　　3：00　　1：00

このほかに日曜と祭日も分けて計算して（時間のルールは上に記載した通り）
これを出勤と退勤時間の入力だけで全部分けるのは可能でしょうか・・・？

自分でやってみたのですが全然出来ません

どなたか教えていただけないでしょうか。お願いします！！！

 私も以前作ったことがありますが。。。ファイルサイズが１メガを超えてしまいました(ーー;)
 なので、どなたか聡明な方のご提案を一緒に待ちましょうか。。。(メロン２)

 複雑そうで、どこまでできるのか不安ですが・・・
取り敢ず、叩き台ということで、平日の通常勤務と深夜勤務の場合について考えてみました。
作業列が多いですが、それは我慢していただくとして・・・(^^;)
引っかかったのは、休憩時間の取り扱いです。退勤時刻から差し引いて計算してみました。
(計算の条件が見あたりません)
　
　現時点での計算結果はK～O列に表示されます。
　
A4セル：=IF(AND(C4-TIME(5,0,0)>=0,C4-TIME(22,0,0)<0),"通常","深夜")
　下へコピー
C～E列はデータを入力します。
H2:J3セルには時刻の区分を入力します。
F4セル：=C4
G4セル：=D4-E4
H4セル：=IF(OR(COUNT($F4:$G4)<2,MIN($G4,H$3)-MAX($F4,H$2)<0),0,VALUE(TEXT(MIN($G4,H$3)-MAX($F4,H$2),"[h]:mm")))
　J4までコピーし、H6～J6までコピーします。
　
	A	B	C	D	E	F	G	H	I	J　
1	体系	祝日	出勤	退勤	休憩	"出勤"	"退勤"	日勤1	深夜	日勤2	
2								5:00	22:00	29:00
3								22:00	29:00	34:00
4	通常		11:00	24:00	1:00	11:00	23:00	11:00	1:00	0:00
5	通常		18:00	28:00	1:00	18:00	27:00	4:00	5:00	0:00
6	深夜		22:00	33:00	1:00	22:00	32:00	0:00	7:00	3:00
　
K4セル：=SUM(H4:J4)
L4セル：=IF(A4="深夜",MIN("8:00",I4+J4),MIN("8:00",H4+J4))
M4セル：=MIN(I4,"8：00"-L4)
N4セル：=IF(A4="深夜",IF(I4+J4-"8：00">0,I4+J4-"8：00",0),IF(H4-"8：00">0,H4-"8：00",0))
O4セル：=IF(A4="深夜",0,IF(I4-M4>0,I4-M4,0))
　K4:O4を下方向へコピー
	K	L	M	N	O
1	実働	日勤	深夜	残業	"深夜残業"
2				
3				
4	12:00	8:00	0:00	3:00	1:00
5	9:00	4:00	4:00	0:00	1:00
6	10:00	3:00	5:00	2:00	0:00
　
　　見栄えおよびファイルサイズは一切考慮していません・・・いかがなものでしょうか?　(Hatch)

Hatchさん有難うございました。。回答頂けて嬉しいです！

Hatchさんに教えて頂いた通りに作ってみたのですがL６～O６までが
数字があいませんでした。。

L６　　　M６　　　N６　　　O６

8：00　　0：00　　2：00　　0：00

と出てしまいます。
A6を通常に直すか空白にするとHatchさんの答えと同じになるのですが・・・

他はちゃんと計算出来ました。
私の作り方がどこか間違っているかも知れませんが教えていただけますか？（もも）

 失礼しました。
L4セル：=MIN("8:00",H4+J4)
として、下方向へコピーします。
　
ところで、休憩時間の処理は上記の方法でよろしいですか?
また、計算結果に問題はないか十分検証をしてみてください。
どこかに落とし穴があるかも・・・　(Hatch)

Hatchさん出来ました！

ですが、休憩時間の処理方法を書き忘れていました・・・m(__)m

９時間拘束の真中に１時間休憩が入ります。。（出勤時間の４時間後）

この場合どうしたら良いでしょう・・・。

あと、出来れば時間を３０分切り捨てで計算できるといいのですが・・・

（これは時間を入力するときに自分で調節すればなんとかなります）

何度もすみません（もも）

 出勤時間は30分単位で切り上げ、退勤時間は30分単位で切り捨てでよろしいでようか?
F4セル：=VALUE(TEXT(CEILING(C4,"0:30"),"[h]:mm"))
G4セル：=VALUE(TEXT(FLOOR(D4-E4,"0:30"),"[h]:mm"))
といった感じになります。
ただし、休憩時間の処理はまだ考慮していません。
　
各時間区分の計算が上記でよろしければ、次は休憩時間の処理を考えることにしましょう。
(1)出勤時刻の4時間後とは、「9:15」出勤であれば、切り上げて「9:30」の4時間後の
「13:30～14:30」が休憩時間でよろしいでしょうか？
(2)4時間未満の勤務や拘束9時間未満の勤務の場合などがありますか?
　その場合も同様の処理でよろしいでしょうか?
(3)休憩時間は1時間で出勤～退勤までの間に1回だけでしょうか?
　　(長時間の勤務の場合、2回目の休憩はないですか?)
　　　(Hatch)
　
 現在の状況を書いておきます。休憩は(1)の条件としています。
計算結果はP～T列に動いています。途中に休憩時間の計算を入れました。
	A	B	C	D	E	F	G	H	I	J	K	L
1	"体系"	"祝日"	出勤	退勤	休憩	"出勤"	"退勤"	休憩始	休憩終	日勤1	休憩	深夜
2										5:00		22:00
3										22:00		29:00
4	通常		9:00	18:00	1:00	9:00	18:00	13:00	14:00	8:00	1:00	0:00
5	通常		18:00	28:00	1:00	18:00	28:00	22:00	23:00	4:00	0:00	5:00
6	深夜		23:00	33:00	1:00	23:00	33:00	27:00	28:00	0:00	0:00	5:00
　
	M	N	O	P	Q	R	S	T
1	休憩	日勤2	休憩	実働	日勤	深夜	残業	"深夜残業"
2		29:00						
3		34:00						
4	0:00	0:00	0:00	8:00	8:00	0:00	0:00	0:00
5	1:00	0:00	0:00	9:00	4:00	4:00	0:00	1:00
6	1:00	4:00	0:00	9:00	3:00	5:00	1:00	0:00
　
E4：=IF(COUNT(H4:I4)>1,I4-H4,"")
F4：=IF(C4="","",VALUE(TEXT(CEILING(C4,"0:30"),"[h]:mm")))
G4：=IF(D4="","",VALUE(TEXT(FLOOR(D4,"0:30"),"[h]:mm")))
H4：=IF(C4="","",C4+TIME(4,0,0))
I4：=IF(C4="","",C4+TIME(5,0,0))
J4：=IF(OR(COUNT($F4:$G4)<2,MIN($G4,J$3)-MAX($F4,J$2)<0),0,VALUE(TEXT(MIN($G4,J$3)-MAX($F4,J$2)-K4,"[h]:mm")))
K4：=IF(MIN($I4,J$3)-MAX($H4,J$2)<0,0,MIN($I4,J$3)-MAX($H4,J$2))
L4：=IF(OR(COUNT($F4:$G4)<2,MIN($G4,L$3)-MAX($F4,L$2)<0),0,VALUE(TEXT(MIN($G4,L$3)-MAX($F4,L$2)-M4,"[h]:mm")))
M4：=IF(MIN($I4,L$3)-MAX($H4,L$2)<0,0,MIN($I4,L$3)-MAX($H4,L$2))
N4：=IF(OR(COUNT($F4:$G4)<2,MIN($G4,N$3)-MAX($F4,N$2)<0),0,VALUE(TEXT(MIN($G4,N$3)-MAX($F4,N$2)-O4,"[h]:mm")))
O4：=IF(MIN($I4,N$3)-MAX($H4,N$2)<0,0,MIN($I4,N$3)-MAX($H4,N$2))
P4：=SUM(J4,L4,N4)
Q4：=IF(A4="深夜",MIN("8：00"-L4,J4+N4),MIN("8:00",J4+N4))
R4：=IF(A4="深夜",MIN(L4,"8:00"),MIN(L4,"8：00"-Q4))
S4：=IF(A4="深夜",IF(L4+N4-"8：00">0,L4+N4-"8：00",0),IF(J4-"8：00">0,J4-"8：00",0))
T4：=IF(A4="深夜",0,IF(L4-R4>0,L4-R4,0))
　
だんだんと、醜くなってきましたが、取り敢ずは計算の方を優先ということで・・・(^^;)　
　(Hatch)

Hatchさんお礼が遅くなってすみませんでした。

現場の責任者に休憩の時間等を確認してみましたが今のところ１時間の休憩以外は

サービスで（休憩時間扱いしない）付くみたいなので大丈夫です(｡･･｡)

早退などで４時間未満の勤務もあるかもしれないのですがその場合いは休憩を入力

しなければOKですよね！

（1）に関してもHatchさんに考えて頂いた通りで大丈夫です。

まだここの現場が始まって２週間なので変更等あるかもしれないのですが

その時はまた質問させて下さい。。

幾つかのパターンで試してみましたが今のところ問題ないです！

本当に助かりました～　　有難うございました。。

本当、ここで回答下さる皆さんすごいですね！！

あっ、休憩時間の処理方法がまだでした。。

（1）　「9:15」出勤であれば、切り上げて「9:30」の4時間後の
　　　　「13:30～14:30」が休憩時間でOKです！

（2)　　4時間未満の勤務や拘束9時間未満の勤務の場合はありますが
　　　　同様の処理で大丈夫です！

（3)　　休憩時間は今のところ1時間で出勤～退勤までの間に1回だけです。

　　色々すみません(≧σ≦)　　　　　　（もも）

 一段落ということで、ホッとしました。
かなり見苦しい表になっていますが、ご愛敬ということで・・・　(Hatch)

コメント返信：

[ 一覧(最新更新順) ]

[[20040723163753]] 『複雑な勤務時間を分ける』（もも） ページの最後に飛ぶ

[[20040723163753]]　『複雑な勤務時間を分ける』（もも）　ページの最後に飛ぶ