[[20050124152850]]　『引数は省略できません』（ちょっかく）　ページの最後に飛ぶ

『引数は省略できません』（ちょっかく）

このサイトを見て、セル内の値によってセル背景色を変えるやり方を学んだのですが、
セルの値が変更されたら実行するのではなくて、ボタンを押したら実行するようにした
いです。(最終イメージは範囲を選択してボタンを押したら選択した範囲に対してセル
内の値によってセル背景色を変更。)

以下のスクリプトの1行目を
「Sub ボタン1_Click(ByVal Target As Range)」
と変えたら「引数は省略できません。」と返されるのですが、どこの引数がいけないの
かさっぱり分かりません。

どのように記述したらよいのでしょう。助けてください。

 元の記述
===セルの値が変わったら実行する===
Private Sub Worksheet_Change(ByVal Target As Range)
'変数宣言
Dim colr As Integer
Dim c As Variant
    If Target.Count > 1 Then Exit Sub
    If Target.Column <> 1 Then Exit Sub
        For Each c In Target
            Select Case c.Value
                Case "1"
                    colr = 3  'ここの色番号をお好きなように
                Case "2"
                    colr = 4
                Case "3"
                    colr = 5
                Case "4"
                    colr = 6
                Case "5"
                    colr = 7
                Case "6"
                    colr = 8
                Case "7"
                    colr = 9
                Case "8"
                    colr = 10
                Case Else
                    colr = xlNone
            End Select
            c.Interior.ColorIndex = colr
    Next c
End Sub

 こんな感じでしょうか。
　
Sub ボタン1_Click()
'変数宣言
Dim colr As Integer
Dim c As Range
        For Each c In Selection
            Select Case c.Value
                Case "1"
                    colr = 3  'ここの色番号をお好きなように
                Case "2"
                    colr = 4
                Case "3"
                    colr = 5
                Case "4"
                    colr = 6
                Case "5"
                    colr = 7
                Case "6"
                    colr = 8
                Case "7"
                    colr = 9
                Case "8"
                    colr = 10
                Case Else
                    colr = xlNone
            End Select
            c.Interior.ColorIndex = colr
    　　Next c
End Sub

 （川野鮎太郎）

ちょっかくです。

ありがとうございました。やりたい動作ができました。

コメント返信：

[ 一覧(最新更新順) ]

[[20050124152850]] 『引数は省略できません』（ちょっかく） ページの最後に飛ぶ

[[20050124152850]]　『引数は省略できません』（ちょっかく）　ページの最後に飛ぶ