[[20091027125654]]　『マクロ‐リストボックス』（レインボー）　ページの最後に飛ぶ

『マクロ‐リストボックス』（レインボー）

 マクロ‐リストボックス（sheet1のリスト）で選択した行を、
 テキストボックスとチェックボックスに反映し、上書きするやり方を教えてください

 初めて質問させていただきます。マクロ初心者２００３＿Windows2000を使用しています。
 ユーザーフォームにリストボックスを作り（sheet1のリスト）、その１つを選択いたします。
 コマンドボタン１を押すと、選択したデータの一部がテキストボックスに反映するようにしています。
 ここまではできるのですが、
 テキストボックスに選択されたデータの上書き（文字や数字（プラス、マイナス）日付を上書きもしくは、
 Deleteキーで消したもの）を、sheet１のその行のリストに反映させるコマンドボタン２がうまく作動しません。
 また、１つチェックボックスを入れているのですが、ユーザーフォームへの読み込み（チェックをつけり消したり）、
 sheet1への反映がうまくいきません。

 下記コードが長くなってしまいすみませんが、どなたかお力を貸していただきたくよろしくお願いいたします。

 （リストボックスに出るsheet1のデータ）
 Ａ８から題（管理番号や品名など）がはじまり、Ｕまであります。
 （Ｆは、管理番号なため必ず値が入りますが、Ｉ以降Ｕまでは空白のセルも存在しています）
 表は伸縮いたします。

 （ユーザーフォーム）
 リストボックスには、sheet１のＡ９～Ｕ９の最終行までのデータを引用しています。
 コマンドボタン１を押すと、
 テキストボックス９＝Ｏ　　（空白、数字たとえば10など）　
 テキストボックス１０＝Ｐ　（空白、マイナスも含む数字たとえば-10など）
 テキストボックス１１＝Ｑ　（空白、日付）
 テキストボックス１２＝Ｒ　（空白、数字）
 テキストボックス１４＝Ｕ　（空白、コメント欄のため文字や数字など）
 が、リストボックスで選択した行のものが反映されます。

 コマンドボタン２を押すと、
 テキストボックス９＝Ｏ　　（空白、数字たとえば10など）　
 テキストボックス１０＝Ｐ　（空白、マイナスも含む数字たとえば-10など）
 テキストボックス１１＝Ｑ　（空白、日付）
 テキストボックス１２＝Ｒ　（空白、数字）
 テキストボックス１４＝Ｕ　（空白、コメント欄のため文字や数字など）
 deleteキーで空白にしたり、上書きしたものを、
 リストボックスで選択したsheet1のその行に上書きしたいのですが、うまくいきません。

 チェックボックス１は、sheet1のＳ行で、リストボックスで選択された行のＳ行に、
 終了と書かれていたら、チェックボックスのチェックがついて表示され、書かれていなかったらチェックされず表示されます。
 ユーザーフォーム上でチェックをつけたりはずしたりした際、
 常にその選択行に反映させるようにしたいのですが、作動しません。

（コード）
Private Sub UserForm_Initialize()

    Dim r As Range
        Set r = Sheets("Sheet1").Range("A8").CurrentRegion.Offset(1)
        Set r = r.Resize(r.Rows.Count - 1)

    With ListBox1
        .ColumnWidths = "0;0;0;0;0;50;50;50;0;0;0;0;0;0;0;0;0;0;0;0;0"
        .ColumnCount = 21
        .RowSource = r.Address(A8, U)
    End With

End Sub

Private Sub CommandButton1_Click()

    If ListBox1.ListIndex <> -1 Then
        TextBox9.Value = ListBox1.List(ListBox1.ListIndex, 14)
        TextBox10.Value = ListBox1.List(ListBox1.ListIndex, 15)
        TextBox12.Value = ListBox1.List(ListBox1.ListIndex, 17)
        TextBox14.Value = ListBox1.List(ListBox1.ListIndex, 20)
    End If

    If Not IsEmpty(ListBox1.List(ListBox1.ListIndex, 16)) Then
        TextBox11.Value = Format(CDate(ListBox1.List(ListBox1.ListIndex, 16)), "m/d")
    Else
        TextBox11.Value = ""
    End If

　　If ListBox1.List(ListBox1.ListIndex, 18) = "終了" Then

        CheckBox1.Value = True
    Else
        CheckBox1.Value = False
    End If

End Sub

Private Sub CheckBox1_Click()

Dim l As Range
Set l = Sheets("Sheet1").Range("A8").CurrentRegion.Offset(1)
Set l = l.Resize(l.Rows.Count - 1)

If CheckBox1.Value = True Then

    l(ListBox1.ListIndex + 1, 19).Value = "終了"
Else
    l(ListBox1.ListIndex + 1, 19).Value = ""
End If

End Sub

Private Sub CommandButton2_Click()

    If ListBox1.ListIndex <> -1 Then
        Dim r As Range
        Set r = Sheets("Sheet1").Range("A8").CurrentRegion.Offset(1)
        Set r = r.Resize(r.Rows.Count - 1)

        If IsDate(TextBox11.Value) Or TextBox11.Value = "" Then
        r(ListBox1.ListIndex + 1, 17) = TextBox11.Value
        End If
        r(ListBox1.ListIndex + 1, 15) = TextBox9.Value
        r(ListBox1.ListIndex + 1, 16) = TextBox10.Value
        r(ListBox1.ListIndex + 1, 18) = TextBox12.Value
        r(ListBox1.ListIndex + 1, 21) = TextBox14.Value
    End If
End Sub

 ＜コマンドボタン２＞と＜チェックボックス１＞がリストボックスで選択したSheet1のその行に反映されない点で困っています。
 ながながと書きすみませんが、ご教示よろしくお願いいたします。

 1) CommandButton1_Click で
    >If Not IsEmpty(ListBox1.List(ListBox1.ListIndex, 16)) Then
     IsEmpty　関数は機能していますか？

 2) ListBox1.ListIndex + 1 が違っている
    ということですか？
    > Sheet1のその行に反映されない点で困っています。
    どのように期待通りに反映されていないのかがわかりません。
 (seiya)

 大分書き換えてしまいましたが、このような事であってますか？

  Private Sub UserForm_Initialize()
  Dim tbl
  With Sheets("Sheet1")
    tbl = .Range(.Range("F9"), .Range("F9").End(xlDown)).EntireRow.Columns("F:H").Value
  End With
  With Me.ListBox1
    .ColumnCount = 3
    .ColumnWidths = "50;50;50"
    .List = tbl
  End With
  End Sub

  Private Sub CommandButton1_Click()
  Dim tbl, n As Long
  With Sheets("Sheet1")
    tbl = .Range(.Range("F9"), .Range("F9").End(xlDown)).EntireRow.Columns("A:U").Value
  End With
  With Me
    n = .ListBox1.ListIndex + 1
    If n > 0 Then
      .TextBox9.Value = tbl(n, 14)
      .TextBox10.Value = tbl(n, 15)
      .TextBox12.Value = tbl(n, 17)
      .TextBox14.Value = tbl(n, 20)
      If tbl(n, 16) = "" Then
        .TextBox11.Value = ""
      Else
        .TextBox11.Value = Format(CDate(tbl(n, 16)), "m/d")
      End If
      If tbl(n, 18) = "終了" Then
        .CheckBox1.Value = True
      Else
        .CheckBox1.Value = False
      End If
    End If
  End With
  End Sub

  Private Sub CheckBox1_Click()
  With Sheets("Sheet1").Range("R8").Offset(Me.ListBox1.ListIndex + 1)
    If Me.CheckBox1.Value = True Then
      .Value = "終了"
    Else
      .Value = ""
    End If
  End With
  End Sub

  Private Sub CommandButton2_Click()
  Dim n As Long
  n = Me.ListBox1.ListIndex + 1
  If n > 0 Then
    With Sheets("Sheet1").Rows(8 + n).Columns("A:U")
      If IsDate(Me.TextBox11.Value) Or Me.TextBox11.Value = "" Then
        .Cells(17) = Me.TextBox11.Value
      End If
      .Cells(14) = Me.TextBox9.Value
      .Cells(15) = Me.TextBox10.Value
      .Cells(17) = Me.TextBox12.Value
      .Cells(20) = Me.TextBox14.Value
    End With
  End If
  End Sub

 (x-men)

x-men様　お礼がだいぶ遅くなりすみませんでした。
マクロ起動いたしました。本当にありがとうございます。
（レインボー）

コメント返信：

[ 一覧(最新更新順) ]

[[20091027125654]] 『マクロ‐リストボックス』（レインボー） ページの最後に飛ぶ

[[20091027125654]]　『マクロ‐リストボックス』（レインボー）　ページの最後に飛ぶ