[[20080326173553]]　『プルダウンボックス内の文字サイズ』（しご）　ページの最後に飛ぶ

『プルダウンボックス内の文字サイズ』（しご）

フィルター使用などの場合に使用するプルダウンボックス内の
文字サイズのカスタマイズがしたいのですが
シート表示倍率の変更ではなく、ボックス内の文字サイズのみの変更は可能でしょうか？

hukanou

 ご参考に
[[20070605112107]]『リストボックスの大きさ』
[[20070806121341]]『入力規制でプルダウンメニューを作ったのですが、プルダウンされる文字が小さくて読めません。文字を大きくする方法はありますか？』

 (1or8)

 入力規則のリストでは、コマンドバー「フォーム」のコンボボックスをカスタマして使われています。
 これも中の文字列のサイズ指定が出来ませんから、入力規則のリストでも文字変更は出来ません。

 ＶＢＡでよければ、
 入力規則のリストを真似てみました。

 新規ブックの標準モジュール（あくまでも新規ブックです)に

 '==========================================
 Sub コンボボックス作成()
    Dim rng As Range
    Call mk_sample_data
    Set rng = Range("c1")
    With ActiveSheet.OLEObjects.Add(ClassType:="Forms.ComboBox.1", Link:=False, _
                                    DisplayAsIcon:=False, _
                                    Left:=rng.Left, _
                                    Top:=rng.Top, _
                                    Width:=rng.Width + 12, _
                                    Height:=rng.Height)
       .ListFillRange = "a1:a6"
       .LinkedCell = "c1"
       .Name = "リスト"
       With .Object
          .Font.Size = 18
          End With
       .PrintObject = False
       End With
 End Sub
 '========================================================================================
 Sub mk_sample_data()
    Range("a1:a6").Value = _
    [{"a";"b";"c";"d";"e";"f"}]
    Range("c1:c20").EntireRow.RowHeight = 26
 End Sub

 擬似入力規則を実行したいシートのシートモジュールに

 '========================================================================================
 Option Explicit

 Private Sub Worksheet_Activate()
    set_combobox
 End Sub
 '=================================================================================
 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    set_combobox
 End Sub
 '=================================================================================
 Sub set_combobox()
    If Application.Intersect(ActiveCell, Range("c1:c20")) Is Nothing Then
       OLEObjects("リスト").Visible = False
    Else
       With OLEObjects("リスト")
          .Visible = True
          .Left = ActiveCell.Left
          .Top = ActiveCell.Top
          .Width = ActiveCell.Width + 12
          .Height = ActiveCell.Height
          .LinkedCell = ActiveCell.Address
          .Object.Value = ActiveCell.Value
          End With
       End If
 End Sub

 として、まず当該シートをアクティブにした状態で
 「コンボボックス作成」を実行してみてください。

 入力規則リストのようなコンボボックスがセルC1に作成されます。

 リストは、当該シートのC1からｃ20が対象です。
 リストメンバーはA1:A6になります。

 セルｃ１からｃ２０の範囲で移動してみてください。入力規則のリストのようなコンボボックスが表示されます

 クリックしてみてください。メンバ表示では、文字が大きくなって表示されると思います。

 興味があったら試してみて下さい。

 ichinose

コメント返信：

[ 一覧(最新更新順) ]

[[20080326173553]] 『プルダウンボックス内の文字サイズ』（しご） ページの最後に飛ぶ

[[20080326173553]]　『プルダウンボックス内の文字サイズ』（しご）　ページの最後に飛ぶ