[[20080912135409]]　『条件に合う部分だけを計算させたい』（お父さん）　ページの最後に飛ぶ

『条件に合う部分だけを計算させたい』（お父さん）

予実　年月　　売り上げ

 実績　2008/1　10
実績　2008/2　20
実績　2008/3　25
実績　2008/4　28
実績　2008/5　30
実績　2008/6　35
実績　2008/7　40
実績　2008/8　43
予定　2008/9　45
予定　2008/10　52
予定　2008/11　54
予定　2008/12　60

このようなシートがあり、実績の売り上げ部分についてのみ計算をさせたく、sumifやcountif以外の計算式を当てはめたい場合どのようにすればよいでしょうか。
毎月更新するたびに計算式の範囲を修正するのが面倒なため、あらかじめ全範囲を参照しておいて、計算範囲を自動判別できるようにしたいと考えています。

 >sumifやcountif以外の計算式を当てはめたい場合･･･
 SUMIF，COUNTIFは使用しては何故いけないんですか？
 SUMIFなら範囲を修正する必要も無いと思いますが？
 （ぽ）

sumをしたいわけではないのです、、、
具体的には重決定を出すためにRSQという関数を使おうとしています。
上記の場合（2008/8まで実績の場合）
=RSQ(C2:C9,B2:B9)
という計算式になるようにしたいです。

 最初の質問とRSQ関数を結びつけることってできるんでしょうか？
 RSQ関数はHELP見ましたが理解できないんでパスしますが。(^^)

 実際されたい内容をきちんと書かれたほうが
 無駄なレスもつきませんし、適切な回答が付くと
 思いますよｂ
 （ぽ）

 こんな感じでしょうか。
=RSQ(OFFSET(C1,MATCH(A2,A:A,0)-1,,COUNTIF(A:A,"実績")),OFFSET(B1,MATCH(A2,A:A,0)-1,,COUNTIF(A:A,"実績")))
 ただし、実績は連続していないとだめですよ。

 （川野鮎太郎）

 衝突！

 下表を前提としています。
　
	[A]	[B]	[C]
[1]	実績	2008/1	10
[2]	実績	2008/2	20
[3]	実績	2008/3	25
[4]	実績	2008/4	28
[5]	実績	2008/5	30
[6]	実績	2008/6	35
[7]	実績	2008/7	40
[8]	実績	2008/8	43
[9]	予定	2008/9	45
[10]	予定	2008/10	52
[11]	予定	2008/11	54
[12]	予定	2008/12	60
　
=RSQ(INDEX(C1:C12,MATCH("実績",A1:A12,0)):INDEX(C1:C12,MATCH("予定",A1:A12,0)-1),
 INDEX(B1:B12,MATCH("実績",A1:A12,0)):INDEX(B1:B12,MATCH("予定",A1:A12,0)-1))
　
でどうでしょうか。
(ROUGE) #相関係数の使い方に疑問は感じますが。。。

 みなさまありがとうございます。
いずれも望んでいた結果が得られました。
いやはやみなさん凄いですね。。

 本音は回帰分析を自動化したくて、当初の質問があやふやだった点お詫びいたします。
（たしかに相関関数の使い方も疑問持たれたことと思います）
代わりといってはなんですが、自分でもほかの方法で考えてみました。

 =RSQ((C1:INDEX(C1:C12,COUNTIF(A1:A12,"実績"))),(B1:INDEX(B1:B12,COUNTIF(A1:A12,"実績"))))

 みなさんの関数の使い方も非常に参考になりました。
どうもありがとうございました。

コメント返信：

[ 一覧(最新更新順) ]

[[20080912135409]] 『条件に合う部分だけを計算させたい』（お父さん） ページの最後に飛ぶ

[[20080912135409]]　『条件に合う部分だけを計算させたい』（お父さん）　ページの最後に飛ぶ