[[20060119172622]]　『条件付で一定期間の合計金額を計算』（いっぺい）　ページの最後に飛ぶ

『条件付で一定期間の合計金額を計算』（いっぺい）

 A     B     　C          D         E
 1    A社  2004/03/21　\10,000   納期遅れ
 2　  B社　2004/04/15　\15,000
 3    A社　2004/08/17  \12,000
 4    B社  2004/10/20  \16,000
.
.
 20   A社　2006/01/19  \13,000　 納期遅れ

 ①A社(B1:B20)の2004/03/21～2005/03/20迄(C1:C20)の合計金額(D2:D20)の計算式
 ②A社(B1:B20)の2004/03/21～2005/03/20迄(C1:C20)の納期遅れ件数(D2:D20)の計算式

 初心者ですが、宜しくお願いします。

 WindowsXP
 Excel2003

 （A案)
 =SUMPRODUCT((B2:B21="A社")*(C2:C21>=DATE(2004,3,21))*(C2:C21<=DATE(2005,3,20)),D2:D21)
 納期遅れの金額
 =SUMPRODUCT((B2:B22="A社")*(C2:C22>=DATE(2004,3,21))*(C2:C22<=DATE(2005,3,20))*(E2:E22="納期遅れ"),D2:D22)
 納期遅れの件数
 =SUMPRODUCT((B2:B22="A社")*(C2:C22>=DATE(2004,3,21))*(C2:C22<=DATE(2005,3,20))*(E2:E22="納期遅れ"))

 作業列等を使っていいなら、
	A	B	C	D	E	F	G	H	I	J
1	No	会社名	日付	金額	備考		会社名	日付	日付	備考
2	1	A社	2004/3/21	\10,000	納期遅れ	1	A社	>=2004/3/21	<=2005/3/20	納期遅れ
3	2	B社	2004/4/15	\15,000		0				
4	3	A社	2004/8/17	\12,000		2				
5	4	B社	2004/10/20	\16,000		0				
	.					0				
	.					0				
20	20	A社	2006/1/19	\13,000		0				
として、
 （B案)F列を作業列にして、F2に
 =IF(AND(B2="A社",C2>=DATE(2004,3,21),C2<=DATE(2005,3,20),E2="納期遅れ"),1,
IF(AND(B2="A社",C2>=DATE(2004,3,21),C2<=DATE(2005,3,20)),2,0))
 として、下方向へフィルハンドルをドラッグしてコピー
 =SUMIF($F$2:$F$21,">=1",$D$2:$D$21)
 納期遅れの金額
 =SUMIF($F$2:$F$21,1,$D$2:$D$21)
 納期遅れの件数
 =COUNTIF($F$2:$F$21,1)

 （C案)G1:J2を作業列にして、
 =DSUM($A$1:$E$19,4,G1:I2)
 納期遅れの金額
 =DSUM($A$1:$E$19,4,G1:J2)
 納期遅れの件数
 =DCOUNT($A$1:$E$19,4,G1:J2)
 といったような数式が考えられます。　　(Hatch@Excel2002)

回答ありがとうございます！！
これで家に帰れます。

お世話になりました。m(__)m

コメント返信：

[ 一覧(最新更新順) ]

[[20060119172622]] 『条件付で一定期間の合計金額を計算』（いっぺい） ページの最後に飛ぶ

[[20060119172622]]　『条件付で一定期間の合計金額を計算』（いっぺい）　ページの最後に飛ぶ