[[20080127205000]]　『年賀はがき当選結果』（333）　ページの最後に飛ぶ

『年賀はがき当選結果』（333）

本日、抽選結果の年賀はがきの番号を入力して結果を出したいのですが？？

下記のようにA８に番号入力するとB8に結果が出るようになんて行いたいのですが？

かなりの葉書数で困っています・・・

下記以外でも皆さんの中でいい方法があれば教えていただけないでしょうか？

 	  A	  B	  C	  D	  E	            F	
1	１等	２等	３等	４等	オリジナル賞	C組限定	
2	574578	957358	9660	37	935473	          812751	
3		769466		64	588104	          561101	
4		397940			520056		
5					700871		
6							
7	番号	結果					
8	574578	１等					
9	111111	外れ

 配置がかわりますが（作業セルも使います。）
	[A]	[B]	[C]	[D]	[E]	[F]	[G]	[H]
[1]	番号	賞名		番号	結果	６桁	４桁	２桁
[2]	574578	１等		812751	Ｃ組？	Ｃ組？	#N/A	#N/A
[3]	957358	２等		574578	１等	１等	#N/A	#N/A
[4]	769466	２等		957358	２等	２等	#N/A	#N/A
[5]	397940	２等		119660	３等	#N/A	３等	#N/A
[6]	9660	３等		111137	４等	#N/A	#N/A	４等
[7]	37	４等		935473	オリジ	オリジ	#N/A	#N/A
[8]	64	４等			ナル賞	ナル賞		
[9]	935473	オリジナル賞						
[10]	588104	オリジナル賞						
[11]	520056	オリジナル賞						
[12]	700871	オリジナル賞						
[13]	812751	Ｃ組？						
[14]	561101	Ｃ組？

 E2に
=IF(ISNA(F2),IF(ISNA(G2),IF(ISNA(H2),"外れ",H2),G2),F2)
 F2に
=VLOOKUP($D2,$A$2:$B$14,2,FALSE)
 G2に
=VLOOKUP(--RIGHT($D2,4),$A$1:$B$14,2,FALSE)
 H2に
=VLOOKUP(--RIGHT($D2,2),$A$2:$B$14,2,FALSE)

 とするのはどうでしょう。

 「Ｃ組？」と出た物は、組番号を確認してください。

 (HANA)

 「当選番号チェックサイト」もしくは「年賀はがき」などで、Web検索するといいですよ。

 【大当たり年賀状＆かもめーる 当選番号チェックサイト】が便利でした。。。(777)

 =INDEX($A$1:$F$1,SMALL(IF((MOD($A8,10^LEN($A$2:$F$5))=$A$2:$F$5)*($A$2:$F$5<>""),COLUMN($A$2:$F$5)),1))
 配列数式です　Ctrl+Shift+Enter

 (HANA)さんの表のようにした方が良いですね
 B15に　「外れ」と入力

 =INDEX(B:B,SMALL(IF((MOD($D2,10^LEN($A$2:$A$15))=$A$2:$A$15),ROW($A$2:$A$15)),1)) 
 配列数式です　Ctrl+Shift+Enter

 E2に
 =IF(ISNA(F2),IF(ISNA(G2),IF(ISNA(H2),"外れ",H2),G2),F2)
 F2に
　=IF(ISERROR(VLOOKUP($D2,$A$2:$B$14,2,FALSE)),"",VLOOKUP($D2,$A$2:$B$14,2,FALSE))
 G2に
　=IF(ISERROR(VLOOKUP(--RIGHT($D2,4),$A$1:$B$14,2,FALSE)),"",(VLOOKUP(--RIGHT($D2,4),$A$1:$B$14,2,FALSE)))
 H2に
 =IF(ISERROR(VLOOKUP(--RIGHT($D2,2),$A$2:$B$14,2,FALSE)),"",(VLOOKUP(--RIGHT($D2,2),$A$2:$B$14,2,FALSE)))
 #N/Aを消去します
 (shota)

コメント返信：

[ 一覧(最新更新順) ]

[[20080127205000]] 『年賀はがき当選結果』（333） ページの最後に飛ぶ

[[20080127205000]]　『年賀はがき当選結果』（333）　ページの最後に飛ぶ