[[20080624171255]]　『残業時間の計算方法について』（ゆうち）　ページの最後に飛ぶ

『残業時間の計算方法について』（ゆうち）

 初めて質問させていただきます。ｴｸｾﾙ初心者なので分かりやすい解説をして頂けたら幸いです。　宜しくお願いします。

  　　A　　　　　　　B　　　　　C　 　　　　　　D　　　　　　E　
 1　出勤時間　　退社時間　　通常勤務時間　　残業時間　　深夜残業時間
 2　　9:00　　　　23:30　　　 　9:30　　　　　3:30　　　　　1:30

 エクセルでこのような表を作成しました。
 通常時間の計算式は下記のように設定しました。

 =IF(OR(COUNT(A2:B2)<2,B2-"18:30"<0),"",FLOOR(VALUE(TEXT(MIN(B2,"18:30")-MAX(A2,"9:00"),"h:mm")),"0:15"))　
 です。
 出勤･退社が決まっている社員の場合この式でも良いのですが･･･
 出勤･退社ﾊﾟﾀｰﾝが3つある社員がいるのでどうして良いのか分かりません。

 出勤　　　　退社
 9:00　～　　18:30
 9:15　～　　18:45
 9:30　～　　19:00

 勤務時間が9:30以降残業になります。また,22:00以降は深夜残業です。
 私の作成した式が生かせれば幸いです。宜しくお願い致します。

 ＞出勤･退社パターンが3つある社員がいるのでどうして良いのか分かりません。

 社員がどのパターンになるか、どうやって判断するのですか？

       ここを見ると、出社時刻で判断していいとも思えないのですが。
         ↓
 ＞・・MAX(A2,"9:00")・・

 （半平太）

半平太さん　ｺﾒﾝﾄありがとうございます。
説明不足でｽﾐﾏｾﾝ・・・。

自分の知っている関数をなんとなく組み合わせて作ってみたのですが・・・。

社員の中でもﾌﾚｯｸｽﾀｲﾑ制の人が居ます。
今の計算式のままでは,18:30以降が全て残業･深夜残業となってしまうので計算が合いません。

9:00～18:30それ以降を残業というのを　9:30以降残業という形にしたいです。

無知で申し訳ありませんが,宜しくお願いします。

（ゆうち）

 ※出勤・退社パターンは出勤時刻により判別するものとします。
 ※翌朝5:00(29:00)以降までの継続勤務は生じないものとします。

      A         B           C           D         E            F
1  出勤時間  退社時間  通常勤務時間  残業時間	 深夜残業時間  拘束時間
2    9:00     18:30	9:30	  0:00	    0:00	        9:30
3    9:00	     23:30	9:30	  3:30	    1:30	       14:30
4    9:15	     23:45	9:30	  3:15	    1:45	       14:30
5    9:30	     24:00	9:30	  3:00	    2:00	       14:30

 C2=MIN(F2,"9:30")					
 D2=MIN(F2-C2,F2-C2-(B2-"22:00"))					
 E2=MAX(B2-"22:00",0)					
 F2=B2-A2					
 C2:F2をフィルダウン

 叩き台としての一案ですのでご参考まで。。。(gon-2)

 15分の丸めルールについて、議論していませんが、見切りで　<(_ _)>

 (1) C2セル =IF(COUNT(A2:B2)<2,"",FLOOR(TEXT(MIN("9:30",B2-A2),"h:mm"),"0:15"))
 (2) D2セル =IF(COUNT(A2:B2)<2,"",FLOOR(TEXT(MAX(0,B2-A2-C2-E2),"h:mm"),"0:15"))
 (3) E2セル =IF(COUNT(A2:B2)<2,"",FLOOR(TEXT(MIN(MAX(0,B2-A2-"9:30"),MAX(0,B2-"22:00")),"h:mm"),"0:15"))

 行   ___A____  ___B____  _____C______  ___D____  ____ E _____
  1   出勤時間  退社時間  通常勤務時間  残業時間  深夜残業時間
  2   　9:00      23:30     9:30          3:30      1:30      
  3   　9:15      18:45     9:30                              
  4   　9:30      19:00     9:30                              
  5   　9:00      23:30     9:30          3:30      1:30      
  6   　9:15      23:45     9:30          3:15      1:45      
  7    11:00      23:00     9:30          1:30      1:00      
  8   　9:05      24:55     9:30          3:30      2:45

 　セルの書式（表示形式）は→ 　[h]:mm;;　としてください。

  （半平太）

　(半平太さん）

　丁寧なご回答,本当にありがとうございました。
　おかげさまで,希望通りの表が出来上がりました。感謝でｲｯﾊﾟｲです★☆★

コメント返信：

[ 一覧(最新更新順) ]

[[20080624171255]] 『残業時間の計算方法について』（ゆうち） ページの最後に飛ぶ

[[20080624171255]]　『残業時間の計算方法について』（ゆうち）　ページの最後に飛ぶ