[[20060202104935]]　『時間の表示』（だい）　ページの最後に飛ぶ

『時間の表示』（だい）

時間の表示で

Ａ1　1/4 10:00
Ｂ1　1/4 17:00
Ｃ1　6時間

Ａ2　1/5 8:00
Ｂ2　1/5 17:00
Ｃ2　1日

Ａ3　1/6 13:00
Ｂ3　1/6 17:00
Ｃ3　4時間

１２時から１３時までの時間は表示しないで、こういう風に表示するにはどうすればいいのでしょうか。どなたか分かる方教えてください。

 ◆作成途中です！
 	A	　B	　　　　　C
 1	1/4 10:00	　1/4 17:00	6時間
 2	1/5 8:00	　1/5 17:00	8時間
 3	1/6 13:00	　1/6 17:00	4時間

 C1=B1-A1-IF((MOD(A1,1)<=--"12:00")*(MOD(B1,1)>=--"13:00"),"1:00",0)

 ★表示形式を、ユーザー定義で、　h"時間"  にしてください！

 ◆確認！実働8時間で、「1日」でしょうか？実働が9時間の場合はどのような表示になるのでしょうか？
 ◆以上の点が不明のため、とりあえず上記内容で回答しました！
 （Maron）

ありがとうございます！
勤務時間は８時から１７時までで、途中１２時から１３時まで休憩が入ります。
なので実際働いている時間は８時間です。

 ◆8時間までしかないか、8時間以上でも、「1日」との表示でよければ！
 ★表示形式を、ユーザー定義で、　[>0.33333332]"1日";h"時間"  とすれば、とりあえずご希望のような表示になります！
 （Maron)

上の計算式入力したら出てきました！ありがとうございます。
もう一つ教えてもらいたいのですが、

     Ａ　       Ｂ　      Ｃ　　　　Ｄ　　　　　　Ｅ　　　Ｆ

１ 2/2 10:00 2/2 17:00 6時間　　6時間　　　　20日　　17日6時間

２ 2/3 8:00　 2/3 17:00 1日　　　1日6時間

３ 2/4 13:00 2/4 17:00　 4時間　　2日2時間

という風にＤのところに累計を出して、Ｅ・Ｆの欄で２０日から累計を引いた日数を
出すにはどのようにすればいいのでしょう？質問ばかりで申し訳ないのですがどなたか
分かる方教えていただけないでしょうか？

 レスが付かないので・・・、参考程度で見て下さい。
D列への表示がなければ、すごく楽なんですけどね。

 まず、【表示形式】ですが、
 C列は、現状のMaronさんが提示されているままお使い下さい。
 D列とF列は、[>=1]d"日"h"時間";h"時間"　として下さい。　6時間・1日6時間・2日0時間　という感じになります。
『2日』のみにする方法は、私には考え付きません。
 E列は、0"日"

 次に【数式】ですが、
 C1セル：
=IF(B1-A1-IF((MOD(A1,1)<=--"12:00")*(MOD(B1,1)>=--"13:00"),"1:00",0)>=--"8:00",--TEXT("8:00","h:mm"),--TEXT(MOD(B1-A1-IF((MOD(A1,1)<=--"12:00")*(MOD(B1,1)>=--"13:00"),"1:00",0),1),"h:mm"))
とし、下方コピー。
 D1セル：
=INT(C1)*"8:00"+MOD(C1,1)
 D2セル：
=INT(SUM(INT(D1)*"8:00",MOD(D1,1),INT(C2)*"8:00",MOD(C2,1))/"8:00")+MOD(SUM(INT(D1)*"8:00",MOD(D1,1),INT(C2)*"8:00",MOD(C2,1)),"8:00")
とし、下方コピー。
 E1セル：20　と手入力。
 F1セル：
=INT(((E1-INT(D3))*"8:00"-MOD(D3,1))/"8:00")+MOD((E1-INT(D3))*"8:00"-MOD(D3,1),"8:00")
 この式は、
=INT((E1*"8:00"-SUM(C1:C3))/"8:00")+MOD(E1*"8:00"-SUM(C1:C3),"8:00")
でも大丈夫です。上のはD列を使い、下のは、C列を使った式です。
以上です。
文字列にして計算する方法や作業列を使う方法も考えましたが、これが一番簡単そう。
 尚、分単位での計算は、考慮に入れてませんので、アレンジ出来るかどうか分かりません。
(sin)

コメント返信：

[ 一覧(最新更新順) ]

[[20060202104935]] 『時間の表示』（だい） ページの最後に飛ぶ

[[20060202104935]]　『時間の表示』（だい）　ページの最後に飛ぶ