[[20050729125246]]　『給与計算』（はぶ茶）　ページの最後に飛ぶ

『給与計算』（はぶ茶）
アルバイトの方のタイムカードから勤務時間を計算し、時給を掛けています。

1　　　　A　　　　　　　　B　　　　　　　　C　　　　　　　 D

2　　出勤時間　　退勤時間　　　労働時間　　　金額

3　　　10:00　　　　　19：00　　　　　　 9:00　　　　　 \9,000

4　　　19:00　　　　　05：00　　　　　　10:00　　　　　\10,000

日勤の方は常に時給￥1000ですが、夜勤の方の場合、23:00以降は時給￥1200になります。
ですのでＤ４の金額は間違っているという事になります。
Ｄ列に23:00までは￥1000、23:00以降は￥1200にすると言う数式は可能でしょうか？

(Ａ，Ｂ列ともにhh:mmです。)
Ｃ列の労働時間の数式は、=FLOOR(VALUE(TEXT(E2-D2,"h:mm")),"0:15")です。

他の方の質問を見て色々勉強しましたが、どうしてもこれだけ分かりませんでした。
月末と言う事もあり、焦っています。
どうか、宜しくお願い致します。

 勤務時間の計算は結構複雑になる場合が多いので、
 今後回答を続けることが出来るかどうかはわかりませんが、
 レスが付きませんので、とりあえずアドバイスだけ。

 レスが付かない理由の一つは、条件が不十分だということです。
 夜勤の方は23:00以後は別単価となるとのことですが、

 1.夜勤と日勤は明確に区分されているのか。
   それとも出勤時間がどうであれ、単に23:00以後は単価が変わるということか。
 2.夜勤の場合の出勤時刻は、0:00以後ということもありうるのか。
 3.23:00以後の単価は、翌日何時まで適用するのか。
   または、それは考慮する必要はないのか。

 など、とりあえず必要ではないかと思われることを列記しました。
 月末で急いでいるとのことですが、
 給料計算の場合などは特に急いで回答して間違っていると困りますので、
 余裕を持った時間がないと回答しづらいのも事実です。
 (sato)

条件が明確でなく、申し訳御座いませんでした。
上記のご質問の解答です。

1.10:00～23:00までが日勤、23:00～5:00が夜勤となります。

2.夜勤の場合の出勤時間が00:00以降になる事はありません。

3.23:00～5:00が夜勤です。時給は￥1200となり、7:00までの適用となります。
　考慮するとはどのような事でしょうか？

こちらの個人的な問題を表記して申し訳ありませんでした。
お手をお貸し頂ければ幸いです。
宜しくお願い致します。

(はぶ茶)

 とりあえず、E列に夜勤時間を出す作業列を設けて、

 E2=IF(AND(B2>A2,B2>"23:00"),B3-"23:00",0)+IF(A2>B2,B2+"1:00",0)

 とします。金額欄は、

 D2=(C2-E2)*24*1000+E2*24*1200

 として下にコピーしますと、上記の例ではD3の金額は \11,200 となります。
 細かい検証は時間が無いのでしておりませんのでご確認をお願いします。

 >Ｃ列の労働時間の数式は、=FLOOR(VALUE(TEXT(E2-D2,"h:mm")),"0:15")です
 この意味が上記のレイアウトでは辻褄が合わないようなので、
 考慮しておりません。
 また、出勤時刻、退勤時刻とも15分毎の切り上げ切捨ても考慮しておりません。
 (sato)

satoさん、お返事が遅くなり申し訳ありません…。
やってみたのですが、出来ませんでした。
下の表で出す場合、どのようにしたら深夜時間が出るのでしょう…？
深夜時間を出るようにしたら、普通の勤務時間が「0」になってしまいました…
何が間違っているか、色々試したのですが分かりませんでした。
satoさん！！！お力を貸して下さい！！

1　　　　A　　　　　　　　B　　　　　　　　C　　　　　　 E　　　　　　D

2　　出勤時間　　退勤時間　　　日勤時間　　　深夜時間　　　　金額

3　　　19:00　　　　　04：00　　　　　　 4:00　　　　　　5:00　　　　　 \10,000

それと大変申し訳ないのですが、日勤時間(時給￥1000)と深夜時間(時給￥1200)を別に出す事は可能ですか？

 前回の回答は、C列に通算の労働時間がすでに入力済みの前提で作ったので、
 レイアウトが変わると正しく計算されませんね。
 今回のレイアウトもちょっと作り直してみたんですが、

      A           B           C          D              E
 1  出勤時間   退勤時間	日勤時間   深夜時間        金額
 2   19:00        4:00       4:00        5:00         10,000
 3   23:00        7:00       0:00        8:00          9,600
 4    8:00       15:00       7:00        0:00          7,000
 5   13:00       23:30      10:00        0:30         10,600

 C2=IF(OR(B2>"23:00"*1,B2<="7:00"*1),"23:00"-A2,B2-A2)
 D2=IF(B2>"23:00"*1,B2-"23:00",0)+IF(B2<="7:00"*1,B2+"1:00",0)
 E3=C2*24*1000+D2*24*1200

 としてみましたが、合ってますでしょうか？
 なお、夜勤の場合は0:00以後の出勤はなく、また7:00までに退勤するものして
 考えてありますので、0:00出勤とか8:00退勤があると正しく計算されません。
 (sato)

satoさん出来ましたっっ！！！！

本当に有難う御座います！！
C2の数式をコピーしたら、出勤･退勤共に入力していない状態で23:00と出てしまうのは仕方無い事なのでしょうか？

またまたド素人で申し訳無いのですが…

この複雑な数式を変えようとすると、エラーが出てしまいました…

(はぶ茶)

 どうぞ。(sato)

 C2=IF(COUNT(A2:B2)=2,IF(OR(B2>"23:00"*1,B2<="7:00"*1),"23:00"-A2,B2-A2),"")
 D2=IF(COUNT(A2:B2)=2,IF(B2>"23:00"*1,B2-"23:00",0)+IF(B2<="7:00"*1,B2+"1:00",0),"")

satoさんすみません…

上にある計算式プラス日勤時間、夜勤時間共に15分刻みで出す場合はどうしたら良いでしょう…？

      A           B           C         　  D              E
 1  出勤時間   退勤時間　　　日勤時間       深夜時間        金額
 2   19:00        4:20      　 4:00        5:15         10,300
 3   18:44        4:00       　4:15        5:00         10,250

と言うように出したいんです…。

本当に何度も何度も申し訳無いのですが、これが出来れば完璧です！！

最後のお願いです！！

出勤時間と深夜時間を15分刻みで出す方法を教えて下さい！！

 数式がどんどん長くなりますが、

 C2=IF(COUNT(A2:B2)=2,IF(OR(B2>"23:00"*1,B2<="7:00"*1),"23:00"-CEILING(A2,"0:15")
   ,FLOOR(B2,"0:15")-CEILING(A2,"0:15")),"")

 D2=IF(COUNT(A2:B2)=2,IF(B2>"23:00"*1,FLOOR(B2,"0:15")-"23:00",0)
   +IF(B2<="7:00"*1,FLOOR(B2,"0:15")+"1:00",0),"")

 ではどうでしょうか。
 (sato)

完璧に出来ました！！！

satoさん、お忙しい中本当にどうも有難う御座いました！！

丁寧で分かりやすく、凄く助かりました。

(はぶ茶)

コメント返信：

[ 一覧(最新更新順) ]

[[20050729125246]] 『給与計算』（はぶ茶） ページの最後に飛ぶ

[[20050729125246]]　『給与計算』（はぶ茶）　ページの最後に飛ぶ