[[20080131202515]]　『SUMPRODUCTの部分一致について』（マスター）　ページの最後に飛ぶ

『SUMPRODUCTの部分一致について』（マスター）

A1～A100の中に"テスト1"があって尚且つ、B1～B100の中に"テスト2"という文字が含まれている場合、C1～C100を足しこむ

=SUMPRODUCT((シート1$A$1:$A$100="テスト1")*(シート1$B$1:$B$100="*テスト2*")*シート1$C$1:$C$100)

これがうまくいきません

Aは完全一致
Bは部分一致にしたいのです。
Aだけだとちゃんと動くのですが、Bを入れると結果が「0」になってしまいます

どなたかご回答よろしくお願いいたします

 =SUMPRODUCT((Sheet1!$A$1:$A$100="テスト1")*(NOT(ISERR(FIND("テスト2",Sheet1!$B$1:$B$100))))*(Sheet1!$C$1:$C$100))
 とか
 =SUMPRODUCT((Sheet1!$A$1:$A$100="テスト1")*(LEN(Sheet1!$B$1:$B$100)<>LEN(SUBSTITUTE(Sheet1!$B$1:$B$100,"テスト2","")))*(Sheet1!$C$1:$C$100))
 というのは？　(Hatch)

うぉー助かりました

ありがとうございました！

(マスター)

 解決済みですが…きも～ち短く
 =SUMPRODUCT((Sheet1!$A$1:$A$100="テスト1")*COUNT(FIND("テスト2",Sheet1!$B$1:$B$100))*Sheet1!$C$1:$C$100)
 もひとつ
 =SUM((Sheet1!$A$1:$A$100="テスト1")*NOT(ISERR(SEACH("テスト2",Sheet1!$B$1:$B$100)))*Sheet1!$C$1:$C$100)
 としてCtrl+Shift+Enter

 SUMPRODUCTにはワイルドカード使えないんですねぇ。
 勉強になりました。
 (GYM)

 おはようございま～す。。。♪

 解決済ですが～。。。

 こんな表の場合です。

 ┌─┬────┬────────┬────┐
 │  │   A    │       B        │   C    │
 ├─┼────┼────────┼────┤
 │ 1│テスト1 │aaaテスト2bbb   │      10│
 ├─┼────┼────────┼────┤
 │ 2│テスト2 │テスト3         │      20│
 ├─┼────┼────────┼────┤
 │ 3│テスト1 │ABCテスト1      │      30│
 ├─┼────┼────────┼────┤
 │ 4│テスト4 │テスト5         │      40│
 ├─┼────┼────────┼────┤
 │ 5│テスト5 │テスト6         │      50│
 ├─┼────┼────────┼────┤
 │ 6│テスト1 │あテスト2いう   │      60│
 ├─┼────┼────────┼────┤
 │ 7│テスト1 │テスト2         │      70│
 ├─┼────┼────────┼────┤
 │ 8│        │                │        │
 └─┴────┴────────┴────┘

 >SUMPRODUCTにはワイルドカード使えないんですねぇ。

 ご希望とは違うかも知れませんけれど。。。

 B列に　テスト1Aテスト2BC ←こんな文字が無ければです。

 =SUMPRODUCT(ISNUMBER(SEARCH("テスト1*テスト2*",Sheet1!$A$1:$A$100&
Sheet1!$B$1:$B$100))*Sheet1!$C$1:$C$100)

 こんな使い方も出来ますネ。。
 でも、こういう使い方はあまりしないですね！！。。

 ご参考にどうぞ。。。

 。。。。Ms.Rin～♪♪

コメント返信：

[ 一覧(最新更新順) ]

[[20080131202515]] 『SUMPRODUCTの部分一致について』（マスター） ページの最後に飛ぶ

[[20080131202515]]　『SUMPRODUCTの部分一致について』（マスター）　ページの最後に飛ぶ