[[20060417232205]]　『最大値と最小値を検索し何月の数値かを自動的に表』（オレンジ）　ページの最後に飛ぶ

『最大値と最小値を検索し何月の数値かを自動的に表示させたい』（オレンジ）

　　1月　　2月　　3月　　4月

い　　5　　 10　　7　　　20

ろ　　8　　　9　　10　　　15

は　 4　　 25 　　33 　 28

 上記のような1月から12月までの商品別の売上表があり、
　商品ごとに最大値と最小値を検索して
　その数字が何月のものかを自動的に表示させたいのです。
　MAX関数、MIN関数とHLOOKUP関数を組み合わせてみたのですがうまくいきません。
　どなたか教えていただけないでしょうか？

 間違ってましたので、削除しました。

 とりあえず表示の例題には対応させてみました。
	 [A]	 [B]	 [C]	 [D]	 [E]	 [F]	 [G]
 [ 1]		1月	2月	3月	4月	最大月	3月
 [ 2]	い	5	10	7	20	最小月	1月
 [ 3]	ろ	8	9	10	15		
 [ 4]	は	4	25	33	28

 G1=INDEX(B1:E1,IF(ISNA(MATCH(MAX(B2:E4),B2:E2,0)),IF(ISNA(MATCH(MAX(B2:E4),B3:E3,0)),IF(ISNA(MATCH(MAX(B2:E4),B4:E4,0)),"",MATCH(MAX(B2:E4),B4:E4,0)),MATCH(MAX(B2:E4),B3:E3,0)),MATCH(MAX(B2:E4),B2:E2,0)))
 G2=INDEX(B1:E1,IF(ISNA(MATCH(MIN(B2:E4),B2:E2,0)),IF(ISNA(MATCH(MIN(B2:E4),B3:E3,0)),IF(ISNA(MATCH(MIN(B2:E4),B4:E4,0)),"",MATCH(MIN(B2:E4),B4:E4,0)),MATCH(MIN(B2:E4),B3:E3,0)),MATCH(MIN(B2:E4),B2:E2,0)))

 （川野鮎太郎）

	A	B	C	D	E	F   ･･･	M	N	O	P
1	商品名	1月	2月	3月	4月	5月 ･･･	12月	合計	最大月	最小月
2	い	5	10	7	20			42	4月	1月
3	ろ	8	9	10	15			42	4月	1月
4	は	4	25	33	28			90	3月	1月

 >商品ごとに最大値と最小値を検索してその数字が何月のものかを自動的に表示させたいのです

 O2=IF(B2="","",INDEX($B$1:$M$1,MATCH(MAX(B2:N2),B2:N2,0)))
 P2=IF(B2="","",INDEX($B$1:$M$1,MATCH(MIN(B2:M2),B2:M2,0)))

 (Maron)

 ＞商品ごとに
 ↑読み損ねていたので無駄に長い式を挙げました・・・＿/￣|○ il||li

 （川野鮎太郎）

 突然横からですみません。
 いつも大変参考にさせてもらっています
 (Maron)さんの答えで
 O2=IF(B2="","",INDEX($B$1:$M$1,MATCH(MAX(B2:N2),B2:N2,0)))
 の N2 のところは M2 の誤りかなと思ったのですが、、
 (たどころ)

 ◆たどころさん、そうですね、間違っていますね。
 ◆フォローありがとうございます
 (Maron)

 川野様、Maron様ご回答ありがとうございました。
 その通りに数式を入力して出来ました!!!本当にすごいです。
 何時間も悩んだのにあっという間に解決していただきました。
 心から、お礼申し上げます。
 それと、出来ればお聞きしたいのですが、川野さんやMaronさんは
 数式バーに直接この数式を入力して回答を導き出されたのでしょうか？
 私は、なにしろ初心者のため関数は、
 関数の挿入ウィンドウから入力しているのですが、
 このようにネストで関数が複数組み合わさっている場合には
 関数の挿入のアイコンから関数を選択して回答を出すことは難しいのでしょうか？

 （オレンジ）

 関数の挿入のアイコンから、全てを直接入力するのは難しいと思います。
 私の場合は、はじめに大枠でどの式を使うか考え、今回の場合はINDEX関数がそうなります。
 次にINDEX関数の引数を出すにはどの関数が使えるかを考えます。
 さらにその関数の引数に何を使うか、って感じの繰り返しですね。
 関数の挿入のアイコンからINDEX関数を入力します。
 そのときの引数には、取り合えず適当な数値を入れておけば良いです。
 で、その引数だけを算出するために、別のセルに数式を入れます。
 今回の場合は、MATCH関数です。
 そのMATCH関数の引数が、MAX関数なので、MAX関数も別のセルに入れておけば、
 繰り返し修正するときにも楽です。
 全てを組み合わせて正解が出たときに、
 数式バー内で、全部をつなぎ合わせてます。(^_^A;

 おそらく達人と呼ばれる方たちも、大体はそんな感じだと思いますよ(^_^A;
 違ってたらペコリ(o_ _)ｏ))

 追加：逆に内側から考えたほうが早い場合もあります。
 MAX関数で出た数値が、どこにあるかを、どの関数で探す（MATCH関数、LOOKUP関数など）か、
 出てきた数値を使える関数（INDEX関数、OFFSET関数、CHOOSE関数などなど）は何かって感じで。

 （川野鮎太郎）

大変参考になりました。
ご親切に教えていただき、有難うございました。
頑張って勉強します。
（オレンジ）

コメント返信：

[ 一覧(最新更新順) ]

[[20060417232205]] 『最大値と最小値を検索し何月の数値かを自動的に表』（オレンジ） ページの最後に飛ぶ

[[20060417232205]]　『最大値と最小値を検索し何月の数値かを自動的に表』（オレンジ）　ページの最後に飛ぶ