[[20041208145413]]　『ワークシートのAddメソッドで』（ぶー）　ページの最後に飛ぶ

『ワークシートのAddメソッドで』（ぶー）
いつもお世話になります。
素朴な疑問なのですが、よろしくお願いします。

1 Worksheets.Add Before:=Worksheets("Sheet1")

   ActiveSheet.name = "新シート"

2 Worksheets.Add(Before:=Worksheets("sheet1"),count:=3).Name:="新シート"

1と2のコードの違いなのですが、

1のコードに対して2のコードは、ADDからcount:=3がカッコで囲まれています。

その意味って何ですか？
同じ動作をするコードだと思うんですけど。
かなり初歩的な質問ですいません。

 意味というより、ただの文法でしょ。「こうやって書けば動く」といった。　
 （ 2 は間違えてるから動かないけど。:が余分。）　
  (INA)

 それとCount:=3だから3枚のシートを作りますね。
 （川野鮎太郎）

Addメソッドの構文って。

expression.Add(Before,After,Count,Type)で文法でもすでにカッコで

囲ってあるので、記述でもカッコが必要という訳ですか？

Nameプロパティーは、文法内ではないから、: は余計ですね。

（ぶー）

 こんなサンプルを示したら、何か見えますかねぇ…
　
メッセージボックスで考えると
　
Sub msg1()
    '呼び出すだけ 戻り値は無視
    MsgBox "Yes or No", vbYesNo
End Sub
Sub msg2()
    '呼び出すだけ 戻り値は無視
    Call MsgBox("Yes or No", vbYesNo)
End Sub
Sub msg3()
    Dim ReturnValue As Integer
    '戻り値を変数に格納
    ReturnValue = MsgBox("Yes or No", vbYesNo)
    If ReturnValue = vbYes Then
        MsgBox "はい が選択されました"
    Else
        MsgBox "いいえ が選択されました"
    End If
End Sub
Sub msg4()
    '戻り値を直接扱う
    If MsgBox("Yes or No", vbYesNo) = vbYes Then
        MsgBox "はい が選択されました"
    Else
        MsgBox "いいえ が選択されました"
    End If
End Sub
　
これをシートに置き換えて考えると
　
Sub test1()
    '呼び出すだけ 戻り値は無視
    Worksheets.Add Before:=Worksheets("Sheet1")
End Sub
Sub test2()
    '呼び出すだけ 戻り値は無視
    Call Worksheets.Add(Before:=Worksheets("Sheet1"))
End Sub
Sub test3()
    Dim ReturnValue As Worksheet
    '戻り値を変数に格納
    Set ReturnValue = Worksheets.Add(Before:=Worksheets("Sheet1"))
    ReturnValue.Name = Format$(Now, "yymmddhhnnss")
End Sub
Sub test4()
    '戻り値を直接扱う
    Worksheets.Add(Before:=Worksheets("Sheet1")).Name = Format$(Now, "yymmddhhnnss")
End Sub
（ご近所PG）

コメント返信：

[ 一覧(最新更新順) ]

[[20041208145413]] 『ワークシートのAddメソッドで』（ぶー） ページの最後に飛ぶ

[[20041208145413]]　『ワークシートのAddメソッドで』（ぶー）　ページの最後に飛ぶ