[[20050126175050]]　『特定の文字を含むセルの隣のセルに対応する文字を』（WELTEN）　ページの最後に飛ぶ

『特定の文字を含むセルの隣のセルに対応する文字を』（WELTEN）

[特定の文字を含むセルの隣のセルに対応する文字を表示させる]

 うまく説明できるか判りませんが、どうぞお知恵をお貸しください。 
 題名がほとんど内容を表しておりますが、Ｂのデータより　Ｃの様に表示したいのですが
　B　　　　　　　　　C          D       …

 DG/ALT           TY
 KORU/TOGABA      BN
 BOM/B-ALT        TY
 WIZ/G-CTRL       GH
 MOD/EN-K         BN
 WIN/IREBN        BN
 GARI/USU-CTRL    GH

 ★Ｂの列に「ALT」を含む場合は　Ｃの列に「TY」を返し
 　　　　　「CTRL」を含む場合は　Ｃの列に「GH」を返し
　　　　　　それ以外は「BN」を表示させる。
 という作業が一括でできるような関数というか、手法は無いでしょうか？

 B列のデータは500件弱あり、桁数は20桁を越えない位ですが、決まった形は無く
 現在は手作業にて強引に進めております…。 
 もう少し簡易にできないかと思うのですが、どなたかアドバイスお願いします。

 少しベタな方法ですが。
	 A	 B　　　　	 C
  1			
  2		DG/ALT　　	TY
  3		KORU/TOGABA	BN
  4		BOM/B-ALT　	TY
  5		WIZ/G-CTRL	GH
  6		MOD/EN-K　	BN
  7		WIN/IREBN　	BN
  8		GARI/USU-CTRL	GH

 C2=IF(ISERR(FIND("ALT",B2)),IF(ISERR(FIND("CTRL",B2)),"BN","GH"),"TY")			
 （川野鮎太郎）

 このようにするのは、どうでしょう？　　　　　　　　　　　　　　　　　　　　　　　(LOOKUP)
 =IF(B1="","",IF(OR(COUNTIF(B1,{"*ALT*";"*CTRL*"})),
SUBSTITUTE(IF(COUNTIF(B1,"*ALT*"),"/TY","")&IF(COUNTIF(B1,"*CTRL*"),"/GH",""),"/",,1),"BN"))

 すいません。LOOKUPさんに質問です。
 =IF(B1="","",IF(COUNTIF(B1,"*ALT*"),"TY",IF(COUNTIF(B1,"*CTRL*"),"GH","BN")))
 これだけで用を足すような気がするのですが、/入れて、あとで置換えされているのは、
 何か理由がおありなのでしょうか。LOOKUPさんのされることなので、深い意味がありそうで
 訳を知りたくて(^_^A;
 もし良かったら教えていただけませんでしょうか。m(._.)m ペコッ
 ※何かエラーが出るパターンがあるのか、頭を悩ませてます。(/-_-＼)

 判りました！！！　ALTとCTRL両方あった場合ですね。
 スッキリしました。m(._.)m ペコッ
 さすがとしか言いようがないですね。＾＾

 （川野鮎太郎）

出来ました、本当にすっきりいきました。
コピーしたセルをトルグダウンしながら感動してます。
どうもありがとうございます。
なんだか新しい手法を頂いておりますが、検索データALTとCTRLが
被ることは無いんですが…
正直どうしてベタな手法といわれるのかも判らないくらいですから。
とにかくありがとうございました。
　　　　　　　　　　　　（ＷＥＬＴＥＮ）

 いつも勉強させて頂いております。
LOOKUPさんの式にある、COUNTIF(B1,{"*ALT*";"*CTRL*"})は初めて見た形です。
B1セルにALTとCTRLの少なくとも１つがある場合に１を返す式だと思いますが、
両方がある場合に１を返す式というのはあるのでしょうか？
ご存知でしたら教えていただけますでしょうか。
(tora)

 =OR(COUNTIF(B1,{"*ALT*";"*CTRL*"}))は、どちらかがある場合がTRUE、
 =AND(COUNTIF(B1,{"*ALT*";"*CTRL*"}))が、両方ともある場合がTRUE、
 =OR(COUNTIF(B1,{"*ALT*CTRL*";"*CTRL*ALT*"}))とも書けるように思います。　　　　　(LOOKUP)

 ご教示ありがとうございました。(tora)

コメント返信：

[ 一覧(最新更新順) ]

[[20050126175050]] 『特定の文字を含むセルの隣のセルに対応する文字を』（WELTEN） ページの最後に飛ぶ

[[20050126175050]]　『特定の文字を含むセルの隣のセルに対応する文字を』（WELTEN）　ページの最後に飛ぶ