[[20060811134237]]　『改ページ設定』（しんぼー）　ページの最後に飛ぶ

『改ページ設定』（しんぼー）

 エクセル２０００、ＯＳ：Ｗｉｎ９８を使用しています。

 とあるエクセルシートを印刷しようと、マクロにて改ページを設定する
 マクロを組みましたが、思うように設定できません。

 ActiveSheet.PageSetup.PrintArea = "$A$1:$W$400" ’印刷範囲

 ActiveSheet.PageSetup.Orientation = xlPortrait　’印刷向き
 ActiveSheet.PageSetup.PaperSize = xlPaperA4　　 ’用紙サイズ
 ActiveSheet.PageSetup.Zoom = False　　　　　　　’拡大縮小
 ActiveSheet.PageSetup.FitToPagesWide = 1　　　　’横
 ActiveSheet.PageSetup.FitToPagesTall = 2　　　　’縦

 Set ActiveSheet.HPageBreaks(1).Location = Range("A210")　　’改ページ設定

 このようにマクロを組んでいます。最後の改ページ設定でエラーが出るのですが
 なぜかよく分かりません。
 アプリケーションの定義のエラーと出ます。エラー１００４・・・

 宜しくお願いします。

 なぜにSetステートメント？
 (ROUGE)

 マクロを記録したらそうなったので・・・
 しんちゃん

 ActiveSheet.HPageBreaks.Add Range("A210")
 では？
 (ROUGE)

 回答ありがとうございます。
 A210で改ページされません・・・
　しんちゃん

 これでどないでっか？
 (ROUGE)
'----
    With Worksheets("とあるエクセルシート")
        With .PageSetup
            .PrintArea = "$A$1:$W$400"
            .Orientation = xlPortrait
            .PaperSize = xlPaperA4
            .Zoom = False
            .FitToPagesWide = 1
            .FitToPagesTall = 2
        End With
    Set .HPageBreaks(1).Location = .Range("A210")
    End With

 ROUGE様　ありがとうございます。
 早速試してみました。しかし、エラーは出ないのですが
 改ページの設定がうまくいかず、"A210”にならないのです。
 たぶんデフォルトのページの切れ目のまま・・・

 手動で改ページを動かすと普通に動くんですが・・・

 これでどうですか？
 (ROUGE)
'----
Sub test()
    Dim ws As Worksheet
    Set ws = ActiveSheet
    Application.ScreenUpdating = False
    With Worksheets("とあるエクセルシート")
        .Activate
        With .PageSetup
            .PrintArea = "$A$1:$W$400"
            .Orientation = xlPortrait
            .PaperSize = xlPaperA4
            .Zoom = False
            .FitToPagesWide = 1
            .FitToPagesTall = 2
        End With
    If ActiveWindow.View = xlNormalView Then
        ActiveWindow.View = xlPageBreakPreview
        Set .HPageBreaks(1).Location = .Range("A210")
        ActiveWindow.View = xlNormalView
    Else
        Set .HPageBreaks(1).Location = .Range("A210")
    End If
    End With
    ws.Activate
    Set ws = Nothing
    Application.ScreenUpdating = True
End Sub

 ROUGE さま　ありがとうございます。

 希望するものがようやくできました。
 どういう原理でできるようになったかが不明ですが、
 とにかく助かりました。ありがとうございました。

 しんちゃん

 ページ区切り位置は、改ページプレビューになっていないと変更できないみたいです。
 改ページプレビューを変更するには、Windowオブジェクトを弄くらないとだめみたいでした。
 (ROUGE)

コメント返信：

[ 一覧(最新更新順) ]

[[20060811134237]] 『改ページ設定』（しんぼー） ページの最後に飛ぶ

[[20060811134237]]　『改ページ設定』（しんぼー）　ページの最後に飛ぶ