[[20100111213232]]　『近似曲線のデータ抽出』（kazukazu）　ページの最後に飛ぶ

『近似曲線のデータ抽出』（kazukazu）

例

a列　
１
２
３
４
５
６

b列
１
１．９
２．３
２．５
２．７
２．９

というデータを近似曲線を使ってグラフを作成しました。
その後、a列1.5のときのデータを抽出したいのですが可能なのでしょか？
その方法を教えてください。

windows　XP、EXEL2003を使用しています。

私見です。
このデータでは求めても無意味です。
A列２と６の値をはぶいてはじめて近似できそうな感じのデータです。

もとめかたは近似式のXに1.5をいれて計算でもとめればいいです。
あまり現実とかけはなれた例をつくるのはいかがなものかと
かいとうもつかなくなってしまいますよ。
(水上)

 二次での近似ではR２乗値も0.98 で問題ない例だと思いますが。

 ちなみに二次近似では
  y = -0.0768x2 + 0.8832x + 0.29
 となりますので、これに1.5 を代入すれば求まります。
 (Mook)

 >二次での近似ではR２乗値も0.98 で問題ない例だと思いますが。
値のバラつきでまちがったはんだんしたようです。
ごめんなさい。感じでいっちゃいけないですね。反省。

 データから多項式4次のようです。
 各近似式の予測値はSERIESSUM関数で求めることが出来ます
 1.5の場合79.26687です
 多項式4次の係数を求める
 D1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4}),1)
 E1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4}),2)
 F1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4}),3)
 G1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4}),4)
 H1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4}),5)
 又はD1セル=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^COLUMN($A$1:$D$1)),1)
 1.5は79.26687　=SERIESSUM(1.5,4,-1,$D$1:$G$1)+$H$1
 決定係数R2=INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2,3,4},1,1),3)
 (atiboh)

 多分Mookさんの解釈が正しいと思います。
１１．９２．３２．５２．７２．９ 
は
１
１．９
２．３
２．５
２．７
２．９
ですね
したがって１．５は１．９と１．０の間になるとおもいます。
(水上)

 >a列　１２３４５６
 >b列１１．９２．３２．５２．７２．９
 a列は説明変数 (独立変数)
 b列は目的変数 (従属変数)
 と解釈した
 b列の「．」は区切りと見なすとa列b列ともにデータ数は6個と見なされる
 質問内容が不明確であるため私の解釈での回答である
 質問内容が不明確の場合回答は避けるべきかな
 (atiboh)

 あっ　云い忘れた
 a列及びb列の各々の数値と数値の間には空白がないため(区切りの意味)
 b列の「．」は区切りと見なした

 数値は全角ですが区切りのスペースはありますよ。
 (Mook)

 区切りの位置が分かりづらい。気付きませんでした
 基本的には多項式近似であろうと線形・指数・対数・累乗近似であろうと
 予測値(y ')は関数「シリーズ・サム」ちゃんで求められます。
 但し移動平均は無理です
 (atiboh)

 昨日はb列のデータ区切り位置が分からず失礼しました
 水上さんが示したb列テータで再度計算しました
 グラフウィザードでの数式は下記のとおりです
 多項式2次y = -0.0768x2 + 0.8832x + 0.29
 R2 = 0.9761
 対数y = 1.0326Ln(x) + 1.0844
 R2 = 0.9885

 多項式2次と対数近似の決定係数が近いので説明変数選択規準 (Ru) と相対誤差を求めてみました
 説明変数選択規準 (Ru) は、回帰式の当てはまりの良さを評価する基準です。
 Ru = 1-(1-重決定R2)*(n+k+1)/(n-k-1)」]
 相対誤差 ： 回帰式に当てはめて算出した予測値(y ')と実績値(y)の間に、どの程度の誤差があるかを見る尺度です。
 相対誤差 = (実績値(y)-予測値(y '))/実績値(y)×100」

 多項式2次係数(kは3個)
 D1セル -0.07679 =INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2}),1)
 E1セル 0.883214 =INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2}),2)
 F1セル 0.29 =INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2}),3)
 多項式2次決定係数
 H1セル 0.976083 =INDEX(LINEST($B$1:$B$6,$A$1:$A$6^{1,2},1,1),3)
 多項式2次予測値
 I1セル 1.442054 =SERIESSUM(1.5,2,-1,$D$1:$E$1)+$F$1
 多項式2次　Ru
 J1セル 0.880416 =1-(1-H1)*(6+3+1)/(6-3-1)
 相対誤差
 K1セル　3.863095　=(1.5-I1)/1.5*100

 対数近似係数(kは2個)
 D3セル 1.032621 =SLOPE(B1:B6,LN(A1:A6))
 E3セル 1.084354=INTERCEPT(B1:B6,LN(A1:A6))
 対数近似決定係数
 H3セル 0.988483 =RSQ(B1:B6,LN(A1:A6))
 対数近似予測値
 I3セル1.503046=SERIESSUM(LN(1.5),1,1,$D$3)+$E$3
 対数近似　Ru
 J3セル 0.96545 =1-(1-H3)*(6+2+1)/(6-2-1)
 相対誤差
 K1セル　-0.0307　=(1.5-I3)/1.5*100

 説明変数選択規準 (Ru)及び相対誤差は対数近似良いです
 対数近似を採用されたら
 (atiboh)

 誤りあり
 対数近似の相対誤差
 (正) K1セル　-0.20307　=(1.5-I3)/1.5*100
 (atiboh)

コメント返信：

[ 一覧(最新更新順) ]

[[20100111213232]] 『近似曲線のデータ抽出』（kazukazu） ページの最後に飛ぶ

[[20100111213232]]　『近似曲線のデータ抽出』（kazukazu）　ページの最後に飛ぶ