[[20070517115846]]　『２つの検索条件に一致する場合、初出データの行だ』（たかし）　ページの最後に飛ぶ

『２つの検索条件に一致する場合、初出データの行だけに一致するデータの合計を表示する』（たかし）

	[A]	[B]	[C]	[D]
[1]	東京	鈴木	1,000		
[2]	千葉	佐藤	2,000		
[3]	埼玉	田中	  500		
[4]	群馬	伊藤	1,500		
[5]	千葉	藤田	2,000		
[6]	栃木	鈴木	1,000		
[7]	東京	鈴木	  500		
[8]	埼玉	田中	3,000		
[9]	群馬	斉藤	2,000		
[10]	東京	鈴木	1,000

上のようなデータがあったときに、[A]、[B]とも一致する場合、初出行の[D]だけに[C]の合計を表示することはできないでしょうか。
初心者です。よろしくお願いします。

(Excel2003)

(WindowsXP)

 こんにちは～♪

 D1セルへ

 =IF(SUMPRODUCT(($A$1:A1=A1)*($B$1:B1=B1))=1,SUMPRODUCT(($A$1:$A$20=A1)*($B$1:$B$20=B1)*($C$1:$C$20)),"")

 下にコピーします。。。

 ★SUMPRODUCTを２つも使うので
 データ行が多い場合は、重くなりますので
 作業列を使った方が良いかも知れません。。。

 ご参考にどうぞ。。。

 。。。Ms.Rin～♪♪

 ふたたび～です。。。♪

 ★作業列を使った方法です。。。

	A	B	C	D	E
[1]	東京	鈴木	1000	2500	東京鈴木
[2]	千葉	佐藤	2000	2000	千葉佐藤
[3]	埼玉	田中	500	3500	埼玉田中
[4]	群馬	伊藤	1500	1500	群馬伊藤
[5]	千葉	藤田	2000	2000	千葉藤田
[6]	栃木	鈴木	1000	1000	栃木鈴木
[7]	東京	鈴木	500		東京鈴木
[8]	埼玉	田中	3000		埼玉田中
[9]	群馬	斉藤	2000	2000	群馬斉藤
[10]	東京	鈴木	1000		東京鈴木

 E列を作業列にします。。。

 E1セルへ
 =A1&B1 
 下にコピーします。。。

 D1セルへ
 =IF(COUNTIF($E$1:E1,E1)=1,SUMIF(E:E,E1,C:C),"")

 下にコピーします。。

 。。。Ms.Rin～♪♪

ご指導ありがとうございます。
実際のデータは２０００以上の数があるので、どちらにするか考えて使わせていただきます。
本当にありがとうございました。

コメント返信：

[ 一覧(最新更新順) ]

[[20070517115846]] 『２つの検索条件に一致する場合、初出データの行だ』（たかし） ページの最後に飛ぶ

[[20070517115846]]　『２つの検索条件に一致する場合、初出データの行だ』（たかし）　ページの最後に飛ぶ