[[20060703014002]]　『他のブックから指定のシートをコピー抽出』（ばらぶ）　ページの最後に飛ぶ

『他のブックから指定のシートをコピー抽出』（ばらぶ）

こんにちは、またまた質問させていただきます。

ＢＯＯＫ１にシートが３つ
ＢＯＯＫ２にシートが２つあります。

上記２ＢＯＯＫは入力のみで関数はあるもののマクロはなし

作業ＢＯＯＫ３で上記ＢＯＯＫ内にある指定したシートをシートごと呼び出すことがＶＢＡで出来るのでしょうか？

あくまでシートはコピーでＢＯＯＫ１ＢＯＯＫ２は変更はなしです。

「ＢＯＯＫ３でマクロを起動するとＢＯＯＫとシートを選択でき、コピー挿入できる。」

こんな都合のいいこと出来ますか？

よろしくお願いします。

WindowsXP
Excel2000

 文面からは「マクロの記録」でできそうな内容ですが、
記録したマクロでは対応できない部分がある、ということですか？
(みやほりん)(-_∂)b

お返事有難うございます。

説明のが分かりにくくてすいません。。

マクロで記録すると指定の場所にある指定したブックしか挿入できませんでした。

又、ブックの保存場所が変わるとうまくいきません。

出来れば起動すると

『ブックを選択をきいてきて⇒選択⇒シートの選択を聞いてきて

　⇒選択⇒シートをコピー挿入⇒選択したＢＯＯＫを保存せずに終了』

ＢＯＯＫ３のみ開いた状態

をしたいのです。無理でしょうか？

（ばらぶ）

「開く」ダイアログボックスから任意のブックを開くコードは次のようなコードで。
　

 Dim myPath As String 
    myPath = Application.GetOpenFilename(("Excel ファイル (*.xls), *.xls"), , "ブックを選択して下さい。") 
    If myPath = "False" Then Exit Sub 
    Set wb_A = Workbooks.Open(myPath) 
　
【参考】下記のINAさんのコードを参考
[[20040915105039]] 『複数ブックの特定シートを合体』（ran）
　
問題はシート選択の部分。
運用の部分で質問します。
ただ、Book1,Book2はシート挿入のための雛形としてだけ存在でしょうか。
それとも、何か編集した結果としてのコピーシートが必要、ということでしょうか。
（雛形なら、シートコピーよりも、テンプレートのほうが便利）
(みやほりん)(-_∂)b

みやほりんさんお返事ありがとうございます。

ブックの選択、呼び出しコードありがとうございます。

ブックの呼び出しは可能になりました！！が、シートについては依然？？？です。

ヾ（ＴｚＴ;）スイマセン

＞運用の部分で質問します。

＞ただ、Book1,Book2はシート挿入のための雛形としてだけ存在でしょうか。

上記質問で、

運用内容：月間機器集計作業

運用手順：ＢＯＯＫ１に月別機器稼動一覧が手入力されています。

　　　　　シート名「0607（年月）」三ヶ月保存（３シート）

　　　　　ＢＯＯＫ２に機器別稼動一覧が手入力されています。

　　　　　シート名「機種」２種類（２シート）

　　　　　ＢＯＯＫ１・２共時間やＶＬＯＯＫＵＰ等簡単な関数が含まれています。

　　　　　ＢＯＯＫ１・２の入力作業は同僚が行っておりフロッピーで受け渡しをしています。

　　　　　２つのブックを受け取り、私が手作業でＢＯＯＫ３にシートをコピー挿入し、

　　　　　その２つを使って（ＶＢＡ）集計を行っています。

　　　　　最後にそのシートを削除しています。（データが多いため）

やりたいことは、毎回シートを手作業でコピーすることが省けないかということです。

＞（雛形なら、シートコピーよりも、テンプレートのほうが便利）

なので雛形に該当しないと思います（間違ってたらすいません。多分・・）

【参考】ＩＮＡさんのコードを拝見させていただきました。

「シートを合体」というわけではないのですが、コード内容を

とてもすぐには理解できないので少しづつ勉強したいとおもいます。

シートを合体出来るならシートをコピー挿入も出来そうな気がしてきました。

○）＞ｏ＜（○

（ばらぶ）

すいませんがもう少しお知恵をお貸しください。。

ｍ（ＵＵ;）ｍ

（ばらぶ）

 Book3に登録したマクロと仮定して、ざっくり次のようなコードで
「ブック選択＞シート選択＞Book3へ選択シートコピー＞選択したブック閉じる」
という動作になると思います。
　
 Sub BookAndSheetSelect()
      Dim Flag As Boolean
      Dim myPath As String, msg As String, shName As String
      Dim wb_A As Workbook, Sh As Worksheet
         myPath = Application.GetOpenFilename(("Excel ファイル (*.xls), *.xls"), , "ブックを選択して下さい。")
         If myPath = "False" Then Exit Sub
         Set wb_A = Workbooks.Open(myPath)
         For Each Sh In wb_A.Worksheets
             msg = msg & Sh.Name & Chr(10)
         Next
         msg = msg & "シート名を入力してください"
         Do
             shName = InputBox(msg, "シート選択")
             For Each Sh In wb_A.Worksheets
                 If shName = Sh.Name Then Flag = True
             Next
             If Not Flag Then shName = ""
         Loop While Len(shName) = 0
         wb_A.Worksheets(shName).Copy before:=ThisWorkbook.Sheets(1)
         wb_A.Saved = True
         wb_A.Close
         Set wb_A = Nothing
 End Sub
　
シート名入力の場面では、大文字小文字、全角半角は区別され、一字でも違うと
再入力を促されます。
(みやほりん)(-_∂)b

みやほりんさん

どうも有難うござます。

完璧です！！！（思ってた通りの作業が出来ました！）

感謝感激雨あられですっ。

Ｋ（＞д＜）Ｋ

このコードを自分で理解できるよう頑張って勉強していきたいと思います。

本当に本当に有難うございました！！

（ばらぶ）

コメント返信：

[ 一覧(最新更新順) ]

[[20060703014002]] 『他のブックから指定のシートをコピー抽出』（ばらぶ） ページの最後に飛ぶ

[[20060703014002]]　『他のブックから指定のシートをコピー抽出』（ばらぶ）　ページの最後に飛ぶ