[[20060828142949]]　『データ振り分けについて』（りょう）　ページの最後に飛ぶ

『データ振り分けについて』（りょう）

データ整理を行いたいのですが重複したもの（人、値）のデータをひとつにまとめる方法はないでしょうか？

例

番号　　　　　　値

１　　　　　　　１００

２　　　　　　　１００

３　　　　　　　１５０

４　　　　　　　１５０

１　　　　　　　１００

２　　　　　　　１５０

３　　　　　　　２００

４　　　　　　　２００

５　　　　　　　３００

６　　　　　　　４００

↓　　上記のようなデータを下記のようにまとめたいです。

番号　　　　　　値

１　　　　　　　２００

２　　　　　　　２５０

３　　　　　　　３５０

４　　　　　　　３５０

５　　　　　　　３００

６　　　　　　　４００

のように同じ番号で値をまとめたいのですがどうしたらよいでしょうか？

 データ→統合はいかがでしょう？
 あと、ピボットテーブルというのもあります。　(Hatch)

初歩的なしつもんで申し訳ないです。
ありがとうございました。

 関数でやってみました。
 D2:E2以下に抽出、集計しています。
 D2=IF(COUNT(0/FREQUENCY($A$2:$A$11,$A$2:$A$11))<ROW($A1),"",INDEX($A$2:$A$11,
    SMALL(IF(FREQUENCY($A$2:$A$11,$A$2:$A$11)>0,ROW($A$1:$A$10),""),ROW($A1)),))
 としてCtrl+Shift+Enterで数式を確定。

 E2=IF(COUNT(0/FREQUENCY($A$2:$A$11,$A$2:$A$11))<ROW($A1),"",SUMIF($A$2:$A$11,D2,$B$2:$B$11))
 として普通にEnterで数式を確定。
 D2:E2を選択して、必要分下にフィルドラッグします。
 いかがですか？
 (ROUGE)

 統合がよいと思いますが、LOOKUPも数式でリンクさせるものも試しに書いてみました。　　　(LOOKUP)

 C2に=IF(COUNT(A2:A11),MIN(A2:A11),"")
 C3に=IF(C2="","",IF(C2=MAX(A$2:A$11),"",LARGE(A$2:A$11,RANK(C2,A$2:A$11)-1)))
 C3をC11までフィルドラッグ。
 D2に=IF(COUNT(C2),SUMIF(A$2:A$11,C2,B$2:B$11),"")として、D11までフィルドラッグ。

 	A	B	C	D
 			=IF(COUNT(A2:A11),MIN(A2:A11),"")
 1	番号	値	↓	
 2	1	100	1	200
 3	2	100	2	250
 4	3	150	3	350
 5	4	150	4	350
 6	1	100	5	300
 7	2	150	6	400
 8	3	200		
 9	4	200		 ↑
10	5	300		=IF(COUNT(C2),SUMIF(A$2:A$11,C2,B$2:B$11),"")
11	6	400	↑	
			=IF(C2="","",IF(C2=MAX(A$2:A$11),"",LARGE(A$2:A$11,RANK(C2,A$2:A$11)-1)))

コメント返信：

[ 一覧(最新更新順) ]

[[20060828142949]] 『データ振り分けについて』（りょう） ページの最後に飛ぶ

[[20060828142949]]　『データ振り分けについて』（りょう）　ページの最後に飛ぶ