[[20080702152751]]　『VLOOKUPかな？』（ミーコ）　ページの最後に飛ぶ

『VLOOKUPかな？』（ミーコ）

 	A	B	C	D	E
1	あ	cc		い	bb
2		ss			aa
3	い	bb			cc
4		aa			nn
5		cc			
6		nn			
7	う	ww

例としてＤ１に、いと入れたらＥ列にＢ列の項目を引っ張って
来たい。
ＶＬｏｏｋではうまくいきませんでした。

　宜しくお願い致します。

 VLOOKUPでいいんじゃないですか？
 E1=IF(D1="","",VLOOKUP(D1,$A$1:$B$7,2))
 で下に・・・サンプル通り７行目までですが
 （肌）

 多分、こういうことかと。

 	A	B	C	D	E
 1	あ	cc		い	bb
 2	あ	ss			aa
 3 	い	bb			cc
 4       	い	aa			nn
 5	い	cc			
 6	い	nn			
 7	う	ww

 上記のように、空白セルは上のデータを入力します。
 見えると困るなら文字色を白色に。

 E1セル　=IF(ROW(1:1)>COUNTIF($A$1:$A$7,$D$1),"",INDEX($B$1:$B$7,SMALL(IF($A$1:$A$7=$D$1,ROW($A$1:$A$7),""),ROW(1:1))))

 配列数式ですので、Ctrl+Shift+Enter で確定して下さい。
 その後、下へフィルコピー。
　
（純丸）(o^-')b

 こんにちは～♪

 以前にもＡ列が、未入力の場合の
 回答をした記憶が。。。?

 E1セルへ
 =IF(COUNTIF(A:A,$D$1),IF($D$1<>LOOKUP("ー",A$1:INDEX(A:A,MATCH($D$1,A:A,0)+
ROW(A1)-1)),"",INDEX(B:B,MATCH($D$1,A:A,0)+ROW(A1)-1)&""),"")

 下へコピー。。。

 ご参考にどうぞ。。。

 。。。Ms.Rin～♪♪

 （純丸）(o^-')bさん、そうですね。
 VLOOKUPだと昇順されていないとだめだと思って訂正入れようと思ったら・・・でした。
 ぜんぜん的外れな答えでしたorz
 そうですよね。なんでD列が空欄でもE列に入力されているんだろうと思ってました。
 （肌）
 と思ってたら衝突しました。orz
 （純丸）(o^-')bさんの式も、。。。Ms.Rin～♪♪の式もどちらでもよさそうですよ。

 おっと、衝突。まっ、こんなのもありかな？ぐらいですが・・・
以下そのまま載せます。

 データの形式としては、純丸さんが書かれている形をお勧めします。
が、ちょっと手が空いたので、未入力の場合の処理の例です。
 E1セル
=IF(COUNTIF($A$1:$A$7,D1),VLOOKUP(D1,$A$1:$B$7,2,0),"")
 E2セル（この式は空欄になるまで下方コピー。）※改行してます。
=IF(F1="","",
IF(OFFSET($A$1,MATCH($D$1,$A$1:$A$7,0)+ROW(A1)-1,0)<>"","",OFFSET($B$1,MATCH($D$1,$A$1:$A$7,0)+ROW(A1)-1,0)))
(sin)

 空白セルに上のデータを入力なら
 E1=IF(COUNTIF($A$1:$A$7,D$1)<ROW(A1),"",INDEX($B$1:$B$7,MATCH(D$1,$A$1:$A$7,0)+ROW(A1)-1))
 下へコピー でもOKかな。。。(xxx)

多くの返事有り難うございました。
今回は、Ms.Rin～♪♪さんの式を使う事にしました。
式の勉強もこれからしたいと思います。
（ミーコ）

コメント返信：

[ 一覧(最新更新順) ]

[[20080702152751]] 『VLOOKUPかな？』（ミーコ） ページの最後に飛ぶ

[[20080702152751]]　『VLOOKUPかな？』（ミーコ）　ページの最後に飛ぶ