[[20061115093805]]　『Ａ列のデータをＢ列に表示したい』（正）　ページの最後に飛ぶ

『Ａ列のデータをＢ列に表示したい』（正）

いつもお世話になります。
教えてください。

	   A	         B
1	108-1	      108-1
2	110-1	      110-1
3	110-1	      112-1
4	112-1	      1124A-10
5	1124A-10       1124A-20
6	1124A-10	
7	1124A-10	
8	1124A-20	
9	1124A-20	
10	1124A-20

Ａ列に文字コードが昇順で入っています。

Ｂ列に同じコードは出さないようにコピーしたいのです。

Ｂ１以下にどのような数式を入れればよいのでしょうか。

ＸＰ、ＥＸ2003

 B1に=IF(A1="","",A1)。
 B2に=IF(OR(B1="",B1=A$10),"",""&LOOKUP(B1,A$1:A$9,A$2:A$10))
 として、B2をB10までフィルドラッグ。というものは、どうでしょう？　　　　(LOOKUP)

 B1=INDEX($A$1:$A$10,SMALL(IF(MATCH($A$1:$A$10,$A$1:$A$10,0)=ROW($A$1:$A$10),ROW($A$1:$A$10)),ROW(A1)),1)
 といれて、 Ctrl + Shift + Enter として確定し、下行へコピーでは？
   (SS)

(LOOKUP)　様

ご教授有難うございました。
希望通りの答えが得られました。
早速利用させていただきます。

""&LOOKUPとLOOKUPとはどう違うのでしょうか？
教えていただけませんか。

 (SS)　様

ご教授有難うございました。
希望通りの答えが得られました。

しかし下行へコピーした場合に空白のセルに#NUM!が表示されます。

#NUM!が表示され無いようにするにはどう変更すればよろしいでしょうか。
後学のため、教えてくださいませんか。

 ""&を付加したのは、A1:A10の下のほうに未入力セルがある場合の措置です。
 これを付けませんと、表示行の最下段に0が表示される場合があります。

 LOOKUP(B1,A$1:A$9,A$2:A$10)は、LOOKUP()やMATCH(…,…,1)、VLOOKUP(…,…,…,TRUE)が、
 昇順に隙間なく並んでいるデータを検索すると、一致した同一データの最下段を戻すことを
 利用したものです。
 しかし、文字列の並び替えと、これらの関数との整合性が、厳密に保証されているかどうかは、
 気にかかるところでは、あります。　　　　　　　　　　　　　　　　　　　　　　(LOOKUP)

 >>#NUM!が表示され無いようにするにはどう変更すればよろしいでしょうか。

 ですよね。失礼しました。
 チョット式は長くなりますが、こんなのでは？
 =IF(COUNT(IF(MATCH($A$1:$A$10,$A$1:$A$10,0)=ROW($A$1:$A$10),
ROW($A$1:$A$10)))>ROW(A1),INDEX($A$1:$A$10,SMALL(IF(MATCH
($A$1:$A$10,$A$1:$A$10,0)=ROW($A$1:$A$10),ROW($A$1:$A$10)),ROW(A1)),1),"")
   (SS)

(LOOKUP)　様

早速有難うございました。
勉強させていただきます。　
　　　　　　　　　　　　　(正）

(SS)　様

早速有難うございました。
勉強させていただきます。　
　　　　　　　　　　　　　(正）

コメント返信：

[ 一覧(最新更新順) ]

[[20061115093805]] 『Ａ列のデータをＢ列に表示したい』（正） ページの最後に飛ぶ

[[20061115093805]]　『Ａ列のデータをＢ列に表示したい』（正）　ページの最後に飛ぶ