[[20090916174555]]　『住所録を封筒印刷』（ちろるチョコ）　ページの最後に飛ぶ

『住所録を封筒印刷』（ちろるチョコ）

 シート2に住所録があります。シート1が封筒印刷用のシートになっていて
 シート1のD11に郵便番号C13に住所1、C15に住所2、D18に氏名が入るようになっています。
 シート2のA列に郵送と入っている列を順番に封筒印刷するのはどうしたらよいで
 しょうか？
 現在は1列ずつ転記して印刷するマクロを組んでいますが、250名分位あるので
 この方法だと時間がかかります。

 Excelにこだわらなければこんな方法もあります。
 住所録はExcelのまま
 印刷用をWordで作り「差し込み印刷」すると一気にやってくれます。

 yahooで調べるとでますよ^^

 (AA)

 ＞現在は1列ずつ転記して印刷するマクロを組んでいますが
 ってのを載せてみたら？

 (HANA)

 Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim tbl As Variant

    If Intersect(Target, Columns(2)) Is Nothing Then Exit Sub
    Cancel = False
    If MsgBox("「 " & Target.Value & " 」様分を転記します。", vbOKCancel) = vbCancel Then
        MsgBox "終了します"
        Cancel = True: Exit Sub
    End If
    tbl = Range("B" & Target.Row).Resize(1, 4).Value
    With Worksheets("印刷封筒用")
        .Range("D18") = tbl(1, 1)
        .Range("D11") = tbl(1, 2)
        .Range("C13") = tbl(1, 3)
        .Range("C15") = tbl(1, 4)
    End With
    Cancel = True

End Sub

 こんな感じです。1名分ずつ処理しなくてはならないので手間がかかります(≧д≦)
 (ちろるチョコ）

 １．マクロは住所録のあるシートに実行ボタンを作成し　実行しますか？
 ２．住所録は、1行目が見出し 2行目からデータが入っていますか？
 ３．住所録シートのB列の入力がある最終行は、住所録の範囲の最終行と一致しますか？

 (HANA)

 HANA様

 研修に行っていて返事が遅くなりましたm( __ __ )m

 1.実行ボタンは封筒フォームページにあります。

 2.住所録は2行目が見出し、3行目からデータが入っています。

 3.Ｂ列最終行と最終行は一致します。

 (ちろるチョコ）

 コードはこんな感じどうでしょう。

 '------
Sub 印刷()
Dim tbl As Variant, i As Long
If MsgBox("封筒印刷を開始します。", vbOKCancel) = vbCancel Then
    MsgBox "終了します"
    Exit Sub
End If
With Sheets("住所録")
    tbl = .Range("A1").Resize(.Range("B" & Rows.Count).End(xlUp).Row, 5).Value
End With
For i = 3 To UBound(tbl, 1)     'データが3行目からなので　i = 3 からスタート
    If tbl(i, 1) = "郵送" Then  '1列目の内容を確認
        Range("D18").Value = tbl(i, 2)
        Range("D11").Value = tbl(i, 3)
        Range("C13").Value = tbl(i, 4)
        Range("C15").Value = tbl(i, 5)
        ActiveSheet.PrintOut    '印刷
    End If
Next
MsgBox "印刷終了"
End Sub
 '------

 マクロを動かすとすぐに印刷されますので
 テスト時はプリンタを一時停止にして下さい。

 (HANA)

コメント返信：

[ 一覧(最新更新順) ]

[[20090916174555]] 『住所録を封筒印刷』（ちろるチョコ） ページの最後に飛ぶ

[[20090916174555]]　『住所録を封筒印刷』（ちろるチョコ）　ページの最後に飛ぶ