[[20071220171527]]　『１セルにある漢字と仮名の分別方法』（乃愛）　ページの最後に飛ぶ

『１セルにある漢字と仮名の分別方法』（乃愛）

 いつもこちらでは勉強させていただき皆様に感謝しております。

 過去のログを調べたのですが、わかりませんでしたので、
 ご教示いただければと思い、投稿させていただきました。

 タイトル通りですが、以下に例を挙げさせていただきます。

 　　　　　　　　Ａ　　　　　　　　　　　Ｂ
 １ 『高田純二＿タカダジュンジ』　　　高田純二

 とＡ１に氏名（漢字）＋スペース＋氏名（カナ）があります。
 それをＢ１に漢字の名前のみを抽出させることはできますか？

 よろしくお願いしますm(_ _)m

 スペースが1箇所であれば
 =LEFT(A1,FIND(" ",A1)-1)
 でいいかな？
 （ぽ）

 ぽ さん

 ありがとうございます！

 先ほど、FIND関数を見てみました。
 そういうやり方があることを知らなかったので、
 勉強になりました。

 ちなみに、外国の方でミドルネームがある人は
 スペースが２箇所になりますね。
 また、過去のデータ入力誤り等でスペースがない
 場合には、どのような対応したらよろしいのか、
 よろしければ教えていただけませんでしょうか。

 （乃愛）

 > ちなみに、外国の方でミドルネームがある人はスペースが２箇所になりますね。

 B1:
 =Left(A1,Len(A1)-Len(C1))

 C1
 =Trim(Left(Right(Substitute(Substitute(A1," ",Rept(" ",40)),"　",Rept(" ",40)),40),40))

 では？
 (seiya)

 seiyaさん

 ありがとうございます！
 スペースが２つの場合についてはできました。
 見たことがない関数なので、しっかり覚えないと・・・(｀・ω・´)

 それから、スペースが１つの場合と２つの場合の関数を
 結合して↓の関数ができました。

 B1
 =IF(LEN(A1)-LEN(SUBSTITUTE(SUBSTITUTE(A1," ",),"　",))=2,LEFT(A1,LEN(A1)-LEN(C1)),LEFT(A1,FIND("　",A1)-1))

 C1
 =TRIM(LEFT(RIGHT(SUBSTITUTE(SUBSTITUTE(A1," ",REPT(" ",40)),"　",REPT(" ",40)),40),40))

 あとは、スペースがない場合で漢字のみを取り出す方法があれば、
 いいのですが。。

 （乃愛）

 PHONETIC関数で「高田純二タカダジュンジ」が「タカダジュンジタカダジュンジ」
だとできそうな気がしますが・・・？

 ◆こんな方法はいかがでしょうか？
 　　　　　　　A　　　　　　　　　　　　B
 1　　　大阪太郎オオサカタロウ	大阪太郎
 2　　　京都花子キョウトハナコ	京都花子
 3　　　神戸一太郎コウベイチタロウ	神戸一太郎
 4　　　和歌山昇ワカヤマノボル	和歌山昇
 5　　　滋賀彦次郎シガヒコジロウ	滋賀彦次郎
 6　　　奈良アケミナラアケミ　　　　 奈良アケミ

 B1=LEFT(A1,LEN(A1)-LEN(PHONETIC(A1))/2)
 (Maron)

 Maronさん

 ありがとうございます。
 その関数を試してみました。もしかしたら、その関数だけで、
 すべての疑問が解消するかも・・・と思ったのですが、
 スペースが１つの場合と２つの場合の関数を合わせないとダメそうでした。

 なので、↓の関数でやってみようと思います！

 B1
 =IF(LEN(A2)-LEN(SUBSTITUTE(SUBSTITUTE(A2," ",),"　",))=2,LEFT(A2,LEN(A2)-LEN(C2)),IF(LEN(A2)-LEN(SUBSTITUTE(SUBSTITUTE(A2," ",),"　",))=1,LEFT(A2,FIND("　",A2)-1),LEFT(A2,LEN(A2)-LEN(PHONETIC(A2))/2)))

 C1
 =TRIM(LEFT(RIGHT(SUBSTITUTE(SUBSTITUTE(A1," ",REPT(" ",40)),"　",REPT(" ",40)),40),40))

 ぽさん、seiyaさん、Maronさんありがとうございました。
 使ったことのない関数ばかりだったので戸惑いましたが、
 今後も使っていけそうに感じましたので、これから勉強して
 試してみたいと思います。

 ありがとうございました。

 （乃愛）

コメント返信：

[ 一覧(最新更新順) ]

[[20071220171527]] 『１セルにある漢字と仮名の分別方法』（乃愛） ページの最後に飛ぶ

[[20071220171527]]　『１セルにある漢字と仮名の分別方法』（乃愛）　ページの最後に飛ぶ