[[20090717224006]]　『条件にあった合計を求めたい』（KI）　ページの最後に飛ぶ

『条件にあった合計を求めたい』（KI）

 こんばんは。
 Excel初心者です。

 ある範囲の表があります。 
 行と列で項目をそれぞれ指定し、該当する 
 合計値を求めたいのですが、うまく出来ません。
 使用した数式は以下のとおりです。
 考え方が間違っているのでしょうか？

     	[A]	[B]	[C]	[D]	[E]	[F]
 [1]		犬	猫	猿	馬	羊
 [2]	山	20	30	0	20	30
 [3]	川	30	20	20	0	20
 [4]	森	40	10	0	0	20
 [5]	水	50	0	40	10	0
 [6]	空	60	10	60	20	10
 [7]						
 [8]						
 [9]						
 [10]	猿	馬	羊			
 [11]	#N/A	#N/A	#N/A	     	水	川
 [12]	#N/A	#N/A	#N/A	     	森	
 [13]	#N/A	#N/A	#N/A	     	犬	羊

 A11に列が "猿" で、行が "水" と "川" に該当する値の合計値を
 求めるために
 A11=SUMPRODUCT(($A$2:$A$6=$E11:$F11)*($B$1:$F$1=A$10)*($B$2:$F$6))
 と入れ、C13までコピーしましたがエラーとなってしまいました。

 求めたい答えは、
 A11=60
 B11=10
 C11=20
 A12=0
 B12=0
 C12=20

 といった具合です。
 どうかアドバイスをお願い致します。

 SUMPRODUCTにこだわる理由はありますか？

 SUMPRODUCTは一見 手軽かもしれませんが
 仕組みを理解せずに使用する場合は「使用上注意」です。

 13行目は無視していいんですよね？
 少し長くなります。

 A11
 =HLOOKUP(A$10,$A$1:$F$6,MATCH($E11,$A$1:$A$6,0),0)
 +IF($F11="",0,HLOOKUP(A$10,$A$1:$F$6,MATCH($F11,$A$1:$A$6,0),0))

 C12までフィルハンドルで右に下にコピー

 （ていおう）2009/7/17 23:38

 いっぺんに求めようとするから
 難しくなっているんじゃないかと思います。
 　SUMPRODUCT(列が "猿" で、行が "水") ＋ SUMPRODUCT(列が "猿" で、行が "川")
 って感じで、片方ずつの式にして二つを足せば良いと思います。

 でもって、出来た数式をじっくり見ると
 何か見えてくるものがあるかもしれませんね。

 (HANA)

 A11=SUMPRODUCT(($B$1:$F$1=A$10)*(($A$2:$A$6=$D11)+($A$2:$A$6=$E11)),$B$2:$F$6)
 ★右と下にコピー
 (Maron)

 個人的な意見ですが

 私は初心者が仕組みもわからずに
 形だけまねてSUMPRODUCT関数を使用することはお勧めしません。
 ちなみに「配列数式」や「論理値」に関しては理解されていますか？

 掲示板では回答の中で仕組みが解説されることはあまりありませんし
 初級者向けの「詳細な説明」をされているサイトもなかなかありません。

 数式の中で
 なぜ乗算しているのか？
 なぜ加算しているのか？

 配列数式や論理値を含めてそのあたりをしっかり理解されてから
 使用するようにしたほうがいいと思います。
 そうすれば条件が変わったときにも応用が利くと思います。

 （えくせる青年）2009/7/18 11:34

コメント返信：

[ 一覧(最新更新順) ]

[[20090717224006]] 『条件にあった合計を求めたい』（KI） ページの最後に飛ぶ

[[20090717224006]]　『条件にあった合計を求めたい』（KI）　ページの最後に飛ぶ