[[20080529113128]]　『複数の検索結果』（素人）　ページの最後に飛ぶ

『複数の検索結果』（素人）

 仕事柄エクセルをデータベース的によく使用しております。
 データの並んでいるシートから必要分だけの情報を抽出して別シートで表示したいのですが、
 検索結果が複数でも他のシートに検索結果を全数表示させることはできないのしょうか。

 　　商品　　　納入先　　　金額
 　りんご　　　Ａ商店　　　200
 　みかん　　　Ｂ商店　　　100
 　ぶどう　　　Ｃ商店　　　150
 　りんご　　　Ｄ商店　　　190

 を別シートで（ＶＬＯＯＫＵＰのように）「りんご」で検索すると検索結果（納入先）を
 すべて表示するようにはできないのでしょうか。

 　りんご　　　Ａ商店
 　りんご　　　Ｄ商店

 ご教授よろしくお願いします。
[Excel2000]

 作業列を利用する方法です。

 A列：商品、B列：納入先、C列金額として
 データの並んでいるシートに　D2=IF("りんご"=A2,COUNTIF(A$2:A2,"りんご"),"")
 別シート　　　　　　　　に    =INDEX(Sheet1!A$2:A$5,MATCH(SMALL(Sheet1!$D$2:$D$5,ROW()),Sheet1!$D$2:$D$5))
 後はコピペ

 (1or8)

 Sheet2
      A            B
1  抽出品名　　  りんご
2   商品	        納入先
3  りんご	　　　　Ａ商店
4  りんご	　　　　Ｄ商店
5	
 A3=IF(COUNTIF(Sheet1!$A$2:$A$5,$B$1)<ROW(A1),"",
         INDEX(Sheet1!A$1:A$5,SMALL(IF(Sheet1!$A$2:$A$5=$B$1,ROW($A$2:$A$5)),ROW(A1))))	
 配列数式です。Ctrl と Shift を押しながら Enter してください。式が{ }で囲まれます。	
 A3をフィルダウン。B列へコピー  (gon-2)

　こんにちは～♪

 gon-2さんと衝突してしまいましたが。。。

 こんな表の場合です。。。

 Sheet1↓

 ┌─┬────┬────┬────┐
 │  │   A    │   B    │   C    │
 ├─┼────┼────┼────┤
 │ 1│商品    │納入先  │金額    │
 ├─┼────┼────┼────┤
 │ 2│りんご  │Ａ商店  │     200│
 ├─┼────┼────┼────┤
 │ 3│みかん  │Ｂ商店  │     100│
 ├─┼────┼────┼────┤
 │ 4│ぶどう  │Ｃ商店  │     150│
 ├─┼────┼────┼────┤
 │ 5│りんご  │Ｄ商店  │     190│
 ├─┼────┼────┼────┤
 │ 6│        │        │        │
 └─┴────┴────┴────┘

 別シート ↓

 ┌─┬────┬────┬────┐
 │  │   A    │   B    │   C    │
 ├─┼────┼────┼────┤
 │ 1│商品    │納入先  │        │
 ├─┼────┼────┼────┤
 │ 2│りんご  │Ａ商店  │        │
 ├─┼────┼────┼────┤
 │ 3│        │Ｄ商店  │        │
 ├─┼────┼────┼────┤
 │ 4│        │        │        │
 └─┴────┴────┴────┘

 A2セルへ
 りんご と入力します。。

 B2セルへ
 =INDEX(Sheet1!B:B,SMALL(INDEX((Sheet1!$A$1:$A$100<>$A$2)*10^4+ROW($1:$100),),ROW(A1)))&""

 下へコピー。。。

 この式は、データ行が100行になっています。
 それ以上の場合は、範囲を変更して下さい。。。

 ★Sheet1のデータ数が、かなり多い場合は　
 1or8さんの、作業列を使う方法をお勧めします。。。

 ご参考にどうぞ。。。

 。。。Ms.Rin～♪♪

 長い間の問題が解決できました。
 みなさん、ありがとうございました。
 （素人）

コメント返信：

[ 一覧(最新更新順) ]

[[20080529113128]] 『複数の検索結果』（素人） ページの最後に飛ぶ

[[20080529113128]]　『複数の検索結果』（素人）　ページの最後に飛ぶ