[[20091123064612]]　『グラフ内文字列を検索、置換』（マック）　ページの最後に飛ぶ

『グラフ内文字列を検索、置換』（マック）

グラフ内の文字列（タイトル、XY軸名）を検索して置換する方法があったら教えてください
MacOSX10.6, Excel 2004です

 動くかなぁ。。。
 XP,2002 で作りました。

 '------
Sub MAC()
Dim myChart As ChartObject, cc_Title As Object
Dim src_locno As Long, src_txt As String, rep_txt As String
Dim loc_ary As Variant
loc_ary = Array("", "１：　タイトル", "２：　X軸", "３：　Y軸")

    src_locno = Application.InputBox(prompt:="検索場所を値で入力して下さい。" & vbLf & _
                "1: タイトル　　2: X軸　　3: Y軸", Type:=1)
    If src_locno = False Then
        MsgBox "処理を中止します。"
        Exit Sub
    End If

    src_txt = Application.InputBox(prompt:="検索文字列を入力して下さい。", Type:=2)
    If src_txt = "False" Then
        MsgBox "処理を中止します。"
        Exit Sub
    End If

    rep_txt = Application.InputBox(prompt:="置換文字列を入力して下さい。", Type:=2)
    If rep_txt = "False" Then
        MsgBox "処理を中止します。"
        Exit Sub
    End If

    If src_txt = "" And rep_txt = "" Then
        MsgBox "処理を中止します。"
        Exit Sub
    End If

    If MsgBox("検索対象：　" & loc_ary(src_locno) & vbLf _
             & "検索文字：　" & src_txt & vbLf _
             & "置換文字：　" & rep_txt & vbLf _
             & "実行しますか？", vbOKCancel) = vbCancel Then
        Exit Sub
    End If

    For Each myChart In ActiveSheet.ChartObjects
        Select Case src_locno
            Case 1
                Set cc_Title = myChart.Chart.ChartTitle.Characters
            Case 2
                Set cc_Title = myChart.Chart.Axes(xlCategory).AxisTitle.Characters
            Case 3
                Set cc_Title = myChart.Chart.Axes(xlValue).AxisTitle.Characters
        End Select
        cc_Title.Text = Application.Substitute(cc_Title.Text, src_txt, rep_txt)
    Next myChart

    Set cc_Title = Nothing
End Sub
 '------

 (HANA)

コメント返信：

[ 一覧(最新更新順) ]

[[20091123064612]] 『グラフ内文字列を検索、置換』（マック） ページの最後に飛ぶ

[[20091123064612]]　『グラフ内文字列を検索、置換』（マック）　ページの最後に飛ぶ