[[20090527154500]]　『マクロでアクティブセルの行を自動色付けしたいで』（初心者です）　ページの最後に飛ぶ

『マクロでアクティブセルの行を自動色付けしたいです。』（初心者です）

 おわかりになるかた教えて下さい。ｍ（＿＿）ｍ
 (B13:AI17)と(A20:AU38)の範囲内だけ、選択したセルの行い色を付けたいです。
 何とか見よう見まねで、作ったのですが上記の範囲内だけ色をつけるすべがわかりません。

 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　ActiveSheet.Cells.Interior.ColorIndex = 0
 With Target
 ActiveSheet.Range(Cells(.Row, 1), Cells(.Row, 45)).Interior.ColorIndex = 15
 End With
 End Sub

 どなたか、教えて下さい！ちなみにシートは５枚程ございます。
 よろしくお願いします。

 自己削除します。

 (HANA)

 衝突。。。
　
 こんなこと？
　
'/////Sheet Moduleへ貼り付け/////
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
With Range("B13:AI17,A20:AU38")
    .Interior.ColorIndex = xlNone
    If Not Intersect(.Cells, Target.EntireRow) Is Nothing Then
        Intersect(.Cells, Target.EntireRow).Interior.ColorIndex = 15
    End If
End With
End Sub
　
　
それともこっち？
　
'/////ThisWorkbook Moduleへ貼り付け/////
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Dim ary
ary = Array("Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet5")   '<--該当のシート名を記入する。
If Not IsError(Application.Match(Sh.Name, ary, 0)) Then
    With Sh.Range("B13:AI17,A20:AU38")
        .Cells.Interior.ColorIndex = xlNone
        If Not Intersect(.Cells, Target.EntireRow) Is Nothing Then
            Intersect(.Cells, Target.EntireRow).Interior.ColorIndex = 15
        End If
    End With
End If
End Sub
　
(ROUGE)

すごいです！上のほうでできました。

 天才ですねぇ～感激です！ありがとうございましたｍ（＿＿）ｍ

コメント返信：

[ 一覧(最新更新順) ]

[[20090527154500]] 『マクロでアクティブセルの行を自動色付けしたいで』（初心者です） ページの最後に飛ぶ

[[20090527154500]]　『マクロでアクティブセルの行を自動色付けしたいで』（初心者です）　ページの最後に飛ぶ