[[20090915095813]]　『マクロで最終行までコピーするには？』（りりあん）　ページの最後に飛ぶ

『マクロで最終行までコピーするには？』（りりあん）
WindowsXP,Excel2002

 A                 B         C
 区分	        該当月	点検
 初期定期点検	5月	6ヶ月
 　	　　　　　	6ヶ月
 　　　　　　　　　	6ヶ月

マクロでA2セルとB2セルを範囲指定して最終行までコピーしたいのですが
支店ごとにデータの件数が違う為うまくコピーが出来ません。
（私が登録したマクロはA2セルとB2セルを範囲指定してダブルクリックで最終まで
　コピーした為コピーが途中で止まってしまうのです。）

どんなマクロで登録したらいいのでしょうか？

 こんな感じでできそうな...

 With Range("c2", Range("c" & Rows.Count).End(xlUp)).Offset(, -2).Resize(, 2)
     .Value = .Rows(1).Value
 End With
 (seiya)

seiyaさんありがとうございました。
コピー無事に出来たのですが1つ問題が出てしまいました。
すみませんちゃんと説明すれば良かったのですが・・・(T_T)

実はA2セルB2セルには関数が入っているのですがそれが解除されてしまいました。(セル内の色も)
私が組んだマクロのコードとseiyaさんからの貰ったコートを組込んだものを書きましたので
一度見て頂けないでしょうか?

    Range("A2").Select
    ActiveCell.FormulaR1C1 = _
        "=IF(RC[2]=""10年"",""中期点検"",IF(RC[2]=""15年"",""中期点検"",IF(RC[2]=""20年"",""長期点検"",""初期定期点検"")))"
    Range("B2").Select
    ActiveCell.FormulaR1C1 = "=MONTH(RC[2])&""月"""
    Range("A2:B2").Select
    With Selection.Interior
        .ColorIndex = 24
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
    End With
    With Range("c2", Range("c" & Rows.Count).End(xlUp)).Offset(, -2).Resize(, 2)
     .Value = .Rows(1).Value
    End With

 Select/Activate はしない方がいいですよ？

    Range("A2").FormulaR1C1 = _
        "=IF(RC[2]=""10年"",""中期点検"",IF(RC[2]=""15年"",""中期点検"",IF(RC[2]=""20年"",""長期点検"",""初期定期点検"")))"
    Range("B2").FormulaR1C1 = "=MONTH(RC[2])&""月"""
    With Range("A2:B2").Interior
        .ColorIndex = 24
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
    End With
    Range("a2:b2").Copy Range("a3:b" & Range("c" & Rows.Count).End(xlUp).Row)
    Application.CutCopyMode = False
 (seiya)

seiyaさん
ありがとうございました。
今度はちゃんとできました。

コメント返信：

[ 一覧(最新更新順) ]

[[20090915095813]] 『マクロで最終行までコピーするには？』（りりあん） ページの最後に飛ぶ

[[20090915095813]]　『マクロで最終行までコピーするには？』（りりあん）　ページの最後に飛ぶ