[[20050323085224]]　『入力済セルのカウント方法』（みれい）　ページの最後に飛ぶ

『入力済セルのカウント方法』（みれい）

 おはようございます。
 出勤表を作成しましたが、1つ分からないところがあります。

 　　A　　　　B　　　C　　　D　　　E　・　・　・G　　　　
 1　　　　　3/23　　3/24　3/25　　3/26
 2　　　　　　　　　休日　　　　　休日　　　　
 3　山田　　　10　　11　　10　　　8　　　　　　　2←休日出勤数
 4　渡辺　　　10　　10　　8　　　　　　　　　　　1←休日出勤数

 上表のように1行目は日付・2行目は休日・3行目以降は個人データとなっています。
 2行目の休日は、別シートの休日データから反映させています。
 この時、G列に休日出勤した日数をカウントしたいのです。
 お願いいたします。

 =SUMPRODUCT(($B$2:$E$2="休日")*(B3:E3<>""))
こんな感じでできます。範囲は直してください。
（ケン）

 ありがとうございました。
 昨日、=SUMPRODUCT(($B$2:$E$2="休日")*(B3:E3))ここまではたどり着いたのですが、
 うまくいかず困っていました。
 <>""　これはどのような意味を持つのでしょうか？
 （みれい）

 空白以外、て感じです。
（ケン）

 なるほど！ありがとうございました。
 （みれい）

 何度もすみません。
 もうひとつ質問です。
 休日の残業時間の算出もしたいのですが、カウント結果から算出して
 みたのです・・・
 9時間目以降からが残業になるのですが、
 =K3-SUMPRODUCT(($B$2:$E$2="休日")*(B3:E3<>""))*8
 こんな感じでやってみました。K3には休日の合計時間が入力されています。
 しかし！休日は8時間未満で退勤する場合もあります。
 そうするとマイナスとして算出されてしまいます。
 どのようにしたらよいのでしょう？

 よく理解してないかも知れませんが。
=K3-8ではないですか？
（ケン）違うかな？

 =SUMPRODUCT((B3:E3-8)*(B3:E3-8>0)*(B2:E2="休日"))
こう言う事かな？
（ケン）

 ありがとうございました。
 =SUMPRODUCT((B3:E3-8)*(B3:E3-8>0)*(B$2:E$2="休日"))で、コピーして出来ました。
 しかし、問題が1つ浮上してきてしまいました。
 出勤表内に、有給を取った場合「有給」と入力させています。
 有給を入力している人の欄は算出が出来ません。
 テキストデータを無視するには、どうすればいいのでしょうか？
 （みれい）

 まとめます。

 はじめの質問と内容が変わってきてしまったので、
 再度書き直します。（別スレ立てたほうがいいのかしら?）

  　　A　　　　B　　　C　　　D　　　E　・　・　・G　　　　　　　
 1　　　　　3/23　　3/24　3/25　　3/26
 2　　　　　　　　　休日　　　　　休日　　　　
 3　山田　　　10　　11　　10　　　8　　　　　　　2←休日出勤数
 4　渡辺　　有給　　10　　8　　　　　　　　　　　1←休日出勤数

 G3=SUMPRODUCT((B3:E3-8)*(B3:E3-8>0)*(B$2:E$2="休日"))で休日出勤日の
 カウントを行おうと思っていますが、出勤表内に、有給を取った場合
 「有給」と入力させています。
 有給を入力している人の欄は算出が出来ません。
 テキストデータを無視するには、どうすればいいのでしょうか？　
 文字列のみカウントする方法は検索できましたが、文字列無視の方法が
 見つかりませんでした＞＜
 　(みれい)

 休日出勤日数だけなら
 =SUMPRODUCT((B$2:E$2="休日")*ISNUMBER(B3:E3))
 でいいのでは？
 休日出勤で、8時間を超えて働いている日数とかになると、また違ってきますが。
 (kkk)

 返信いただきありがとうございます。
 すいません！！！混乱していました。
 カウントではなく、残業時間の算出でした。
 =SUMPRODUCT((B3:E3-8)*(B3:E3-8>0)*(B$2:E$2="休日"))で、
 休日の残業時間の算出をしましたが、出勤表には有給を取った場合
 「有給」と入力させています。
 有給を入力している人の欄は算出が出来ません。
 テキストデータを無視するには、どうすればいいのでしょうか？
 *残業＝9時間以降

 kazu様：削除が必要な私の書き込みがあれば、削除願います。

  （みれい）

 >*残業＝9時間以降
 と書いているのに、
 =SUMPRODUCT((B3:E3-8)*(B3:E3-8>0)*(B$2:E$2="休日"))
 で、-8となっている意味が理解できませんが？

 =SUM(IF(($B$2:$E$2="休日")*ISNUMBER(B3:E3)*(B3:E3>8),B3:E3-8))
 配列数式ですので、Ctrl + Shift + Enter 
 9時間を引くのなら、8を9に変えてください。
 (kkk)

 ありがとうございました。 バッチリです！
 残業時間は9時間目以降が残業なので、8時間までは通常勤務です。
 なので、-8となっています。
 （みれい）

コメント返信：

[ 一覧(最新更新順) ]

[[20050323085224]] 『入力済セルのカウント方法』（みれい） ページの最後に飛ぶ

[[20050323085224]]　『入力済セルのカウント方法』（みれい）　ページの最後に飛ぶ